Histórico da Página

#include 'protheus.ch'

//-------------------------------------------------------------------
/*/{Protheus.doc} U_MNTA435
Exemplo da utilização do ponto de entrada MNTA435, ID "VALID_OK" 
Neste exemplo o objetivo é não permitir incluir um insumo de MDO com 
data menor que a data atual

@obs
@author  NG Informática
@since   12/02/2019
@return lógico, se obteve sucesso nas validações
@obs neste exemplo é utilizado o retorno lógico utilizado para o ID "VALID_OK" 
/*/
//-------------------------------------------------------------------
User Function MNTA435()
    
    Local aArea     := GetArea()
    Local cId       := PARAMIXB[1] //Indica o momento da chamada do PE
    Local aDadosOS  := {}
    Local aInsumos  := {} //Array de insumos realizados
    Local nOrdem
    Local nInsumo

    If cId == "VALID_OK"
		//Array com os dados das ordens de serviço
		aDadosOS := ParamIXB[2] 
	
        //Percorre o array de ordens
        For nOrdem := 1 To Len( aDadosOS )
            
            //Verifica se há insumos realizados
            If ValType( aDadosOS[ nOrdem, 5 ] ) == "A" 
                aInsumos := aClone( aDadosOS[ nOrdem, 5 ] )
            
                //Percorre o array de insumos realizados
                For nInsumo := 1 to Len( aInsumos )
                   
                    Conout( "Insumo : " + aInsumos[ nInsumo, 4 ] ) 

                    If !aTail( aInsumos[ nInsumo ] ); //Verifica se não está deletado
                        .And. aInsumos[ nInsumo, 3 ] == "M"; //Verifica se é insumo do tipo MDO
                        .And. aInsumos[ nInsumo, 12 ] < dDatabase // Verifica se a data é menor que a data atual
                        
						//Apresenta para o usuário o número da OS que há uma inconsistência
                        MsgAlert( "Ordem " + aDadosOS[ nOrdem, 1 ] +  ": a data dos insumos tipo mão de obra não pode ser menor que a data atual.")
                        
                        //Quando há problema, deve retornar falso
                        RestArea( aArea )
                        Return .F.            
                    EndIf
                    
                Next nInsumo

            EndIf
        Next nOrdem
        
        //Quando não houver problema retorna sucesso na validação
        RestArea( aArea )
        Return .T.
    EndIf
 
Return