• Este ponto de entrada está disponível a partir do release 12.1.17.

<%
#include "protheus.ch"
  
//-----------------------------------------------------------
/*/ MNTI5201
    Fonte web de usuário para adição de elementos à página de cadastro de S.S. via Portal S.S.
    Este fonte será incorporado após o último campo apresentado pelo produto padrão.
/*/
//-----------------------------------------------------------
  
    Local cCampo1   := "TQB_TESTE"
  
//-------------------------------------------------------------------------------
// Insere linha com campo TQB_TESTE (titulo, campo e botao para acionar a consulta padrao)
//-------------------------------------------------------------------------------
%>
<tr class="tabelaTr">
    <td class="tdLabel"> <!-- Titulo -->
        <span class="<%= IIf( X3Obrigat( cCampo1 ) , 'labelObrigat', 'labelComum' )%>" ><%=Trim( RetTitle( cCampo1 ) )%>:</span>
    </td>
    <td> <!-- Campo -->
        <input type="Text" id="<%=cCampo1%>" class="inputCod" maxlength="<%= TamSx3( cCampo1 )[1] %>" value="<%=&('HttpSession->' + cCampo1)%>" onBlur='fValCpUsr(this.value,"<%=cCampo1%>")'>
    </td>
    <td> <!-- Botao para consulta padrao -->
        <button class="buttonF3" onMouseDown="<%=" fsConPad('" + Posicione("SX3", 2, cCampo1, "X3_F3")  + "', '" + cCampo1 + "' ) "%>" ><img class="imgF3" src="ng_lupacons.png" border="0"> </button>
    </td>
</tr>
 
<script>
 
    /*-------------------------------------------------------------------------------
    // Função JavaScript acionada ao clicar no botao de consulta padrao.
    // Em seguida, acionará a função de usuário B_fSXBPAD que pode ser visualizada no exemplo do fonte WEBCONS.PRW
    -------------------------------------------------------------------------------*/
    function fsConPad(cTabela, cCampo){
         
        url="B_fSXBPAD.APW?TabelaF3=" + cTabela + "&CampoF3=" + cCampo;
  
        ji=window.open(url, "Jins2","status=no,scrollbars=yes,width=605,height=550,top=200,left=200");
        ji.focus();
    }


     /*-------------------------------------------------------------------------------
    // Função JavaScript acionada para validar o campo inclusoinserido em tela pelo usuário,.
    // Em seguida, acionará a função padrão W_I05VLDCPO que fará algumas validações padrões do sistemaonde, internamente,
    // eacionará posteriormentea chamaráfunção ade funçãousuário B_VLDUSRCP que pode ser visualizada no exemplo do fonte WEBCONS.PRW
    -------------------------------------------------------------------------------*/
    function fValCpUsr( cValor, cCampo ){
     	
     	<% /*Chama validação do campo passando por parametro o campo no qual será validado
             e qual o valor inserido no campo.*/ %>
        document.MNTI0052.action = 'W_I05VLDCPO.APW?cValor=' + cValor + '&cCampo=' + cCampo;
        document.MNTI0052.submit();
    }
 
</script>

#include "protheus.ch"
#include "apwebex.ch"

