Histórico da Página

...

Descrição:	O ponto de entrada P712VLD permite o usuário validar os parâmetros de execução impedir o avanço nas configurações do MRP.
Localização:	Funções de validação de página do fonte PCPA712.prw
Eventos:	Ao clicar para avançar no wizzard de configuração do MRP.
Programa Fonte:	PCPA712.prw
Sintaxe:	P712LDTL ( ) → lRet
Retorno:	lRet - Indica se pode avançar para a próxima página do wizzard de configuração.
Observações:	Realizar a validação de parâmetros apenas da página atual ou anteriores, caso contrario não será possível alterar o parâmetro pela tela pois o avanço estará bloqueado. O ponto de entrada também é chamado na validação das páginas, caso selecionado para pular para o processamento.

Bloco de código

language	c#
firstline	1
title	Exemplo
linenumbers	true

#INCLUDE "PROTHEUS.CH"   

User Function P712VLD()
    Local cTela	 := ParamIxb[1]
    Local cJson	 := ParamIxb[2]
    Local oJson  := JsonObject():New()
    Local lRet   := .T.
    
    oJson:FromJson(cJson)

    If cTela == "TELA_1"
        If oJson["lGeraDoc"] == .F.
            Help(' ',1,"Help",, "Deve gerar documentos no final do cálculo",2,0)
            lRet := .F. 
        EndIF
    ElseIf cTela == "TELA_2"
        If Val(oJson["numberOfPeriods"]) > 30
            Help(' ',1,"Help",, "Só pode executar com 30 periodos ou menos",2,0)
            lRet := .F.
        EndIf
    ElseIf cTela == "TELA_3"
        If oJson["safetyStock"] == "1" 
            Help(' ',1,"Help",, "Estoque de segurança deve estar configurado como não",2,0)
            lRet := .F.
        EndIf

        If oJson["orderPoint"] == "1"
            Help(' ',1,"Help",, "Ponto de pedido deve estar configurado como não",2,0)
            lRet := .F.
        EndIf
    ElseIf cTela == "TELA_4"
        If oJson["consolidatePurchaseRequest"] != "2"
            Help(' ',1,"Help",, "Não pode aglutinar solicitações de compra",2,0)
            lRet := .F.
        EndIf
        
        If oJson["consolidateProductionOrder"] != "2"
            Help(' ',1,"Help",, "Não pode aglutinar ordens de produção",2,0)
            lRet := .F.
        EndIf
    ElseIf cTela == "TELA_5"
        If oJson["documentType"]["PREVISTOS"] != "1"
            Help(' ',1,"Help",, "Documentos previstos devem ser excluidos",2,0)
            lRet := .F.
        EndIf
    EndIf

Return lRet

Árvore de páginas

Versões comparadas

Versão antiga 4

Nova versão 5

Chave