Histórico da Página

FWBrowse(): AddCustomConfig ( < cTitle>, < bView>, [ bSave] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
cTitle	Caracter	Título a ser exibido na configuração.	X
bView	Bloco de código	Code-Block de carga da janela de configuração	X
bSave	Bloco de código	Code-Block de gravação das configurações efetuadas pelo usuário.

Exemplos

oBrowse:AddCustomConfig("Filial",{|o| MBrFilialCfg(o,Self) }, { || MBrSaveFilCfg(Self) } )

AddFilter

Permite adicionar um filtro na lista de opções de filtros do Browse.

FWBrowse(): AddFilter ( < cFilter>, < cExpAdvPL>, [ lNoCheck], [ lSelected], [ cAlias], [ lFilterAsk], [ aFilParser], [ cID] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
cFilter	Caracter	Título que será exibido no filtro	X
cExpAdvPL	Caracter	Expressão do filtro em formato AdvPL.	X
lNoCheck	Lógico	Indica que o filtro não poderá ser marcado/desmarcado.
lSelected	Lógico	Indica que o filtro deverá ser apresentado como marcado/desmarcado.
cAlias	Caracter	Indica que o filtro é de relacionamento entre as tabelas e a expressão AdvPL deve ser informado obrigatoriamente com expressões SQL.
lFilterAsk	Lógico	Indica se o filtro pergunta as informações na execução.
aFilParser	Array of Record	Array contendo informações parseadas do filtro.
cID	Caracter	Nome do identificador do filtro

Exemplos

oBrowse:AddFilter(cTitle,xCondition)

AddLegend

Permite adicionar legendas no Browse.

FWBrowse(): AddLegend ( < xCondition>, < cColor>, <cTitle>, <cID>, <lFilter>) -->

Nome	Tipo	Descrição	Obrigatório	Referência
xCondition	Expressão	Expressão AdvPL ou Code-Block com a regra da legenda	X
cColor	Caracter	Cor que identifica a regra	X
cTitle	Caracter	Título da legenda, utilizado na janela de visualização das legendas
cID	Caracter	Id
lFilter	Lógico	Indica se deve ser exibido filtro da legenda

Exemplos

oBrowse:AddLegend(xCondition,cColor,cTitle)

AddLine

Permite adicionar um linha no Browse. Sintaxe FWBrowse(): AddLine ( ) -->

AddMarkColumns

Permite adicionar uma coluna com a opção de marca e desmarca.

FWBrowse(): AddMarkColumns ( < bMark>, [ bLDblClick], [ bHeaderClick] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
bMark	Bloco de código	Code-Block com a regra e deverá retornar a imagem referente a marcado/desmarcado.	X
bLDblClick	Bloco de código	Code-Block com a execução do duplo clique na coluna.
bHeaderClick	Bloco de código	Code-Block com a execução do clique no header da coluna.

AddStatusColumns

Permite adicionar uma coluna de status.

FWBrowse(): AddStatusColumns ( < bStatus>, [ bLDblClick] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
bStatus	Bloco de código	Code-Block com a regra e deverá retornar a imagem referente ao status.	X
bLDblClick	Bloco de código	Code-Block com a execução do duplo clique na coluna.

Alias

Retorna o Alias utilizado no Browse. Sintaxe FWBrowse(): Alias ( ) --> cAlias Retorno cAlias (caracter) Alias utilizado no Browse.

AllOk

Executa o Code-Block definido no método SetAllOK(bAllOK). Sintaxe FWBrowse(): AllOk ( ) --> lReturn Retorno lReturn (logico) Retorno da execução do Code-Block.

At

Retorna a posição atual do registro. Sintaxe FWBrowse(): At ( ) --> nAt Retorno nAt () Posição atual do registro.

Browse

Retorna o componente Browse (TGRID). Sintaxe FWBrowse(): Browse ( ) --> oBrowse Retorno oBrowse () Objeto Browse (TGRID).

ClassName

Retorna o nome da classe (FWBROWSE). Sintaxe FWBrowse(): ClassName ( ) --> cClassName Retorno cClassName (caracter) Nome da classe.

CleanExFilter

Executa a limpeza dos filtros estendidos realizados no Browse. Sintaxe FWBrowse(): CleanExFilter ( ) -->

CleanFilter

Realizada a limpeza dos filtros utilizados no Browse. Sintaxe FWBrowse(): CleanFilter ( ) -->

CleanProfile

Elimina as configurações realizadas no Browse do perfil do usuário. Sintaxe FWBrowse(): CleanProfile ( ) -->

ColPos

Retorna a coluna posicionada no Browse

FWBrowse(): ColPos ( [ lDeleted] ) --> nColPos

Nome	Tipo	Descrição	Obrigatório	Referência
lDeleted	Lógico	Indica que deve considerar as colunas deletadas.

nColPos

Coluna posicionada.

Data

Retorna o objeto de dados no Browse. Sintaxe FWBrowse(): Data ( ) --> oData Retorno oData () Retorna o objeto de dados do Browse

DataArray

Retorna se o dados apresentados no Browse é de Array. Sintaxe FWBrowse(): DataArray ( ) --> lDataArray Retorno lDataArray (logico) Indica que o Browse utiliza informações de um array.

DataQuery

Retorna se o dados apresentados no Browse é de Query. Sintaxe FWBrowse(): DataQuery ( ) --> lDataQuery Retorno lDataQuery (logico) Indica que o Browse utiliza informações de uma Query.

DataTable

Retorna se o dados apresentados no Browse é de Tabela. Sintaxe FWBrowse(): DataTable ( ) --> lDataTable Retorno lDataTable (logico) Indica que o Browse utiliza informações de uma Tabela.

DataText

Retorna se o dados apresentados no Browse é de Texto. Sintaxe FWBrowse(): DataText ( ) --> lDataText Retorno lDataText (logico) Indica que o Browse utiliza informações de um arquivo Texto.

DBFFilter

Indica se utiliza filtro para tabelas CODEBASE. Sintaxe FWBrowse(): DBFFilter ( ) --> lDBFFilter Retorno lDBFFilter (logico) Indica se utiliza filtro para tabelas CODEBASE.

DeActivate

Método de destruição da classe.

FWBrowse(): DeActivate ( [ lFreeChildren] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
lFreeChildren	Lógico	Indica se é necessário limpar a classe proprietária. (oOwner)

Default

Compatibilização com a MBrowse antiga. Sintaxe FWBrowse(): Default ( ) -->

DelColumn

Indica que uma determinada coluna está deletada.

FWBrowse(): DelColumn ( < nColumn> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
nColumn	Numérico	Indica a coluna que será marcada como deletada.	X

DeleteFilter

Permite realizar a exclusão de filtros.

FWBrowse(): DeleteFilter ( [ cID] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
cID	Caracter	Identificador do Filtro

DelLine

Executa o Code-Block, definido no método SetDelete(lDelete,bDelete), para deleção de uma linha no Browse. Sintaxe FWBrowse(): DelLine ( ) -->

DelOk

Executa o Code-Block, definido no método SetDelOk(bDelOK), para validar a deleção de uma linha no Browse. Sintaxe FWBrowse(): DelOk ( ) --> lReturn Retorno lReturn

Disable

Desabilita a utilização do Browse. Sintaxe FWBrowse(): Disable ( ) -->

DisableConfig

Desabilita a utilização das configurações do Browse. Sintaxe FWBrowse(): DisableConfig ( ) -->

DisableFilter

Desabilita a utilização do filtro no Browse. Sintaxe FWBrowse(): DisableFilter ( ) -->

DisableLocate

Desabilita a utilização do localizador de registro no Browse. Sintaxe FWBrowse(): DisableLocate ( ) --> DisableReport Desabilita a impressão das informações disponíveis no Browse. Sintaxe FWBrowse(): DisableReport ( ) -->

DisableSaveConfig

Desabilita a gravação das configurações realizadas no Browse. Sintaxe FWBrowse(): DisableSaveConfig ( ) -->

DisableSeek

Desabilita a utilização da pesquisa no Browse. Sintaxe FWBrowse(): DisableSeek ( ) -->

Enable

Habilita a utilização do Browse. Sintaxe FWBrowse(): Enable ( ) -->

ExecuteFilter

Aplica os filtros realizados no Browse.

FWBrowse(): ExecuteFilter ( [ lBrwUpdate] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
lBrwUpdate	Lógico	Atualiza o Browse e posiciona no primeiro registro.

Filtrate

Indica se o Browse está filtrado. Sintaxe FWBrowse(): Filtrate ( ) --> lFiltrate Retorno lFiltrate (logico) Indica se o Browse está filtrado.

FWFilter

Retorna o objeto FWFilter. Sintaxe FWBrowse(): FWFilter ( ) --> oFWFilter Retorno oFWFilter () Retorna o objeto FWFilter.

GetBackColor

Retorna a cor de fundo do Browse. Sintaxe FWBrowse(): GetBackColor ( ) --> nBackColor Retorno nBackColor () Retorna a cor de fundo do Browse

GetClrAlterRow

Retorna a cor alternada do Browse. Sintaxe FWBrowse(): GetClrAlterRow ( ) --> nClrAlterRow Retorno nClrAlterRow () Retorna a cor alternada do Browse

GetColumn

Retorno um objeto tipo FWBrwColumn da coluna passada. Sintaxe FWBrowse(): GetColumn ([nCol]) Retorno oCol Retorna o objeto da coluna posicionada.

GetDescription

Retorna a descrição do Browse. Sintaxe FWBrowse(): GetDescription ( ) --> cDescription Retorno cDescription (caracter) Retorna a descrição do Browse

GetFilterDefault

Retorna o filtro padrão do Browse Sintaxe FWBrowse(): GetFilterDefault ( ) --> cFilterDefault Retorno cFilterDefault (caracter) Retorna o filtro padrão do Browse.

GetForeColor

Retorna a cor da fonte do Browse. Sintaxe FWBrowse(): GetForeColor ( ) --> cForeColor Retorno cForeColor (caracter) Retorna a cor da fonte do Browse.

GetObjMark

Retorna o objeto FWMARKBROWSE utilizado na passagem de parâmetros na execução das rotinas na FWFORMBROWSE; Sintaxe FWBrowse(): GetObjMark ( ) --> oObjMark Retorno oObjMark () Indica o objeto FWMARKBROWSE

GetProfileID

Retorna o identificador do Browse utiliza na gravação das configurações no profile do usuário. Deve ser utilizado quando existir mais de um Browse na rotina. Sintaxe FWBrowse(): GetProfileID ( ) --> cProfileID Retorno cProfileID (caracter) Identificador do Browse

GetQuery

Retorna a Query que esta sendo utilizada no Browse. Sintaxe FWBrowse(): GetQuery ( ) --> cQuery Retorno cQuery (caracter) Indica a Query para a criação do Browse.

GoBottom

Posiciona no último registro do Browse.

FWBrowse(): GoBottom ( [ lCallRefresh] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
lCallRefresh	Lógico	Indica que foi chamado através do método Refresh().

GoColumn

Posiciona na coluna desejada.

FWBrowse(): GoColumn ( [ nColumn] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
nColumn	Numérico	Indica a coluna que deseja posicionar.

GoDown

Salta uma ou mais linhas para baixo do item posicionado.

FWBrowse(): GoDown ( [ nOffSet], [ lReport] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
nOffSet	Numérico	Indica a quantidade de linhas a serem saltadas.
lReport	Lógico	Indica se é impressão dos itens do Browse.

GoPgDown

Salta uma página para baixo do item posicionado. Sintaxe FWBrowse(): GoPgDown ( ) --> GoPgUp Salta uma página para cima do item posicionado. Sintaxe FWBrowse(): GoPgUp ( ) -->

GoTo

Posiciona em um determinado registro do Browse.

FWBrowse(): GoTo ( < nGoto>, [ lRefresh] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
nGoto	Numérico	Indica o item que deverá ser posicionado.	X
lRefresh	Lógico	Indica se deverá forçar a atualização do Browse.

GoTop

Posiciona no primeiro registro do Browse.

FWBrowse(): GoTop ( [ lForce] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
lForce	Lógico	Indica que deverá forçar o posicionamento.

GoUp

Salta uma ou mais linhas para cima do item posicionado.

FWBrowse(): GoUp ( [ nOffSet] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
nOffSet	Numérico	Indica a quantidade de linhas a serem saltadas.

Hide

Permite tornar o Browse invisível Sintaxe FWBrowse(): Hide ( ) -->

LineOk

Executa o Code-Block, definido no método SetLineOk(bLineOk), para validação da linha posicionada. Sintaxe FWBrowse(): LineOk ( ) --> lRet Retorno lRet (logico) Indica se a linha é válida.

LineRefresh

Executa a atualização das informações de uma determinada linha do Browse.

FWBrowse(): LineRefresh ( [ nAt] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
nAt	Numérico	Indica a linha que será atualizada.

Observação:

O parâmetro nAt que refere-se a linha, começa em zero, ele índice é enviado para o método TGrid:SetRowData do binário.

LogicLen

Retorna a quantidade de registros disponíveis para o browse. Sintaxe FWBrowse(): LogicLen ( ) --> nLogicLen Retorno nLogicLen () Indica a quantidade de registros disponíveis.Quando o Browse for de tabela ou Query será retornado o último registro para a orderm selecionada.

ObligateFilter

Retorna se a selecão de um filtro é obrigatório para a apresentação do browse. Sintaxe FWBrowse(): ObligateFilter ( ) --> lObligateFilter Retorno lObligateFilter (logico) Indica se a selecão de um filtro é obrigatório para a apresentação do browse

OptionConfig

Indica se a opção de configuração do Browse está habilitada. Sintaxe FWBrowse(): OptionConfig ( ) --> lOptionConfig Retorno lOptionConfig (logico) Indica se a opção de configuração está habilitada.

OptionReport

Indica se a opção de impressão das informações do Browse está habilitada. Sintaxe FWBrowse(): OptionReport ( ) --> lOptionReport Retorno lOptionReport (logico) Indica se a opção de impressão está habilitada.

Refresh

Executa a atualização das informações no Browse.

FWBrowse(): Refresh ( [ lGoTop] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
lGoTop	Lógico	Indica que deverá ser posicionado no primeiro registro do Browse.

Report

Executa a impressão das informações do Browse. Sintaxe FWBrowse(): Report ( ) -->

Reset

Compatibilidade com o Browse antigo. Sintaxe FWBrowse(): Reset ( ) -->

ResetLen

Compatibilidade com o Browse antigo. Sintaxe FWBrowse(): ResetLen ( ) -->

SetAddLine

Indica a Code-Block executado para adicionar linha no browse.

FWBrowse(): SetAddLine ( < bAdd> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
bAdd	Bloco de código	Indica a Code-Block executado para adicionar linha no browse.	X

SetAfterAddLine

Indica o Code-Block que será executado após a inclusão de uma linha.

FWBrowse(): SetAfterAddLine ( < bAfterAddLine> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
bAfterAddLine	Bloco de código	Code-Block a ser executado após a inclusão de uma linha.	X

SetAlias

Indica o alias da tabela que será utilizada no Browse.

FWBrowse(): SetAlias ( < cAlias> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
cAlias	Caracter	Indica o alias da tabela	X

SetAllOk

Indica o Code-Block executado para validar todos itens do Browse.

FWBrowse(): SetAllOk ( < bAllOk> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
bAllOk	Bloco de código	Code-Block para validar todos itens do Browse.	X

SetArray

Indica o array utilizado para apresentação dos dados no Browse.

FWBrowse(): SetArray ( < aArray> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
aArray	Array of Record	Array utilizado para apresentação dos dados no Browse.	X

SetBackColor

Indica a cor de fundo do Browse.

FWBrowse(): SetBackColor ( < nBackColor> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
nBackColor	Numérico	Cor de fundo do Browse.	X

SetBlkBackColor

Indica a cor de fundo para a linha atual.

FWBrowse(): SetBlkBackColor ( < bBackColor> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
bBackColor	Bloco de código	Codigo de bloco que retorna a cor de fonte para a linha atual.	X

SetBlkColor

Indica a cor de fonte para a linha atual.

FWBrowse(): SetBlkColor ( < bBlkColor> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
bBlkColor	Bloco de código	Codigo de bloco que retorna a cor de fonte para a linha atual.	X

SetChange

Indica a Code-Block executado após a mudança de uma linha.

FWBrowse(): SetChange ( < bChange> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
bChange	Bloco de código	Code-Block executado após a mudança de uma linha.	X

SetClrAlterRow

Indica a cor alternada do Browse.

FWBrowse(): SetClrAlterRow ( < nClrAlterRow> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
nClrAlterRow	Numérico	Indica a cor de alternada do Browse.	X

SetDataArray

Indica que o Browse exibe dados através de um array. Sintaxe FWBrowse(): SetDataArray ( ) -->

SetDataQuery

Indica que o Browse exibe dados através de uma Query, porém, a Query cria um arquivo temporário atualizando de acordo com a demanda. Sintaxe FWBrowse(): SetDataQuery ( ) -->

SetDataTable

Indica que o Browse exibe dados através de uma tabela. Sintaxe FWBrowse(): SetDataTable ( ) -->

SetDataText

Indica que o Browse exibe dados através de um arquivo texto. Sintaxe FWBrowse(): SetDataText ( ) -->

SetDelete

Indica que o usuário pode excluir linhas no Browse.

FWBrowse(): SetDelete ( [ lDelete], [ bDelete] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
lDelete	Lógico	Indica se o usuário pode excluir linhas no Browse.
bDelete	Bloco de código	Code-Block executado na exclusão da linha.

SetDelOk

Indica o Code-Block executado para validar a exclusão da linha.

FWBrowse(): SetDelOk ( < bDelOK> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
bDelOK	Bloco de código	Code-Block executado para validar a exclusão da linha.	X

SetDescription

Indica a descrição do Browse.

FWBrowse(): SetDescription ( < cDescription> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
cDescription	Caracter	Indica a descrição do Browse	X

SetDoubleClick

Indica o Code-Block executado no duplo clique do item no Browse.

FWBrowse(): SetDoubleClick ( < bLDblClick> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
bLDblClick	Bloco de código	Code-Block executado no duplo clique do item no Browse.	X

SetEditCell

Indica que será permitido a edição da célula no Browse.

Esse método só é válido para browse de tabela ou de array. Para browse de array é necessário na criação da FWBrwColumn definir as colunas como editáveis através do método SetEdit e definir o readvar da coluna (pelo método SetReadVar)

FWBrowse(): SetEditCell ( [ lEditCell], [ bValidEdit] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
lEditCell	Lógico	Indica se permite a edição de células.
bValidEdit	Bloco de código	Code-Block executado para validar a edição da célula.

SetFieldFilter

Indica os campos que serão apresentados na edição de filtros.

FWBrowse(): SetFieldFilter ( < aFields> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
aFields	Array of Record	Array contendo os campos apresentados na edição de filtros.	X

SetFile

Indica o arquivo texto que será utilizado no Browse.

FWBrowse(): SetFile ( < cFile>, [ cCharSeparator] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
cFile	Caracter	Arquivo texto. Ex.: "\Browse\Teste.txt"	X
cCharSeparator	Caracter	Indica o caracter separador dos dados. Ex.: ";" para "dados1;dados2;dados3"

SetFilter

Indica o limite superior e inferior de um campo respeitando a classificação das informações atual.

FWBrowse(): SetFilter ( < cCpoFil>, < cTopFun>, [ cBotFun] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
cCpoFil	Caracter	Indica o campo a ser considerado o limite superior e inferior.	X
cTopFun	Caracter	Indica o limite superior.	X
cBotFun	Array of Record	Indica o limite inferior.

SetFilterDefault

Indica o filtro padrão do Browse.

FWBrowse(): SetFilterDefault ( < cFilterDefault> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
cFilterDefault	Caracter	Indica o filtro AdvPL para o Browse.	X

SetFilterRelation

Indica o relacionamento de filtros para o Browse.

FWBrowse(): SetFilterRelation ( < aFilterRelation>, < bChgFields> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
aFilterRelation	Array of Record	Array contendo os itens do relacionamento.	X
bChgFields	Bloco de código	Indica o Code-Block executado para trocar os campos para o filtro.	X

SetFocus

Força o foco no objeto Browse. Sintaxe FWBrowse(): SetFocus ( ) -->

SetFontBrowse

Indica a fonte do Browse.

FWBrowse(): SetFontBrowse ( [ oFont] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
oFont	Objeto	Indica o objeto TFont utilizado no Browse.

SetForeColor

Indica a cor da fonte no Browse.

FWBrowse(): SetForeColor ( < nForeColor> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
nForeColor	Numérico	Cor da fonte no Browse.	X

SetGroup

Indica que o Browse utiliza agrupamento de informações.

FWBrowse(): SetGroup ( < bGroup>, [ lOpen] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
bGroup	Bloco de código	Code-Block com a regra do agrupamento retornando um valor lógico (.T. = Quebra, .F. = Filho ).	X
lOpen	Lógico	Indica que o agrupamento será apresentado com os sub-itens visíveis na abertura do Browse.

SetHeaderImage

Indica a imagem que será apresentada ao lado do título da coluna.

FWBrowse(): SetHeaderImage ( < nColumn>, < cResource> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
nColumn	Numérico	Indica coluna que será apresentada a imagem.	X
cResource	Caracter	Indica a imagem que será apresentada ao lado da coluna.	X

SetInsert

Indica que o usuário poderá inserir novas linhas no Browse.

FWBrowse(): SetInsert ( [ lInsert] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
lInsert	Lógico	Indica que poderá inserir novas linhas.

SetItemDoubleClick

Indica os itens que serão disponibilizados para a configuração do duplo clique pelo usuário.

FWBrowse(): SetItemDoubleClick ( < aItemDoubleClick> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
aItemDoubleClick	Array of Record	Array contendo as informações que serão apresentadas para configuração do duplo clique.	X

SetItemHeaderClick

Indica os itens que serão disponibilizados para a configuração do clique no header pelo usuário.

FWBrowse(): SetItemHeaderClick ( < aItemHeaderClick> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
aItemHeaderClick	Array of Record	Indica os itens que serão disponibilizados para a configuração do clique no header pelo usuário.	X

SetLineBegin

Indica a linha do arquivo texto que deverá ser considerado para ínicio da leitura no Browse.

FWBrowse(): SetLineBegin ( < nLineBegin> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
nLineBegin	Numérico	Indica a linha inicial do arquivo texto.	X

SetLineHeight

Indica a altura da linha no Browse.

FWBrowse(): SetLineHeight ( [ nHeight] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
nHeight	Numérico	Indica a altura da linha

SetLineOk

Indica o Code-Block executado na troca de linha do Browse.

FWBrowse(): SetLineOk ( < bLineOk> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
bLineOk	Bloco de código	Code-Block executado na troca de linha.	X

SetLocate

Habilita a utilização do localizador de registros no Browse.

FWBrowse(): SetLocate ( [ bAction] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
bAction	Bloco de código	Code-Block executado para localização das informações, caso não seja informado será utilizado o padrão.

SetNumberLegend

Indica que a legenda será representada por números.

FWBrowse(): SetNumberLegend ( [ lNumber] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
lNumber	Lógico	Indica que a legenda será representada por números.

SetObjMark

Indica o objeto FWMARKBROWSE utilizado na passagem de parâmetros na execução das rotinas na FWFORMBROWSE.

FWBrowse(): SetObjMark ( < oObjMark> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
oObjMark	Objeto	Indica o objeto FWMARKBROWSE	X

SetObligateFilter

Indica se a selecão de um filtro é obrigatório para a apresentação do browse.

FWBrowse(): SetObligateFilter ( [ lObligateFilter], [ lCanCancel] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
lObligateFilter	Lógico	Indica que o filtro será solicitado na entrada do Browse
lCanCancel	Lógico	Indica que permite o cancelamento na tela de filtros.

SetOwner

Indica o container para criação do Browse.

FWBrowse(): SetOwner ( [ oOwner] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
oOwner	Objeto	Indica o container para criação do Browse.

SetPreEditCell

Indica o bloco de pré-validação para a edição de celula, o bloco devera retorna .T. para abrir a edição e .F. para nao abrir.

FWBrowse(): SetPreEditCell ( < bBlock> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
bBlock	Bloco de código	Code-Block com a funcao de validação. O bloco recebe como parametro o objeto do Browse, a coluna ,e o caracter precionado.	X

SetProfileID

Define o identificador do Browse utiliza na gravação das configurações no profile do usuário. Deve ser utilizado quando existir mais de um Browse na rotina.

FWBrowse(): SetProfileID ( < cProfileID> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
cProfileID	Caracter	Identificador do Browse	X

Obs.: o tamanho máximo do ID deve ser de 4 (quatro) caracteres

SetQuery

Indica a Query que será utilizada para criação do Browse.

FWBrowse(): SetQuery ( < cQuery> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
cQuery	Caracter	Indica a Query para a criação do Browse.	X

Observação: A partir da versão Lib 20161010, não deve ser informado o campo R_E_C_N_O_ na query, pois tratasse de um campo exclusivo na criação de arquivos temporários no banco de dados.

SetQueryIndex

Indica os índices utilizados pela Query na criação do Browse.

FWBrowse(): SetQueryIndex ( < aIndex> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
aIndex	Array of Record	Indica os índices utilizados pela Query na criação do Browse.	X

SetSeek

Habilita a utilização da pesquisa de registros no Browse.

FWBrowse(): SetSeek ( [ bAction], [ aOrder] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
bAction	Bloco de código	Code-Block executado para a pesquisa de registros, caso não seja informado será utilizado o padrão.
aOrder	Array of Record	Array contendo as informações para criação dos detalhes da pesquisa. Estrutura do array: [n,1] Título da pesquisa [n,2,n,1] LookUp [n,2,n,2] Tipo de dados [n,2,n,3] Tamanho [n,2,n,4] Decimal [n,2,n,5] Título do campo [n,2,n,6] Máscara [n,2,n,7] Nome Físico do campo - Opcional - é ajustado no programa [n,3] Ordem da pesquisa [n,4] Exibe na pesquisa

SetSeekChange

Indica o Code-Block executado na mudança da ordem de pesquisa.

FWBrowse(): SetSeekChange ( [ bSeekChange] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
bSeekChange	Bloco de código	Code-Block executado na mudança da ordem de pesquisa.

SetShowLimit

Indica se apresenta somente o limite de informacoes do Browse do tipo Query quando a Query ultrapassar o limite definido.

FWBrowse(): SetShowLimit ( [ lShowLimit] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
lShowLimit	Lógico	Indica se apresenta somente o limite de informacoes do Browse do tipo Query quando a Query ultrapassar o limite definido.

SetSuperDel

Indica o Code-Block executado ao pressionar as teclas CTRL+Del.

FWBrowse(): SetSuperDel ( < bSuperDel> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
bSuperDel	Bloco de código	Code-Block executado no CTRL+Del.	X

SetTypeMove

Indica o tipo de navegação do Browse

FWBrowse(): SetTypeMove ( < nTypeMove> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
nTypeMove	Numérico	Indica o tipo de navegação no Browse 0=Linha ou 1=Coluna	X

SetUseCaseFilter

Habilita a utilização do filtro case no Browse.

FWBrowse(): SetUseCaseFilter ( [ nAlign] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
nAlign	Numérico	Indica o alinhamento do filtro no Browse.

SetUseFilter

Habilita a utilização do filtro no Browse.

FWBrowse(): SetUseFilter ( [ nAlign], [ bOnStart] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
nAlign	Numérico	Indica o alinhamento do filtro no Browse.
bOnStart	Bloco de código	Code-Block executado na criação do componente de filtro.

SetVldExecFilter

Define um bloco de códigos para validar se o filtro deve ser executado.

FWBrowse(): SetVldExecFilter ( < bVldExecFilter> ) -->

SetUniqueKey(aSetKey)

Nome	Tipo	Descrição	Obrigatório	Referência
bVldExecFilter	Bloco de código	Code-Block para validar se o filtro deve ser executado.	X

Define os campos chave de um browse de query ou array para conseguir reposicionar posteriormente em atualizações que forcem a reconstrução do browse. Não será realizado controle de inserção em duplicidade de registros no browse.

FWBrowse(): SetUniqueKey(aSetKey) -->

Nome	Tipo	Descrição	Obrigatório	Referência
aSetKey	Array	Lista com os campos definidos como chave. Quando browse de query espera { “CAMPO1”, “CAMPO2” }, nomes dos campos. Quando browse de array { 1, 2, 3 }, número das colunas do array.	X

Lógico, indica se a definição dos campos aconteceu ou não.

GetUniqueKey()

Retorna a lista com os campos ou colunas definidos como chave para o browse.

FWBrowse(): GetUniqueKey() -->

Array, lista com os campos definidos como chave do browse.

GetUniqueDataKey()

Captura o conteúdo dos campos e colunas informados como chave do browse.

FWBrowse(): SetUniqueKey(aSetKey) -->

GoToDataKey(aDataKey)

Array, com lista com os pares de campos e valores identificados. Quando browse por query: { { “CAMPO”, VALOR }, { “CAMPO”, VALOR } }. Quando browse por array: { { NUM_COLUNA, VALOR }, { NUM_COLUNA, VALOR } }.

Posiciona o browse no registro conforme a chave recebida por parâmetro.

FWBrowse(): SetUniqueKey(aDataKey) -->

Nome	Tipo	Descrição	Obrigatório	Referência
aDataKey	Array	Lista com os pares de campos e valores identificados. Quando browse por query: { { “CAMPO”, VALOR }, { “CAMPO”, VALOR } }. Quando browse por array: { { NUM_COLUNA, VALOR }, { NUM_COLUNA, VALOR } }.	X

Lógico, indica se foi possível realizar o posicionamento no registro do browse conforme o parâmetro informado.

Show

Permite tornar o Browse visível. Sintaxe FWBrowse(): Show ( ) -->

Bloco de código

title	Exemplo com Define
linenumbers	true

#INCLUDE "PROTHEUS.CH"
#INCLUDE "FWBROWSE.CH"
User Function BrwTable()

Local oBrowse
Local oColumn
Local oDlg

//-------------------------------------------------------------------// Abertura da tabela//-------------------------------------------------------------------
DbSelectArea("SX2")
DbSetOrder(1)

//-------------------------------------------------------------------// Define a janela do Browse//-------------------------------------------------------
DEFINE DIALOG oDlg FROM 0,0 TO 600,800 PIXEL 

//------------------------------------------------------------------- // Define o Browse //----------------------------------------------------------------
DEFINE FWBROWSE oBrowse DATA TABLE ALIAS "SX2" OF oDlg 

//-------------------------------------------------------- // Cria uma coluna de marca/desmarca//----------------------------------------------
ADD MARKCOLUMN oColumn DATA { || If(.T./* Função com a regra*/,'LBOK','LBNO') };
DOUBLECLICK { |oBrowse| /* Função que atualiza a regra*/ };
HEADERCLICK { |oBrowse| /* Função executada no clique do header */ } OF oBrowse 

//-------------------------------------------------------- // Cria uma coluna de status //--------------------------------------------------------
ADD STATUSCOLUMN oColumn DATA { || If(.T./* Função com a regra*/,'BR_VERDE','BR_VERMELHO') };
DOUBLECLICK { |oBrowse| /* Função executada no duplo clique na coluna*/ } OF oBrowse 

//-------------------------------------------------------- // Adiciona legenda no Browse //--------------------------------------------------------
ADD LEGEND DATA 'X2_CHAVE $ "AA1|AA2"' COLOR "GREEN" TITLE "Chave teste 1" OF oBrowse 
ADD LEGEND DATA '!(X2_CHAVE $ "AA1|AA2")' COLOR "RED" TITLE "Chave teste 2" OF oBrowse 

//------------------------------------------------------------------- // Adiciona as colunas do Browse //------------------------------------------
ADD COLUMN oColumn DATA { || X2_CHAVE } TITLE "Chave" SIZE 3 OF oBrowse 
ADD COLUMN oColumn DATA { || X2_ARQUIVO } TITLE "Arquivo" SIZE 10 OF oBrowse 
ADD COLUMN oColumn DATA { || X2_NOME } TITLE DecodeUTF8("Descrição") SIZE 40 OF oBrowse 
ADD COLUMN oColumn DATA { || X2_MODO } TITLE "Modo" SIZE 1 OF oBrowse 

//------------------------------------------------------------------- // Ativação do Browse//---------------------------------------------------------------- 
ACTIVATE FWBROWSE oBrowse

//-------------------------------------------------------------------// Ativação do janela//-------------------------------------------------------------------
ACTIVATE DIALOG oDlg CENTERED

Return

Bloco de código

title	Exemplo sem Define
linenumbers	true

User Function BrwTable()
 
Local oBrowse
Local oColumn
Local oDlg
 
// Abertura da tabela
DbSelectArea("SX2")
DbSetOrder(1)

//Define a janela do Browse
oDlg = TDialog():New(0, 0, 600, 800,,,,,,,,,,.T.)

// Define o Browse
oBrowse := FWBrowse():New(oDlg)
oBrowse:SetDataTable(.T.)
oBrowse:SetAlias("SX2")

// Cria uma coluna de marca/desmarca
oColumn := oBrowse:AddMarkColumns({||If(.T./*Função de Marca/desmaca*/,'LBOK','LBNO')},{|oBrowse|/*Função de DOUBLECLICK*/},{|oBrowse|/* Função de HEADERCLICK*/})

// Cria uma coluna de status
oColumn := oBrowse:AddStatusColumns({||If(.T./*Função de avaliação de status*/,'BR_VERDE','BR_VERMELHO')},{|oBrowse|/*Função de DOUBLECLICK*/})

// Adiciona legenda no Browse
oBrowse:AddLegend('X2_CHAVE $ "AA1|AA2"',"GREEN","Chave teste 1")
oBrowse:AddLegend('!(X2_CHAVE $ "AA1|AA2")',"RED","Chave teste 2")

// Adiciona as colunas do Browse
oColumn := FWBrwColumn():New()
oColumn:SetData({||X2_CHAVE})
oColumn:SetTitle("Chave")
oColumn:SetSize(3)
oBrowse:SetColumns({oColumn})

oColumn := FWBrwColumn():New()
oColumn:SetData({||X2_ARQUIVO})
oColumn:SetTitle("Arquivo")
oColumn:SetSize(10)
oBrowse:SetColumns({oColumn})

oColumn := FWBrwColumn():New()
oColumn:SetData({||X2_NOME})
oColumn:SetTitle(DecodeUTF8("Descrição"))
oColumn:SetSize(40)
oBrowse:SetColumns({oColumn})

oColumn := FWBrwColumn():New()
oColumn:SetData({||X2_MODO})
oColumn:SetTitle("Modo")
oColumn:SetSize(1)
oBrowse:SetColumns({oColumn})

// Ativação do Browse
oBrowse:Activate()

// Ativação da janela
oDlg:Activate(,,,.T.)

Return

UpdateBrowse

Realiza a reconstrução do browse para atualizações em tempo de execução. Este método fará com que exista problemas de desempenho nos programas pois o browse é completamente reconstruído.

FWBrowse(): UpdateBrowse(lResetSeek) → NIL

Nome	Tipo	Descrição
lResetSeek	Lógico	Indica se deve refazer a construção das ordens de pesquisa no browse.