//-----------------------------------------------------------
/*/ WebUser Function fSXBPAD
Função generica de usuário para construção de tela de consulta padrão web,
sendo também acionada ao realizar a pesquisa na consulta padrão.
/*/
//-----------------------------------------------------------
WebUser Function fSXBPAD()

	Local cHtml     := ''
	Local cPesquisa := ''
	Local cRecno    := '1;'
	Local cCampo
	Local cConpad
	Local cAliasCon
	Local nIndCon
	
	// Caso seja chamada para construir a tela da consulta padrao,
	// utiliza valores default do SXB
	If ValType( HttpGet->CampoF3  ) <> 'U'
		cCampo    := HttpGet->CampoF3
		cConpad   := Padr( HttpGet->TabelaF3, 6 )
		cAliasCon := AllTrim( Posicione('SXB', 1, cConpad + '101' , 'XB_CONTEM') )
		nIndCon   := Val( AllTrim( Posicione('SXB', 1, cConpad + '201' , 'XB_COLUNA') ) )
	
	Else // Caso seja chamada através da pesquisa na tela da consulta padrao,
		 // utiliza os valores informados para a pesquisa
		cCampo    := HttpSession->cField
		cConpad   := Padr( HttpSession->cSearch, 6 )
		cAliasCon := HttpSession->cAliasSXB
		nIndCon   := Val( HttpPost->indices )
		cPesquisa := HttpPost->cPesquisa
	
	Endif
	
	WEB EXTENDED INIT cHtml START 'I005ENV'
	
	// Seleciona a tabela para pesquisa
	dbSelectArea(cAliasCon)
	dbSetOrder(nIndCon)
	If '_FILIAL' $ Substr( IndexKey(), 1, 10 )
		cPesquisa := xFilial( cAliasCon ) + cPesquisa
	Endif
	
	// Executa pesquisa, posicionando no registro correspondente
	dbSeek(cPesquisa)
	If (cAliasCon)->( !EoF() ) .And. Substr( &( cAliasCon + '->(' + IndexKey() + ')' ), 1, Len( cPesquisa ) ) == cPesquisa
		cRecno := cValToChar( (cAliasCon)->( RecNo() ) ) + ';'
	EndIf
	
	//Carrega variaveis de sessao web
	HttpSession->cSearch   := cConPad
	HttpSession->cField    := cCampo
	HttpSession->cAliasSXB := cAliasCon
	HttpSession->nIndSXB   := nIndCon
	HttpSession->cSeek     := cPesquisa
	HttpSession->cNumRec   := cRecno
	HttpSession->cCurPag   := '1'
	
	//Chama pagina responsavel por exibir a consulta padrão.
	cHtml += ExecInPage('MNTI5SXB')
	
	WEB EXTENDED END

Return cHtml

//-------------------------------------------------------------------
/*/{Protheus.doc} VLDUSRCP
Valida Campos de usuário no portal de SS

No Ponto de Entrada MNTCAMUS é chamada a
função JavaScript fValCpUsr que por sua vez
faz a chamada da validação padrão do sistema
através da função I05VLDCPO, após as validações
padrões é chamada a função de validação dos
campos de usuário VLDUSRCP.
/*/
//-------------------------------------------------------------------
WebUser Function VLDUSRCP(cCampo, cValor)

	Local cHtml := ''
	Local cMsg  := ''
	
	WEB EXTENDED INIT cHtml START 'I005ENV'
	
	// Validação dos campos inclusos em tela.
	If cCampo == 'TQB_TESTE'
		If AllTrim( cValor ) >= '000000' .And. AllTrim( cValor ) <= '000100'
			HttpSession->TQB_TESTE := ''
			cMsg := 'Nao é possivel selecionar a O.S.!'
		Else
			// Atribui valor do campo a sessão. 
			HttpSession->TQB_TESTE := cValor
		Endif
	EndIf

	// Caso o lRet for .F. será apresentada a mensagem passada pelo cMsg em tela,
	// referente ao campo informado no cCampo.
	VldUsrSS(cCampo, Empty(cMsg), cMsg)
	
	WEB EXTENDED END

Return cHtml

