Linha Microsiga Protheus

Árvore de páginas

Versões comparadas

Versão antiga 6

changes.mady.by.user Francisco do Carmo de Oliveira

Gravado em

comparado com

Nova versão 7

changes.mady.by.user Francisco do Carmo de Oliveira

Gravado em

Chave

  • Esta linha foi adicionada.
  • Esta linha foi removida.
  • A formatação mudou.


Índice

01. VISÃO GERAL

...

As transferências ocorrem diretamente da conta do usuário pagador para a conta do usuário recebedor, sem a necessidade de intermediários, o que propicia custos de transação menores.

O PIX poderá ser transacionado de forma on-line e alguns bancos também estão disponibilizando a forma de comunicação do PIX através do modelo CNAB. O processo está preparado para trabalhar com o modelo de QR CODE Dinâmico.

...

Para a inclusão de um novo fornecedor via execauto (MATA020), tabela SA2 e para a inclusão de uma chave PIX para esse novo fornecedor (FINA885), tabela F72, disponibizamos abaixo um código exemplo da execauto de inclusão.

02. EXEMPLO EXECAUTO


Expandir
titleExemplo de Execauto (MATA020)

#INCLUDE "TBICONN.CH"
#INCLUDE "PROTHEUS.CH"
#INCLUDE "FWMVCDef.CH"

//-----------------------------------------------------------------
//Função de usuário para inclusão de fornecedor via execauto (MVC)
//-----------------------------------------------------------------

User Function MT020MVC()

   Local oModel   := Nil
   Local cFornec  := 'FORPIX'
   Local cForLoja := '01'
   Local lIncOk   := .F.

   PREPARE ENVIRONMENT EMPRESA "T1" FILIAL "D MG 01" MODULO "FIN" TABLES "SA2", "F72"

   oModel := FwLoadModel ("MATA020")
   oModel:SetOperation(MODEL_OPERATION_INSERT)
   oModel:Activate()

   oModel:SetValue("SA2MASTER","A2_COD"   , cFornec)
   oModel:SetValue("SA2MASTER","A2_LOJA"  , cForLoja)
   oModel:SetValue("SA2MASTER","A2_NOME"  , "FORN TESTE PIX")
   oModel:SetValue("SA2MASTER","A2_NREDUZ", "F TESTE PIX")
   oModel:SetValue("SA2MASTER","A2_END"   , "RUA FORN PIX ")
   oModel:SetValue("SA2MASTER","A2_EST"   , "SP")
   oModel:SetValue("SA2MASTER","A2_MUN"   , "SAO PAULO")
   oModel:SetValue("SA2MASTER","A2_TIPO"  , "F")

   If oModel:VldData()
      oModel:CommitData()
      MsgInfo("Registro INCLUÍDO!", "Atenção")
      lIncOk:=.T.
   Else
      VarInfo("",oModel:GetErrorMessage())
   EndIf

   oModel:DeActivate()
   oModel:Destroy()
   oModel := NIL

   If lIncOk
      U_F885MVC(cFornec,cForLoja)
   EndIf

   RESET ENVIRONMENT

Return Nil

//-----------------------------------------------------------------
//Função de usuário para inclusão de chave PIX para fornecedor via execauto (MVC)
//-----------------------------------------------------------------

User Function F885MVC(cFornec As Character, cForLoja As Character)

   Local oModel      := Nil

   Default cFornec   := ""
   Default cForLoja  := ""

   DbSelectArea("SA2")
   SA2->(DbSetOrder(1))

   If SA2->(DBSeek(xFilial("SA2") + cFornec + cForLoja))
      oModel := FwLoadModel ("FINA885")
      oModel:SetOperation(MODEL_OPERATION_INSERT)
      oModel:Activate()

      oModel:SetValue("FORMCAB","F72_FILIAL", xFilial("SA2"))
      oModel:SetValue("FORMCAB","F72_COD"   , cFornec)
      oModel:SetValue("FORMCAB","F72_LOJA"  , cForLoja)
      oModel:SetValue("FORMCAB","F72_NOME"  , SA2->A2_NOME)

      oModel:SetValue("FORDETAIL", "F72_TPCHV" , "02")
      oModel:SetValue("FORDETAIL", "F72_CHVPIX", "email_fornec@emailpix.com.br")
      oModel:SetValue("FORDETAIL", "F72_ACTIVE", "1")
      
      If oModel:VldData()
         oModel:CommitData()
         MsgInfo("Registro INCLUÍDO!", "Atenção")
      Else
         VarInfo("",oModel:GetErrorMessage())
      EndIf

      oModel:DeActivate()
      oModel:Destroy()
      oModel := NIL
   EndiF

Return Nil

...