Histórico da Página

#INCLUDE 'TOTVS.CH'    


/*/{Protheus.doc} A410BSIT
    @type  Ponto de entrada que Permite a modificação da Situação 
    do documento conforme necessidade do cliente.
    @author Faturamento
    @since 08/02/2022
    @version P12133
    @param PARAMIXB Array com 3 retornos 
    @param[1] - Tipo Caracter - Recebe o codigo da Filial Corrente
    @param[2] - Tipo Caracter - Recebe o Numero do Pedido
    @param[3] - Tipo Caracter - Recebe a situação do documento
    @return - Tipo caracter - Retorna a String que deverá substituir 
    a situação do documento.
    @example
    (examples)
    @see (links_or_references)
/*/
User Function A410BSIT()
Local cFilUse  := ParamIxb[1]  //filial que esta em uso
Local cNumDoc  := PadR(ParamIxb[2],TamSx3("C5_NUM")[1])   // Numero do pedido
Local cSitDoc  := ParamIxb[3]  // Situação do documento
Local cRet     := ""           // Retorno do ponto de entrada 
Local aArea    := GetArea()
Local aArSC6   := SC6->(GetArea())
Local cChave   := ""
Local nValDoc  := 0

If cFilUse == "D MG 01 "
    If !"Transmitida" $ cSitDoc
        cChave := xFilial("SC6") + cNumDoc
        DbSelectArea("SC6")
        DbSetorder(1) //C6_FILIAL+C6_NUM+C6_ITEM+C6_PRODUTO
        DbSeek(cChave )
       
        While !Eof() .And. cChave == SC6->C6_FILIAL + SC6->C6_NUM 
            
            nValDoc += SC6->C6_VALOR

            SC6->(DbSkip())
        End

        If nValDoc > 1000
            cRet := "Autorização da Gerencia Financeira"
        Else 
            cRet := cSitDoc
        EndIf

    EndIf 

EndIf 

Restarea(aArSC6)
RestArea(aArea)

Return cRet