<%
//-------------------------------------------------------------------
/*/ MNTI5SXB
    Fonte web de usuario para construção da tela de consulta padrão.
/*/
//-------------------------------------------------------------------

    //-------------------------------------------------------------------------------
    // Recupera informações do SXB para montagem da tela da consulta padrão
    //-------------------------------------------------------------------------------

    Local cLINHACOLOR, lLINHACOLOR, nPos, nTamCol, nIndice
    Local aPages, nRecno, nNxtRc, i, j
    
    Local id_pesq    := Trim(HttpSession->cSeek)
    Local cConPad    := HttpSession->cSearch
    Local cAlias     := HttpSession->cAliasSXB
    Local nInd       := HttpSession->nIndSXB
    Local aCamposSXB := {}
    Local nTamBrw    := 5
    Local cRetorno   := ''
    Local cNomeCon   := ''
    Local cContem    := ''
    Local nTamCpo    := ''
  
    cNomeCon := AllTrim( Posicione( 'SXB', 1, Padr( cConPad, 6 )+"101", 'XB_DESCRI' ) )
  
    dbSelectArea("SXB")
    dbSetOrder(1)
    // Nome da consulta padrão + Tipo + Sequencia
    dbSeek(Padr(cConPad,6)+"401")
    While !EoF() .And. SXB->(XB_ALIAS+XB_TIPO+XB_SEQ) == Padr(cConPad,6) + "401"

        cContem := AllTrim(SXB->XB_CONTEM)
        If At(">",cContem) > 0 .and. Len(cContem) <= 154
            cContem := Substr(cContem, ( At(">", cContem ) + 1) )
        Endif
        
        nTamCpo := Posicione( 'SX3', 2, cContem, 'X3_TAMANHO' )
        nTamCol := IIf( nTamCpo < 15, 15, ( nTamCpo + 20 ) ) * 5
        nTamBrw += nTamCol

        aAdd(aCamposSXB,{  RetTitle( cContem ), ;
                            AllTrim(SXB->XB_CONTEM), ;
                            nTamCol, ;
                            !Empty( Posicione( 'SX3', 2, cContem, 'X3_CBOX' ) ), ;
                            AllTrim( Posicione( 'SX3', 2, cContem, 'X3_PICTURE' ) ) ;
                        })

        dbSelectArea("SXB")
        dbSkip()
    EndDo
  
    dbSelectArea("SXB")
    dbSeek(Padr(cConPad,6)+"501",.T.)
    While SXB->XB_ALIAS == Padr(cConPad,6) .And. SXB->XB_TIPO == "5"
        cRetorno += AllTrim(SXB->XB_CONTEM)+";"
        SXB->(dbSkip())
    EndDo
    cRetorno := SubStr(cRetorno,1,Len(cRetorno)-1)
  
    //Verifica tamanho do Browse
    If nTamBrw < 560
        If Len(aCamposSXB) > 0
            aCamposSXB[Len(aCamposSXB)][3] += (560 - nTamBrw)
        Endif
        nTamBrw := 560
    Endif

%>

<%
//-------------------------------------------------------------------------------
// Cabeçalho da página HTML
//-------------------------------------------------------------------------------
%>

<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN" "http://www.w3.org/TR/html4/loose.dtd">
<html>
<head>
    <title>'  Portal Inclus&atilde;o de SS - Consulta '</title>
    <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
    <link rel="stylesheet" type="text/css" href="NGCSS.css">
</head>

<%
//-------------------------------------------------------------------------------
// Estilização da tela/página da consulta padrão
//-------------------------------------------------------------------------------
%>
<style type="text/css">
  
    body {
        margin: 5px;
    }
     
    a{
        text-decoration: none;
        color: #253453;
        font-weight: bold;
    }
     
    a:link, a:visited{
        color: #253453;
        font-weight: bold;
    }
     
    a:hover{
        background-color:#8ca0c7;
        color: #FFFFFF;
        font-weight: bold;
    }
    a:active{
        color: #253453;
        font-weight: bold;
    }
     
    a.pagina{
        text-decoration: none;
        color: #FFFFFF;
        font-weight: none;
    }
     
    a.pagina:link, a.pagina:visited{
        color: #FFFFFF;
        font-weight: none;
    }
     
    a.pagina:hover{
        color: #FFFFFF;
        font-weight: bold;
    }
    a.pagina:active{
        color: #FFFFFF;
        font-weight: bold;
    }
     
    .divrolagem {
        overflow: auto; /* define barra de rolagem automatica quando o conteudo ultrapassar o limite em x ou y*/
        height: 300px;  /* define o limite maximo da autura do div */
        width: 580px;   /* define o limite maximo da largura do div*/
        padding-top: 5pt;
    }

    /*Mantem cabecalho do browse estatico*/
    .rowHeader{
        position:relative;
        top: expression(offsetParent.scrollTop);
        height:18px;
        z-index: 20;
        background-color: #263957;
    }

</style>

<%
//-------------------------------------------------------------------------------
// Funções Javascript referentes às ações na tela de consulta padrão
//-------------------------------------------------------------------------------
%>

<script language="Javascript">
  
