Histórico da Página

#INCLUDE "totvs.ch"

/*/{Protheus.doc} User Function F380ATR

    (Ponto de entrada para manipular/gravar dados complementares antes do carregamento dos registro para conciliação)
    @type  Function
    @author Cassio S. Dias
    @since 17/11/2023
    @return Nil
    @see (links_or_references)
    /*/

User Function F380ATR()
    Local cMsg := ""
    Local aArea := GetArea()
    Local aAreaTRB := TRB->(GetArea())
    Local nCont := 0
      
    DbSelectArea("TRB")
    While ! TRB->(EoF())
        If !Empty(TRB->E5_OK)
            dbSelectArea("SE5")
            SE5->(DbGoTo(TRB->E5_RECNO))          
            If ! Empty(SE5->E5_RECONC)
                cMsg += "- "+SE5->E5_PREFIXO+" - "+SE5->E5_NUMERO+" - "+SE5->E5_PARCELA+" - "+dToC(SE5->E5_DTDISPO)+" - "+SE5->E5_HISTOR+" . "+Chr(13)+Chr(10)
            EndIf
        EndIf
    
        If Empty(TRB->E5_OK)
            dbSelectArea("SE5")
            SE5->(DbGoTo(TRB->E5_RECNO))          
            If  Empty(SE5->E5_RECONC)
                cMsg += "- "+SE5->E5_PREFIXO+" - "+SE5->E5_NUMERO+" - "+SE5->E5_PARCELA+" - "+dToC(SE5->E5_DTDISPO)+" - "+SE5->E5_HISTOR+" . "+Chr(13)+Chr(10)
            EndIf
        EndIf
        
        nCont++
        TRB->(DbSkip())

        if TRB->(EoF())
        MSGINFO( "Foram localizados "+cValtoChar(nCont)+" registros.", "Registros Encontrados" )
        ENDIF 
    EndDo
      
    If !Empty(cMsg)
        cMsg := "Serão desconciliados:"+Chr(13)+Chr(10)+"- Prefixo - Número - Parcela - Data - Histórico" + Chr(13)+Chr(10)+ cMsg
        Aviso('Atenção', cMsg, {'OK'}, 03)
    EndIf
      
    RestArea(aAreaTRB)
    RestArea(aArea)
Return

<style>
div.theme-default .ia-splitter #main {
    margin-left: 0px;
}
.ia-fixed-sidebar, .ia-splitter-left {
    display: none;
}
#main {
    padding-left: 10px;
    padding-right: 10px;
    overflow-x: hidden;
}

.aui-header-primary .aui-nav,  .aui-page-panel {
    margin-left: 0px !important;
}
.aui-header-primary .aui-nav {
    margin-left: 0px !important;
}
</style>