/* Função para selecionar o registro na consulta padrão */
function fcSeleciona(cCodRet, cCamposAtu){

    var aRet = cCodRet.split(';')
    var aCampos = cCamposAtu.split(';');

    for(i=0; i<aCampos.length;i++){
        window.opener.document.getElementById(aCampos[i]).value = aRet[i];
        window.opener.document.getElementById(aCampos[i]).focus();
    }
  
    close();
    return;
}


/* Função para realizar a busca do registro informado no campo de pesquisa */
function fcPesquisar(){
    document.forms[0].cPESQUISA.value = document.forms[0].f_nome.value;
    document.forms[0].action = 'B_fSXBPAD.APW';
    document.forms[0].submit();
}

</script>

<%
//-------------------------------------------------------------------------------
// Início do formulário da página HTML
//-------------------------------------------------------------------------------
%>

<form name='MNTI5SXB' method='post' action=''>
<opener.location.reload()>
<body onLoad="document.MNTI5SXB.f_nome.focus()">
  
<INPUT TYPE="HIDDEN" NAME="cPESQUISA" VALUE="">
<INPUT TYPE="HIDDEN" NAME="cNumRec" value='<%=HttpSession->cNumRec%>'>
<INPUT TYPE="HIDDEN" NAME="cCurPag" value='<%=HttpSession->cCurPag%>'>

<%
//-------------------------------------------------------------------------------
// Área de pesquisa
//-------------------------------------------------------------------------------
%>

    <div id="divCabec" style="width: 580px;">
        <div id="bordaCabec" style="width: 580px;">
            <b class="bordaEsqAzul1"></b><b class="bordaEsqAzul2"></b><b class="bordaEsqAzul3"></b><b class="bordaEsqAzul4"></b>
            <div id="tituloCabec" class="divtitulo" style="width: 100%; height:15px;">
                <span style="padding: 0pt 0pt 0pt 10pt">Preencha o campo abaixo e clique em Pesquisar.</span>
            </div>
            <b class="bordaDirAzul4"></b><b class="bordaDirAzul3"></b><b class="bordaDirAzul2"></b><b class="bordaDirAzul1"></b>
        </div>
    </div>
    
    <div id="divIndices" style="width: 580px; background-color: #FFFFFF; padding-bottom: 10pt">

    <table>
        <tr width="100%">
            <td colspan="2"><span class="txtTitulo" style="padding: 0pt 0pt 0pt 10pt;">Consulta <%=cNomeCon%></span></td>
        </tr>
        <tr>
            <td width="290px" align="left" style='padding: 0pt 0pt 0pt 10pt'>
                <input name="f_nome"  type="text"  id="f_nome" size="50" onChange='fcPesquisar();' style="width:270px;">
            </td>
            <td>
                <input type="button" name="Submit" value="Pesquisar" onclick="fcPesquisar();" onmouseover="this.style.cursor='pointer'"/>
            </td>
        </tr>
        <tr width="100%">
            <td colspan="2" width="290px" align="left" style='padding: 0pt 0pt 0pt 10pt'>
                <select size="1" name="indices" style="width:275px;">
                <%//Monta ComboBox com Indices da Pesquisa
                    dbSelectArea("SIX")
                    dbSetOrder(1)
                    dbSeek(cAlias)
                    While !Eof() .and. SIX->INDICE == cAlias
                        If Val(SIX->ORDEM) > 0
                            nIndice := Val(SIX->ORDEM)
                        Else
                            nIndice++
                        Endif
                        If nIndice == nInd%>
                            <option selected value="<%=nIndice%>"><%=SixDescricao()%></option>
                        <%Else%>
                            <option value="<%=nIndice%>"><%=SixDescricao()%></option>
            <%           Endif
                        dbSelectArea("SIX")
                        dbSkip()
                    EndDo
                %>
                </select>
            </td>
        </tr>
        </tr>
    </table>
</div>

<%
    //-------------------------------------------------------------------------------
    // Paginação do resultado
    //-------------------------------------------------------------------------------

    aPages := StrTokArr(HttpSession->cNumRec,';')
    nRecno := IIf(Val(HttpSession->cCurPag) <= Len(aPages), Val(aPages[Val(HttpSession->cCurPag)]  ), 0 )
    nNxtRc := IIf(Val(HttpSession->cCurPag) < Len(aPages) , Val(aPages[Val(HttpSession->cCurPag)+1]), 0 )

    
    //-------------------------------------------------------------------------------
    // Área de seleção dos registros
    //-------------------------------------------------------------------------------
%>

<div id="bordaPags" style="width: 580px;">
    <b class="bordaEsqAzul1"></b><b class="bordaEsqAzul2"></b><b class="bordaEsqAzul3"></b><b class="bordaEsqAzul4"></b>
    <div id="divPags" class="divtitulo" style="width: 100%; height: 40px;">
        <div id="txtPags" class="divtitulo" style="width: 100%; height:20px;">
            <span style="padding: 5pt 0pt 0pt 10pt">Para selecionar um Registro, clique sobre um dos campos da linha.</span>
        </div>
    </div>
    <b class="bordaDirAzul4"></b><b class="bordaDirAzul3"></b><b class="bordaDirAzul2"></b><b class="bordaDirAzul1"></b>
</div>
  
<div class="divrolagem">
    <table width="<%=nTamBrw%>" id="browse">
        <thead>
            <tr align="left" valign="middle" class="rowHeader">
                <%For i:=1 To Len(aCamposSXB)%>
                    <th width="<%=aCamposSXB[i][3]%>">
                        <span class="headerField"><%=aCamposSXB[i][1]%></span>
                    </th>
                <%Next i%>
            </tr>
        </thead>
        <tBody>
            <%lLINHACOLOR := .T.
  
                dbSelectArea(cAlias)
                dbSetOrder(nInd)
                dbSeek(id_pesq)
                dbGoTo(nRecno)
                 
                // Faz a busca dos registros que serão apresentados em tela
                While (cAlias)->(!Eof()) .And. nNxtRc != &(cAlias+"->(RecNo())") .and. Substr(&(cAlias+"->("+IndexKey()+")"),1,Len(id_pesq)) == id_pesq
  
                    %>
  
                    <tr class="linhaBrowse">
                        <%
                        If lLINHACOLOR
                            cLINHACOLOR := "WHITE"
                            lLINHACOLOR := .F.
                        Else
                            cLINHACOLOR = "#dae3f2"
                            lLINHACOLOR := .T.
                        EndIf
                        For i:=1 To Len(aCamposSXB)
                            If aCamposSXB[i][4]
                                cColuna := Substr(NGRETSX3BOX(aCamposSXB[i][2],&(aCamposSXB[i][2])),1,aCamposSXB[i][3])
                            Else
                                cColuna := &(aCamposSXB[i][2])
                            Endif
  
                            If !Empty(aCamposSXB[i][5])
                                cColuna := Transform(cColuna,aCamposSXB[i][5])
                            Endif
                            %>
                            <td width="<%=aCamposSXB[i][3]%>" height="12" bgcolor="<%=cLINHACOLOR%>" style="text-align:left">
                                <span class="celula">
                                    <%
                                        aRet := StrTokArr(cRetorno,';')
                                        cRet := ""
                                        For j := 1 To Len(aRet)
                                            cRet += &(aRet[j])+";"
                                        Next j
                                        cRet := SubStr(cRet,1,Len(cRet)-1)
                                    %>
                                    <a href="javascript:fcSeleciona('<%=(cRet)%>', '<%=HttpSession->cField%>')">
                                    <%=cColuna%></a>
                                </span>
                            </td>
                        <%Next i%>
                    </tr>
                  <%dbSelectArea(cAlias)
                    dbSkip()
                EndDo%>
        </tBody>
    </table>
</div>

<%
//-------------------------------------------------------------------------------
// Área de paginação
//-------------------------------------------------------------------------------
%>

<div id="bordaPags" style="width: 580px;">
    <b class="bordaEsqAzul1"></b><b class="bordaEsqAzul2"></b><b class="bordaEsqAzul3"></b><b class="bordaEsqAzul4"></b>
        <div id="divPags" class="divtitulo" style="height:15px;">
            <table width="100%" border="0" cellspacing="0" cellpadding="0">
            </table>
        </div>
    <b class="bordaDirAzul4"></b><b class="bordaDirAzul3"></b><b class="bordaDirAzul2"></b><b class="bordaDirAzul1"></b>
</div>
</form>
</body>
</html>