Aviso
Ler documentação sobre o serviço que utilizará essa classe: Smart View - Protheus como Fonte de Dados Nativa

Aviso
Recomendado utilizar a integração em ambiente com dicionário no banco de dados

Aviso
Classe deverá ser utilizada com a linguagem TL++

Objetivo

Classe disponibilizada para a construção do Objeto de Negócio para integração com o TReports, um facilitador para a geração de relatórios.

Utilização da Nova Classe

A nova classe criada em TL++ possui Namespace que deverá ser herdado no novo fonte.

Bloco de código

title	namespace

totvs.framework.treports.integratedprovider

Exemplo de uso:

Bloco de código

#include "msobject.ch"
// Referência o .th da classe
#include "totvs.framework.treports.integratedprovider.th"

// Cria um novo namespace para sua classe
namespace custom.financeiro.naturezas.integratedprovider

// Caso queira desativar a utilização da classe mudar para active=.F.
@totvsFrameworkTReportsIntegratedProvider(active=.T.)

// Cria uma nova classe e herda a classe principal (IntegratedProvider) com o namespace
class SEDTReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider 
	public method new() as object
endclass

Métodos

New()

Método de instância da classe.

Neste método serão criados os objetos oData e oSchema que serão utilizados para a montagem do Objeto de Negócio.

Informações
Objetos oData e oSchema são tratados internamente, nesta documentação haverá exemplos de métodos destes objetos, apenas eles serão utilizados externamente.

GetSchema()

Retorna o Schema de dados.

Informações

title	Método AliasToSchema()

self:oSchema:AliasToSchema() - Método do objeto oSchema que transforma o alias em um schema, todos os campos serão enviados.

Método disponível para uso externo, outros tratamentos do objeto oSchema é feito internamente.

Exemplo de uso:

Bloco de código
method getSchema() as object class SEDTReportsBusinessObject self:oSchema:aliasToSchema("SED") //Alias utilizado para retorno dos dados return self:oSchema

...

title	Método AddProperty()

self:oSchema:AddProperty() - Método do objeto oSchema que adiciona uma propriedade ao schema.

Método disponível para uso externo, outros tratamentos do objeto oSchema é feito internamente.

Parâmetros:

Aviso

A partir da LIB Label 20230918 é possível fazer o tratamento nos objetos de negócio para aceitar campos personalizados.

Documentação completa no link: Smart View - Personalização de Campos

Aviso

A partir da LIB Label 20231121 é possível criar objetos de negócio aninhados.

Documentação completa no link: Smart View - Objetos de Negócios Aninhados

Informações

title	Logs

É possível ver os logs da integração ligando a chave FwTraceLog=1 no INI do ambiente utilizado, para mais informações sobre a chave: Chaves para controle de logs

Índice

maxLevel	1
exclude	Índice

Objetivo e Vantagens do Objeto de Negócio em TLPP

Classe disponibilizada para a construção do Objeto de Negócio para integração com o Smart View, sendo possível utilizá-la como um facilitador para geração de relatórios.

Principais pontos na utilização:

Utilização de funções advpl para recuperar os dados dos campos
Contextualização de Grupo de Empresa/Filial a partir das funções RetSqlName e xFilial
Utilização de querys elaboradas para recuperar dados em várias tabelas
Paginação das requisições para busca de dados, melhorando a performance e sendo possível carregar uma massa de dados maior
Facilitador para preenchimento de filtros na criação do relatório a partir do lookup nos campos
Tratamento para Dados Protegidos

Utilização da classe IntegratedProvider

A nova classe criada em TL++ possui Namespace e Annotation que deverá ser herdado no novo fonte.

Bloco de código

title	namespace

totvs.framework.treports.integratedprovider

Exemplo de uso:

Bloco de código

#include "protheus.ch"
#include "msobject.ch"
// Referência o .th da classe
#include "totvs.framework.treports.integratedprovider.th"

// Cria um novo namespace para sua classe
namespace custom.financeiro.naturezas.integratedprovider

// Caso queira desativar a utilização da classe mudar para active=.F.
@totvsFrameworkTReportsIntegratedProvider(active=.T., team="SIGAFIN", tables="SED", name="Naturezas", country="ALL", initialRelease="12.1.2210")

// Cria uma nova classe e herda a classe principal (IntegratedProvider) com o namespace
class SEDTReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider 
	public method new() as object
endclass

Informações

title	Annotation no Objeto de Negócio

Para mais informações sobre o Annotation do objeto de negócio, acessar a documentação completa: Smart View - Annotation no objeto de negócio

Métodos

New()

Método de instância da classe.

Neste método serão criados os objetos oData e oSchema que serão utilizados para a montagem do Objeto de Negócio.

Sintaxe: New() → objeto self

Informações

Objeto oData

Serão feitos tratamentos internos neste objeto.

Ele possui apenas dois métodos para uso externo, usado em conjunto com os métodos da nova classe, sendo eles:

Método AliasToData() - Método do objeto

...

Exemplo de uso:

Bloco de código

method getSchema() as object class SEDTReportsBusinessObject
	self:oSchema:addProperty("Descrição", "Descrição da Natureza", "C", "ED_DESCRIC")
	self:oSchema:addProperty("Código", "Código da Natureza", "C", "ED_CODIGO")
return self:oSchema

GetData()

Retorna o Objeto de dados.

Parâmetros:

...

Nome

...

Informações

title	Método AliasToData()

self:oSchema:AliasToData() - Método do objeto oData que converte o alias recebido em dados para o TReports.

Apenas este método está disponível para uso externo, outros tratamentos do objeto oData é feito internamente.

Exemplo de uso:

Bloco de código
method getData(nPage as numeric, oFilter as object) as object class SEDTReportsBusinessObject self:oData:aliasToData("SED", oFilter) //Exemplo sem uso do filtro return self:oData

SetDisplayName()

Define o nome do relatório.

Exemplo de uso:

Bloco de código
self:SetDisplayName("Naturezas")

GetDisplayName()

Retorna o nome do relatório.

AppendArea()

Adiciona uma área a qual o relatório pertence.

Parâmetros:

...

Bloco de código
self:AppendArea("Financeiro")

GetAreas()

Retorna a área que os relatórios pertencem.

SetDescription()

Define a descrição do relatório.

GetDescription()

Retorna a descrição do relatório.

Exemplos completos:

Bloco de código

title	Exemplo 1
collapse	true

#include "msobject.ch"
#include "totvs.framework.treports.integratedprovider.th"

namespace custom.financeiro.naturezas.integratedprovider

@totvsFrameworkTReportsIntegratedProvider(active=.T.)
class SEDTReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider
    public method new() as object
    public method getDisplayName() as character
    public method getAreas() as array
    public method getData() as object
    public method getSchema() as object
endclass

method new() as object class SEDTReportsBusinessObject
	_Super:new()
	self:setDescription("Naturezas financeiras do Protheus")
return self

method getDisplayName() as character class SEDTReportsBusinessObject
return "Naturezas"

method getAreas() as array class SEDTReportsBusinessObject
return {"Financeiro"}

method getData(nPage as numeric, oFilter as object) as object class SEDTReportsBusinessObject
	self:oData:aliasToData("SED", oFilter)
return self:oData

method getSchema() as object class SEDTReportsBusinessObject
	self:oSchema:aliasToSchema("SED")
return self:oSchema

...

title	Exemplo 2
collapse	true

...

Smart View.

Nome	Tipo	Obrigatório	Default	Descrição
cAlias	Caracter	X		Workarea que será trabalhada
oFilter	Objeto	X		Objeto de filtro do Smart View

Método AppendData() - Método do objeto oData que adiciona um json para o array de dados.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
jData	Json	X		Json contendo os dados (chave:valor)

Informações
Lembrando que a chave enviada no appendData é o mesmo valor que foi definido como id daquele campo no schema.

Exemplos de uso estarão abaixo nos métodos criados para a classe IntegratedProvider.

Aviso

title	Campos do Tipo Data

Os campos do tipo data deverão ser formatados no formato UTC aaaa-mm-ddThh:mm:ss-+Time Zone (ISO 8601). É possível realizar essa conversão utilizando a função FWTimeStamp(5, StoD(cDate), "00:00:00").

Exemplo: FwTimeStamp(5, StoD((cAlias)→B1_UREV), "00:00:00")

Documentação: https://tdn.totvs.com.br/display/framework/FWTimeStamp

A partir da LIB Label 20230807 disponibilizaremos funções para conversões de data pro formato do smart view, caso a data esteja vazia iremos fazer o tratamento corretamente, verificar a documentação completa: Smart View - Conversão de datas

Informações

Objeto oSchema

Serão feitos tratamentos internos neste objeto.

Ele possui apenas dois métodos para uso externo, usados em conjunto com os métodos da nova classe, sendo eles:

Método AliasToSchema() - Método do objeto oSchema que transforma o alias em um schema, caso seja utilizado apenas o primeiro parâmetro todos os campos serão enviados.

Informações

title	Id da propriedade

Ao utilizar o método aliasToSchema, o Id da propriedade é o nome do campo na tabela, ex. A1_NOME

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
cAlias	Caracter	X		Alias/WorkArea que será utilizado
xField	Variante		Nil	Contém os campos que serão utilizado no schema, podendo ser caracter ou array.

Método AddProperty() - Método do objeto oSchema que adiciona uma propriedade ao schema.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
cId	Caractere	X		ID da propriedade (Não pode conter símbolos ou caracteres especiais, exceto _ (underline)) *Obs.: pode ser preenchido com o nome do campo: ex: A2_COD*
cDescription	Caractere	X		Descrição da propriedade
cType	Caractere	X		Tipo da propriedade (A partir da LIB Label 20230403 será aceito o tipo 'memo') Tipos aceitos: string, number, boolean, date e memo
cDisplayName	Caractere	X		Nome de exibição da propriedade
cRealName	Caractere	X		Nome da propriedade no Protheus (Nome real do campo da tabela), caso seja um campo 'manual' enviar o mesmo valor do cId
cComboValues (Disponível a partir da LIB Label 20220321)	Caractere		Ao ser utilizado o método self:setIsCBoxLookup() documentado abaixo, com o segundo parâmetro igual a .T., o cComboValues receberá o valor do combobox do campo a partir da SX3 (Utilizado em filtros/parâmetros criados a partir de um campo)	Valores do key-label (Formato igual ao combobox da SX3, ex.: "D MG 01=Filial BH" separado por ; caso tenha mais de uma opção)
lIsRequired (Disponível a partir da LIB Label 20220321)	Lógico		.F.	Indica que será obrigatório informar um valor para o campo
cRenameField (Disponível a partir da LIB Label 20220905)	Caractere			Indica um apelido para o campo (utilizado quando a query contém campos repetidos)
lCanFilter (Disponível a partir da LIB Label 20230626)	Lógico		.T.	Indica se o campo pode ser filtrado

Exemplos de uso estarão abaixo nos métodos criados para a classe IntegratedProvider.

Obs: O nome real é necessário para que o filtro seja feito com base no nome real do campo, caso contrário, o mesmo levará em consideração a propriedade name.

Método AddParameter() - Método do objeto oSchema que adiciona um parâmetro ao objeto de negócio.

Informações
Disponível a partir da LIB Label 20230515

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
cId	Caractere	X		ID da propriedade (Não pode conter símbolos ou caracteres especiais)
cDisplayName	Caractere	X		Nome de exibição da propriedade
cType	Caractere	X		Tipo da propriedade (Tipos aceitos: string, number, boolean e date)
lIsMultiValue	Lógico		.F.	Indica se aceita múltiplos valores
cUrl	Caractere			Indica o path da url personalizada que servirá para consulta
lHasOptions	Lógico		.F.	Indica se tem options (combo)
lHasLookUp	Lógico		.F.	Indica se tem a consulta (lookup)
cIdConsult	Caractere			Id para identificação da consulta
cParamId (Disponível a partir da LIB Label 20241125)	Caractere			Id do parâmetro
cDescription (Disponível a partir da LIB Label 20241125)	Caractere			Descrição do parâmetro (help)
lAllowNull (Disponível a partir da LIB Label 20241125)	Lógico		.T.	Indica se o valor pode ser nulo
aDefaultValues (Disponível a partir da LIB Label 20241125)	Array			Valores default do parâmetro
nMaxLength (Disponível a partir da LIB Label 20241125)	Numérico		150	Valor máximo do parâmetro
lVisible (Disponível a partir da LIB Label 20241125)	Lógico		.T.	Indica se é visível ou não

Exemplos de uso:

Bloco de código

self:addParameter("Xisto_LookUp_Url", "Xpto", "string", .T., "api/smartview/xisto",,.T.,"SA2") //Parâmetro com consulta lookup personalizada (api)
self:addParameter("Xisto_Combo", "Xpto", "string", .T., "", .T.,,"MTR110", "MV_PAR01") //Parâmetro com consulta combo usando a SX1

Para mais informações sobre consultas personalizadas, acessar a documentação completa: Smart View - Lookup e Combo nos parâmetros nativos

Informações

Objeto oFilter

Serão feitos tratamentos internos neste objeto.

Ele possui métodos para uso externo, usados em conjunto com o método getData do objeto de negócios

Método hasFilter() - Método do objeto oFilter que indica a existência de filtros (O Smart View permite filtrar os dados)

Retorno: Logical → Indica a presença de filtros

Sintaxe: oFilter:hasFilter() → logical

Método hasFields() - Método do objeto oFilter que indica se existem campos de retorno (O Smart View permite retornar uma quantidade de campos menor que o objeto de negócios possui, filtrando assim os campos, não os dados)

Retorno: Logical → Indica a presença de campos de retorno

Sintaxe: oFilter:hasFields() → logical

Método getAdvplExpression() - Método do objeto oFilter que retorna os filtros no formato ADVPL

Retorno: character → Filtro de dados no formato ADVPL

Sintaxe: oFilter:getAdvplExpression() → character

Método getSQLExpression() - Método do objeto oFilter que retorna os filtros no formato SQL

Retorno: character → Filtro de dados no formato SQL

Sintaxe: oFilter:getSQLExpression() → character

Método getFields() - Método do objeto oFilter que retorna um array contendo os campos que foram solicitados (Mesma lógica do hasFields)

Retorno: array → Campos que devem ser retornados

Sintaxe: oFilter:getFields() → array

Método getRawFilter() - Método do objeto oFilter que retorna um JSON com o filtro solicitado pelo Smart View em seu formato original, é com base nele que as expressões SQL e ADVPL são geradas (Mesma lógica do hasFilter)

Retorno: json → JSON com o filtro solicitado pelo Smart View

Sintaxe: oFilter:getRawFilter() → json

Método getParameters() - Método do objeto oFilter que retorna os parâmetros nativos do Objeto de Negócio.

Retorno: json → Json com os parâmetros

Sintaxe: oFilter:getParameters() → json

Observação: Método só disponível na LIB 20230626 ou superior

...

GetSchema()

Retorna a Estrutura de dados.

Exemplos de uso:

Bloco de código
method getSchema() as object class SEDTReportsBusinessObject self:aliasToSchema("SED") //Alias utilizado para retorno dos dados return self:oSchema

Bloco de código
method getSchema() as object class SEDTReportsBusinessObject self:aliasToSchema("SED", "E1_FILIAL") //Alias e campo utilizado para retorno dos dados return self:oSchema

Bloco de código

method getSchema() as object class SEDTReportsBusinessObject
	local aFields as array
	aFields := {"E1_PREFIXO","E1_NUM"}
	self:aliasToSchema("SED", aFields) //Alias e campos utilizados para retorno dos dados
return self:oSchema

Bloco de código

method getSchema() as object class SEDTReportsBusinessObject
	self:addProperty("Descricao", "Descrição da Natureza", "string", "Descrição", "ED_DESCRIC")
	self:addProperty("Codigo", "Código da Natureza", "string", "Natureza", "ED_CODIGO")
return self:oSchema

Informações

A partir da LIB Label 20230403 poderá ser informado campos memos no método addProperty(). Exemplo:

Bloco de código
method getSchema() as object class SEDTReportsBusinessObject self:addProperty("Descricao", "Descricao", "memo", "Descrição", "NUE_DESC") return self:oSchema

Sintaxe: GetSchema() → objeto self:oSchema

...

GetData()

Retorna o Objeto de dados.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
nPage	Numérico		Página atual	Número da página atual
oFilter	Objeto			Objeto do Filtro

Exemplos de uso:

Bloco de código

method getData(nPage as numeric, oFilter as object) as object class SEDTReportsBusinessObject
	// Objeto de filtro nulo pois o recurso não se encontra ativo
	self:aliasToData("SED", oFilter)
return self:oData

Bloco de código

method getData(nPage as numeric, oFilter as object) as object class SEDTReportsBusinessObject
local cQuery as character
local cAlias as character
local oExec as object

cQuery := "SELECT ED_DESCRIC FROM " + RetSqlName('SED') + " WHERE D_E_L_E_T_ = ' '"

if oFilter:hasFilter()
    cQuery += " AND " + oFilter:getSQLExpression()
endif

oExec  := FwExecStatement():New(ChangeQuery(cQuery))
cAlias := oExec:OpenAlias()  

while !(cAlias)->(Eof())
    self:appendData({"Descrição": (cAlias)->ED_DESCRIC})
    (cAlias)->(DBSkip())
enddo

(cAlias)->(DBCloseArea())

return self:oData

Sintaxe: GetData() → objeto self:oData

...

SetDisplayName()

Define o nome do relatório.

Aviso

title	Importante

É obrigatório o envio do DisplayName nos Objetos de Negócio

Exemplo de uso:

Bloco de código
SetDisplayName("Naturezas")

Sintaxe: SetDisplayName(<cTexto>) → nil

...

GetDisplayName()

Retorna o nome do relatório.

Sintaxe: GetDisplayName() → self:cTexto

...

AppendArea()

Adiciona uma área a qual o relatório pertence.

Aviso

title	Importante

É obrigatório o envio de pelo menos uma área nos Objetos de Negócio

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
cArea	Caracter	X		Nome da área do relatório

Exemplo de uso:

Bloco de código
AppendArea("Financeiro")

Sintaxe: AppendArea(<cArea>) → nil

...

GetAreas()

Retorna a área que os relatórios pertencem.

Sintaxe: GetAreas() → self:aArray

...

SetDescription()

Define a descrição do relatório.

Aviso

title	Importante

É obrigatório o envio da Descrição nos Objetos de Negócio

Sintaxe: SetDescription(<cTexto>) → nil

...

GetDescription()

Retorna a descrição do relatório.

Sintaxe: GetDescription() → self:cTexto

Aviso

title	Filtros

Os filtros serão setados na interface do novo Smart View

Exemplos de criação da nova classe:

Bloco de código

title	Exemplo 1
collapse	true

#include "msobject.ch"
#include "totvs.framework.treports.integratedprovider.th"

namespace custom.financeiro.naturezas.integratedprovider  

@totvsFrameworkTReportsIntegratedProvider(active=.T., team="SIGAFIN", tables="SED", name="Naturezas", country="ALL", initialRelease="12.1.2210") class SEDTReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider
    public method new() as object
    public method getDisplayName() as character
    public method getAreas() as array
    public method getData() as object
    public method getSchema() as object
endclass

method new() as object class SEDTReportsBusinessObject
	_Super:new()
	self:setDescription("Naturezas financeiras do Protheus")
return self

method getDisplayName() as character class SEDTReportsBusinessObject
return "Naturezas"

method getAreas() as array class SEDTReportsBusinessObject
return {"Financeiro"}

// Os filtros serão setados na interface do novo TReports
method getData(nPage as numeric, oFilter as object) as object class SEDTReportsBusinessObject
	self:aliasToData("SED", oFilter)
return self:oData

method getSchema() as object class SEDTReportsBusinessObject
	self:aliasToSchema("SED")
return self:oSchema

Bloco de código

title	Exemplo 2
collapse	true

#include "msobject.ch"
#include "totvs.framework.treports.integratedprovider.th"

namespace custom.financeiro.fornecedores.integratedprovider

@totvsFrameworkTReportsIntegratedProvider(active=.T., team="SIGACOM", tables="SA2", name="SA2TReportsBusinessObject", country="ALL", initialRelease="12.1.2210") 
class SA2TReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider
    public method new() as object
    public method getAreas() as array
    public method getDescription() as character
    public method getData() as object
    public method getSchema() as object
endclass

method new() as object class SA2TReportsBusinessObject
	_Super:new()
	self:setDisplayName("Fornecedores")
return self

method getDescription() as character class SA2TReportsBusinessObject
return "Fornecedores do Protheus"

method getAreas() as array class SA2TReportsBusinessObject
return {"Financeiro", "Contas a pagar"}

method getData(nPage as numeric, oFilter as object) as object class SA2TReportsBusinessObject
	local cQuery as character
	local cAlias as character
	local oExec as object

	cQuery := "SELECT A2_NOME, A2_COD FROM " + RetSqlName('SA2') + " WHERE D_E_L_E_T_ = ' '"
	
	//Os filtros serão setados na interface do novo TReports
	if oFilter:hasFilter()
	    cQuery += " AND " + oFilter:getSQLExpression()
	endif

	oExec  := FwExecStatement():New(ChangeQuery(cQuery))
	cAlias := oExec:OpenAlias()  

	while !(cAlias)->(Eof())
	    self:appendData({"Nome": (cAlias)->A2_NOME, "Codigo": (cAlias)->A2_COD})
	    (cAlias)->(DBSkip())
	enddo

	(cAlias)->(DBCloseArea())
return self:oData

method getSchema() as object class SA2TReportsBusinessObject
	self:addProperty("Nome", "Nome do Fornecedor", "string", "Fornecedor", "A2_NOME")
	self:addProperty("Codigo", "Codigo do Fornecedor", "string", "Cod do Fornecedor", "A2_COD")
return self:oSchema

Bloco de código

title	Exemplo 3
collapse	true

#include "msobject.ch"
#include "totvs.framework.treports.integratedprovider.th"

namespace custom.materiais.produtos.integratedprovider   
@totvsFrameworkTReportsIntegratedProvider(active=.T., team="SIGACOM", tables="SB1", name="Materiais", country="ALL", initialRelease="12.1.2210")   
class SB1TReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider
    public method new() as object
    public method getDisplayName() as character
    public method getDescription() as character
    public method getData() as object
    public method getSchema() as object
endclass

method new() class SB1TReportsBusinessObject
_Super:new()
self:appendArea("Materiais")
return self

method getDisplayName() as character class SB1TReportsBusinessObject
return "Produtos"

method getDescription() as character class SB1TReportsBusinessObject
return "Produtos do Protheus"

method getData(nPage as numeric, oFilter as object) as object class SB1TReportsBusinessObject
local cQuery as character
local cAlias as character
local oExec as object

cQuery := "SELECT B1_FILIAL, B1_COD, B1_DESC, B1_TIPO, B1_UM, B1_UREV FROM " + RetSQLName("SB1") + " WHERE D_E_L_E_T_ = ' '"

//Os filtros serão setados na interface do novo TReports
if oFilter:hasFilter()
    cQuery += " AND " + oFilter:getSQLExpression()
endif

oExec  := FwExecStatement():New(ChangeQuery(cQuery))
cAlias := oExec:OpenAlias()  

while !(cAlias)->(Eof())
    self:appendData({"Filial": (cAlias)->B1_FILIAL,; 
            "Codigo": (cAlias)->B1_COD,; 
            "Descricao": (cAlias)->B1_DESC,;
            "Tipo": (cAlias)->B1_TIPO, ;
            "Unidade": (cAlias)->B1_UM, ;
            "Revisao": iif(!empty((cAlias)->B1_UREV)), FwTimeStamp(5, StoD((cAlias)->B1_UREV), "00:00:00"), nil) }) //O campo data deverá ser enviado no formato correto, se estiver vazio enviar nil
    (cAlias)->(DBSkip())
enddo

(cAlias)->(DBCloseArea())

return self:oData

method getSchema() as object class SB1TReportsBusinessObject
self:aliasToSchema("SB1", "B1_COD")
self:addProperty("Descricao", "Descricao", "string", "Descricao","B1_DESC")
self:addProperty("Tipo", "Tipo", "string", "Tipo","B1_TIPO")
self:addProperty("Unidade", "Unidade de medida", "string", "Unidade","B1_UM")
self:addProperty("Revisao", "Revisao", "date", "Revisao","B1_UREV") 
return self:oSchema

Informações
Método disponível a partir da LIB Label 20231505

...

SetPergunte()

Indica o Pergunte (SX1) do relatório.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
cPergunte	Caractere	X		Código do pergunte no SX1

Exemplo de uso:

Bloco de código

method new() as object class SRA2TReportsBusinessObject
    _Super:new()
    self:setDisplayName("Funcionários")

    if !self:setPergunte("GPER140") //Indica o pergunte que será utilizado no relatório
      FwLogMsg("WARN",, "SmartView",,, , "Grupo de perguntas nao encontrado", , ,)   
    endif
return self

Sintaxe:setPergunte(<cPergunte>) → logical

Informações
Retorno lógico disponível a partir da LIB Label 20230918

Informações

title	Pergunte

Todos os MV_PAR virão maiúsculos no retorno. Ex: MV_PAR01, MV_PAR02

...

SetErrorStatus()

Indica o código de erro e as mensagens que serão exibidas no relatório

Informações
Pode ser utilizado nos métodos getData e getSchema da classe.

Parâmetros:

Nome	Tipo	Obrigatório	Descrição
nCodError	Numérico	X	Códigos de erro 4xx.
cMessage	Caractere	X	Mensagem de erro que será exibida.
cDetailedMsg	Caractere	X	Mensagem detalhada do erro que será exibida.

Exemplo de uso:

Bloco de código

method new() as object class SRA2TReportsBusinessObject
    _Super:new()
    self:setDisplayName("Funcionários")

     if !self:setPergunte("GPER140") //Indica o pergunte que será utilizado no relatório GPER140
        if !self:setErrorStatus(400,"Sem Pergunte","Verifique o grupo de perguntas informado!")
           FwLogMsg("WARN",, "SmartView",,, , "Codigo de erro invalido, aceito somente codigos de erro 4xx", , ,)
        endif
         FwLogMsg("WARN",, "SmartView",,, , "Grupo de perguntas nao encontrado", , ,)   
    endif

return self

Sintaxe:setErrorStatus(<nCodError>, <cMessage>, <DetailedMsg>) → logical

Informações
Método disponível a partir da LIB Label 20230918

...

SetCanFilter()

Indica se o campo pode ser filtrado.

Informações
Método disponível a partir da LIB Label 20230626

Parâmetros:

Nome

Tipo

Obrigatório

Default

Descrição

cId

Caractere

X

Id da propriedade

Obs.: Se foi utilizado o método aliasToSchema o Id da propriedade é o nome do campo na tabela, ex. A1_NOME

lCanFilter

Lógico

X

Indica se o campo pode ser filtrado

Exemplo de uso:

Bloco de código

method getSchema() as object class BA3TReportsBusinessObject
	self:aliasToSchema("BA3" , {"BA3_DATBLO", "BA3_CODINT", "BA3_MATRIC"})
 	self:setCanFilter("BA3_MATRIC", .F.) //Setando o campo enviado pelo aliasToSchema como não filtrável
return self

Sintaxe: setCanFilter(<cId>, <lCanFilter>) → nil

...

SetPropDisplayName()

Seta o displayName da propriedade.

Informações
Método disponível a partir da LIB Label 20230626

Parâmetros:

Nome

Tipo

Obrigatório

Default

Descrição

cId

Caractere

X

Id da propriedade

Obs.: Se foi utilizado o método aliasToSchema o Id da propriedade é o nome do campo na tabela, ex. A1_NOME

cDisplayName

Caractere

X

Nome de exibição

Exemplo de uso:

Bloco de código

method getSchema() as object class BA3TReportsBusinessObject  
	self:aliasToSchema("BA3" , {"BA3_DATBLO", "BA3_CODINT", "BA3_MATRIC", "BA3_VERCON"})
	self:setPropDisplayName("BA3_VERCON", "Versão (BA3)") //Mudando o displayName da propriedade de BA3_VERCON para Versão (BA3)
return self

Sintaxe: setPropDisplayName(<cId>, <cDisplayName>) → nil

...

Implementação do LookUp nos Filtros de campos

Informações
Disponível a partir da LIB Label 20220321

Com os métodos documentados a seguir será possível adicionar o LookUp dos campos na interface do Smart View. Esse lookup será utilizado quando o usuário criar um filtro/parâmetro através dos campos do objeto de negócio, seu uso é opcional.

Padrão Key-Label

Key - Chave do LookUp (Valor que será procurado na tabela do schema)

Label - Label de exibição do Lookup. (Nome amigável que será apresentado na interface do Smart View)

Método self:setIsCBoxLookup()

Indica no objeto Schema que o LookUp será do tipo Key-Value (combobox).

Informações
Método deverá ser utilizado no new() da nova classe criada, exemplo completo estará no final da documentação.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
lKeyLabel	Lógico	X	.F.	Indica que o filtro lookup será do tipo key-label
lX3	Lógico		.F.	Indica que utilizará o SX3 para recuperar os valores do key-label dos campos

Exemplo de uso:

Bloco de código
self:setIsCBoxLookup(.T., .T.)

Sintaxe: self:SetIsCBoxLookUp(<lKeyLabel>, <lX3>) → nil

Aviso

title	Atenção

Ao utilizar o parâmetro lX3 como .T. todos os campos da classe passará pela aplicação do lookup de acordo com a SX3, caso o número de campos seja grande a performance poderá ser afetada.

...

Método self:oSchema:setComboValues()

Indica os valores dos combos dos schemas da nova classe.

Informações
Método deverá ser utilizado no getSchema() após a criação dos campos da nova classe, exemplo completo estará no final da documentação.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
cField	Caracter	X		Campo que receberá o LookUp Key-Label
cComboValues	Caracter	X		Valores do key-label (Formato igual ao combobox da SX3, ex.: "D MG 01=Filial BH" separado por ; caso tenha mais de uma opção)
lIsRequired	Lógico		.F.	Indica que é obrigatório o preenchimento do campo.

Utilização com o método addProperty() documentado acima

Exemplo de uso:

Bloco de código
self:oSchema:addProperty("Filial", "Filial", "string", "Filial", "B1_FILIAL", "D MG 01=Filial BH; D MG 02=Filial Uberaba", .F.)

Exemplos completos com LookUp Key-Label:

Bloco de código

title	Exemplo 1 - LookUp Key-Label
collapse	true

#include "msobject.ch"
#include "protheus.ch"
#include "totvs.framework.treports.integratedprovider.th"
 
namespace custom.materiais

@totvsFrameworkTReportsIntegratedProvider(active=.T., team="SIGACOM", tables="SB1", name="Materiais", country="ALL", initialRelease="12.1.2210")  
class SB1TReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider
    public method new() as object
    public method getDisplayName() as character
    public method getDescription() as character
    public method getData() as object
    public method getSchema() as object
endclass
 
method new() class SB1TReportsBusinessObject
_Super:new()
self:appendArea("Materiais")
self:setIsCBoxLookup(.T., .T.)
return self
 
method getDisplayName() as character class SB1TReportsBusinessObject
return "Produtos"
 
method getDescription() as character class SB1TReportsBusinessObject
return "Produtos do Protheus"
 
method getData(nPage as numeric, oFilter as object) as object class SB1TReportsBusinessObject
local cQuery as character
local cAlias as character
local oExec as object
 
cQuery := "SELECT B1_FILIAL, B1_COD, B1_DESC, B1_TIPO, B1_UM, B1_UREV, B1_FILIAL, B1_PRV1 FROM " + RetSQLName("SB1") + " WHERE D_E_L_E_T_ = ' '"
 
//Os filtros serão setados na interface do novo TReports
if oFilter:hasFilter()
    cQuery += " AND " + oFilter:getSQLExpression()
endif

oExec  := FwExecStatement():New(ChangeQuery(cQuery))
cAlias := oExec:OpenAlias()  
 
while !(cAlias)->(Eof())
    cDate := iif(!empty((cAlias)->B1_UREV)), FwTimeStamp(5, StoD((cAlias)->B1_UREV), "00:00:00"), nil)
    self:appendData({"Filial": (cAlias)->B1_FILIAL,; 
            "Codigo": (cAlias)->B1_COD,; 
            "Descricao": (cAlias)->B1_DESC,;
            "Tipo": (cAlias)->B1_TIPO, ;
            "Unidade": (cAlias)->B1_UM, ;
            "Revisao": cDate ,;
            "Preco": (cAlias)->B1_PRV1})
    (cAlias)->(DBSkip())
enddo
 
(cAlias)->(DBCloseArea()) 
 
return self:oData
 
method getSchema() as object class SB1TReportsBusinessObject
local cComboFil as character

cComboFil := "D MG 01=Filial BH; D MG 02=Filial Uberaba"

self:addProperty("Filial", "Filial", "string", "Filial", "B1_FILIAL", cComboFil,.F.)
self:addProperty("Codigo", "Codigo", "string", "Codigo", "B1_COD")
self:addProperty("Descricao", "Descricao", "string", "Descricao","B1_DESC")
self:addProperty("Tipo", "Tipo", "string", "Tipo","B1_TIPO")
self:addProperty("Unidade", "Unidade de medida", "string", "Unidade","B1_UM") 
self:addProperty("Revisao", "Revisao", "date", "revisao","B1_UREV") 
self:addProperty("Data", "Data", "date", "Data","B1_UREV")
self:addProperty("Preco", "Preço", "number", "Preço","B1_PRV1")
return self:oSchema

Bloco de código

title	Exemplo 2 - LookUp Key-Label
collapse	true

#include "msobject.ch"
#include "protheus.ch"
#include "totvs.framework.treports.integratedprovider.th"

namespace custom.financeiro.naturezas.integratedprovider

// Parece que ao fazer o uso da namespace dessa forma, está gerando alguams exceções aleatório quanto as propriedades das classes
// using namespace totvs.framework.treports.integratedprovider

@totvsFrameworkTReportsIntegratedProvider(active=.T., team="SIGAFIN", tables="SED", name="Naturezas Financeiras", country="ALL", initialRelease="12.1.2210")  
class SEDTReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider
    public method new() as object
    public method getDisplayName() as character
    public method getAreas() as array
    public method getData() as object
    public method getSchema() as object
endclass

method new() as object class SEDTReportsBusinessObject
_Super:new()
self:setDescription("Naturezas financeiras do Protheus")
self:setIsCBoxLookup(.T., .F.)
return self

method getDisplayName() as character class SEDTReportsBusinessObject
return "Naturezas"

method getAreas() as array class SEDTReportsBusinessObject
return {"Financeiro"}

method getData(nPage as numeric, oFilter as object) as object class SEDTReportsBusinessObject
self:aliasToData("SED", oFilter)
return self:oData

method getSchema() as object class SEDTReportsBusinessObject
self:aliasToSchema("SED")

self:setComboValues("ED_FILIAL", "D MG 01=Filial BH; D MG 02=Filial Uberaba", .F.)
self:setComboValues("ED_CALCIRF", "Sim=Sim; Não=Não")
return self:oSchema

Exemplo do Key-Label na interface:

Image Added

Padrão LookUp

ID - Chave do LookUp (Valor que será procurado na tabela do schema)

Prod - Código de exibição do Lookup (Mesmo conteúdo do ID)

Desc - Descrição do LookUp (Nome amigável que será apresentado na interface do Smart View)

Método self:setIsLookup()

Indica no objeto Schema que o LookUp será do tipo padrão LookUp.

Informações
Método deverá ser utilizado no new() da nova classe criada, exemplo completo estará no final da documentação.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
lIsLookUp	Lógico	X	.F.	Indica que o filtro será do tipo padrão lookup

Exemplo de uso:

Bloco de código
self:setIsLookup(.T.)

Sintaxe: self:SetIsLookUp(<lIsLookUp>) → nil

...

Método self:oSchema:setDescriptor()

Indica a descrição para o LookUp (padrão lookup).
(depreciado - a partir da lib 20230515 utilizar o array aDescriptor nos métodos SetLookupQuery e SetLookupVal)

Informações
Método deverá ser utilizado no getSchema() da nova classe criada, exemplo completo estará no final da documentação.

Parâmetros:

Nome	Tipo	Default	Descrição
cId	Caracter	ID	Indica o cabeçalho de exibição da chave do lookup
cProd	Caracter	Código	Indica o cabeçalho de exibição do código do lookup (Mesmo conteúdo do ID)
cDesc	Caracter	Descrição	Indica o cabeçalho de exibição da descrição do lookup

Exemplo de uso:

Bloco de código
self:setDescriptor("Código","Código do Produto", "Descrição do Produto")

Sintaxe: self:oSchema:setDescriptor(<cId>, <cProd>, <cDesc>) → nil

...

Método self:oSchema:setLookUpVal()

Indica os valores para o LookUp (padrão lookup)

Informações
Método deverá ser utilizado no getSchema() da nova classe criada, exemplo completo estará no final da documentação.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
cField	Caracter	X		Indica o campo que será setado a consulta
aStruct	Array	X		Indica a estrutura que será utilizada no Lookup Exemplo da estrutura: aStruct[1][1]:"ATF0510001" aStruct[1][2]:"ATFA036 EMISSAO DE NOTA EM LOT" aStruct[2][1]:"0003" aStruct[2][2]:"PRODUTO PADRAO"
lIsRequired	Lógico		.F.	Indica que é obrigatório o preenchimento do campo
aDescriptor	array		Titulo do campo de acordo com SX3	array com as descrições de cada campo, na ordem do dados passados (a partir da lib 20230515)
nFieldReturn	numérico		1	numero da coluna que deverá retornar na consulta (a partir da lib 20230515)

Exemplo de uso:

Bloco de código
self:setLookUpVal(cField, aStruct, lIsRequired)

Sintaxe: self:setLookUpVal(<cField>, <aStruct>, <lIsRequired>) → nil

...

Método self:oSchema:setX5Struct()

Indica os valores para o LookUp (padrão lookup) a partir da SX5.

Informações
Método deverá ser utilizado no getSchema() da nova classe criada, exemplo completo estará no final da documentação.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
cField	Caracter	X		Indica o campo que será setado a consulta
cTable	Caracter	X		Indica a tabela da SX5 que será utilizada para buscar a estrutura do lookup
lIsRequired	Lógico		.F.	Indica que é obrigatório o preenchimento do campo

Exemplo de uso:

Bloco de código
self:setX5Struct(cField, cTable, lIsRequired)

Sintaxe: self:setX5Struct(<cField>, <cTable>, <lIsRequired>) → nil

...

Método self:oSchema:setLookUpQuery()

Indica os valores para o LookUp (padrão lookup) a partir de uma query.

Informações
Método deverá ser utilizado no getSchema() da nova classe criada, exemplo completo estará no final da documentação.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
cField	Caracter	X		Campo que será setado a consulta
aFields	Array	X		Indica os campos da estrutura da consulta (chave-descrição). Exemplo: aFields[1]:"ED_CODIGO" aFields[2]:"ED_DESCRIC" ou (a partir da lib 20230515) aFields[1] := {"CAMPO","TIPO", SIZE, DECIMAL} Caso seja passado um vetor simples apenas com o nome dos campos os dados adicionais serão procurados na SX3
cQuery	Caracter	X		Indica a tabela da SX5 que será utilizada para buscar a estrutura do lookup
lIsRequired	Lógico		.F.	Indica que é obrigatório o preenchimento do campo
aDescriptor	array		Titulo do campo de acordo com SX3	array com as descrições de cada campo, na ordem do dados passados (a partir da lib 20230515)
cFieldReturn	Caracter		Primeiro campo do aFields	coluna que deverá retornar na consulta (a partir da lib 20230515)
cOrder	Caracter		Primeiro campo do aFields	clausula a ser utilizada no order by do select (a partir da lib 20230515)

Exemplo de uso:

Bloco de código
self:setLookUpQuery(cField, aFields, cQuery, lIsRequired)

Sintaxe: self:setLookUpQuery(<cField>, <aFields>, <cQuery>, <lIsRequired>) → nil

Exemplos completos com padrão LookUp:

Bloco de código

title	Exemplo 1 - padrão LookUp - Valores setados manualmente
collapse	true

#include "msobject.ch"
#include "protheus.ch"
#include "totvs.framework.treports.integratedprovider.th"
 
namespace custom.materiais.produtos.integratedprovider.lookup
 
@totvsFrameworkTReportsIntegratedProvider(active=.T., team="SIGACOM", tables="SB1", name="Produtos do Protheus", country="ALL", initialRelease="12.1.2210")
class SB1TReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider
    public method new() as object
    public method getDisplayName() as character
    public method getDescription() as character
    public method getData() as object
    public method getSchema() as object
endclass
 
method new() class SB1TReportsBusinessObject
_Super:new()
self:appendArea("Compras")
self:setIsLookUp(.T.)
return self
 
method getDisplayName() as character class SB1TReportsBusinessObject
return "Produtos"
 
method getDescription() as character class SB1TReportsBusinessObject
return "Produtos do Protheus"
 
method getData(nPage as numeric, oFilter as object) as object class SB1TReportsBusinessObject
local cQuery as character
local cAlias as character
local oExec as object
 
cQuery := "SELECT B1_FILIAL, B1_COD, B1_DESC, B1_TIPO, B1_UM, B1_UREV FROM " + RetSQLName("SB1") + " WHERE D_E_L_E_T_ = ' '"
 
//Os filtros serão setados na interface do novo TReports
if oFilter:hasFilter()
    cQuery += " AND " + oFilter:getSQLExpression()
endif

oExec  := FwExecStatement():New(ChangeQuery(cQuery))
cAlias := oExec:OpenAlias()  

while !(cAlias)->(Eof())
    cDate := iif(!empty((cAlias)->B1_UREV)), FwTimeStamp(5, StoD((cAlias)->B1_UREV), "00:00:00"), nil)
    self:appendData({"Filial": (cAlias)->B1_FILIAL,; 
            "Codigo": (cAlias)->B1_COD,; 
            "Descricao": (cAlias)->B1_DESC,;
            "Tipo": (cAlias)->B1_TIPO, ;
            "Unidade": (cAlias)->B1_UM, ;
            "Revisao": cDate})
    (cAlias)->(DBSkip())
enddo
 
(cAlias)->(DBCloseArea()) 
 
return self:oData
 
method getSchema() as object class SB1TReportsBusinessObject
local cField as character
local aStruct as array
local lIsRequired as logical
Local aDescriptor as array
Local nFieldReturn as numeric

//Seta a descrição da consulta
self:setDescriptor("Código","Código do Produto", "Descrição")

cComboFil := "D MG 01=Filial BH; D MG 02=Filial Uberaba; D RJ 01 =Filial RJ"

self:aliasToSchema("SB1", {"B1_FILIAL", "B1_COD"})
self:addProperty("Descricao", "Descricao", "string", "Descricao","B1_DESC")
self:addProperty("Tipo", "Tipo", "string", "Tipo","B1_TIPO")
self:addProperty("Unidade", "Unidade de medida", "string", "Unidade","B1_UM") 
self:addProperty("Revisao", "Revisao", "date", "revisao","B1_UREV") 
self:addProperty("Camp Log", "Camp Log", "boolean", "Camp Lógico","B1_LOGI")

cField := "B1_COD"
aStruct := {}
aAdd(aStruct, {"ATF0510001", "ATFA036 EMISSAO DE NOTA EM LOT"})
aAdd(aStruct, {"0003","PRODUTO PADRAO"})
aAdd(aStruct, {"EST00000000000000000000001GGGR","'PRODTO ESTOQUE GRADE EAI INTE"})
lIsRequired := .F.
aDescriptor := {"Codigo","Descrição"}
nFieldReturn := 1
//Seta os valores para o Lookup
self:setLookUpVal(cField, aStruct, lIsRequired, aDescriptor, nFieldReturn)

return self:oSchema

Bloco de código

title	Exemplo 2 - padrão LookUp - SX5
collapse	true

#include "msobject.ch"
#include "protheus.ch"
#include "totvs.framework.treports.integratedprovider.th"

namespace custom.financeiro.fornecedores.integratedprovider.lookup

@totvsFrameworkTReportsIntegratedProvider(active=.T., team="SIGAFIN", tables="SA2", name="Fornecedores", country="ALL", initialRelease="12.1.2210")
class SA2TReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider
    public method new() as object
    public method getAreas() as array
    public method getDescription() as character
    public method getData() as object
    public method getSchema() as object
endclass

method new() as object class SA2TReportsBusinessObject
_Super:new()
self:setDisplayName("Fornecedores")
self:setIsLookUp(.T.)
return self

method getDescription() as character class SA2TReportsBusinessObject
return "Fornecedores do Protheus"

method getAreas() as array class SA2TReportsBusinessObject
return {"Financeiro", "Contas a pagar"}

method getData(nPage as numeric, oFilter as object) as object class SA2TReportsBusinessObject
local cQuery as character
local cAlias as character
local oExec as object

cQuery := "SELECT * FROM " + RetSqlName('SA2') + " WHERE D_E_L_E_T_ = ' '"

if oFilter:hasFilter()
    cQuery += " AND " + oFilter:getSQLExpression()
endif

oExec  := FwExecStatement():New(ChangeQuery(cQuery))
cAlias := oExec:OpenAlias()  

while !(cAlias)->(Eof())
    self:appendData({"Nome": (cAlias)->A2_NOME,;
            "Codigo": (cAlias)->A2_COD,;
            "Estado": (cAlias)->A2_EST})
    (cAlias)->(DBSkip())
enddo

(cAlias)->(DBCloseArea())

return self:oData

method getSchema() as object class SA2TReportsBusinessObject

self:addProperty("Nome", "Nome do Fornecedor", "string", "Nome","A2_NOME")
self:addProperty("Codigo", "Código do Fornecedor", "string", "Código", "A2_COD")
self:addProperty("Estado", "Sigla da Federacao", "string", "Estado", "A2_EST")
//Seta o lookup a partir de uma tabela da SX5
self:setX5Struct("A2_EST", "12", .F.)

return self:oSchema

Bloco de código

title	Exemplo 3 - padrão LookUp - Query
collapse	true

#include "msobject.ch" 
#include "totvs.framework.treports.integratedprovider.th"

namespace custom.financeiro.naturezas.integratedprovider.lookup

@totvsFrameworkTReportsIntegratedProvider(active=.T., team="SIGAFIN", tables="SED", name="Naturezas", country="ALL", initialRelease="12.1.2210") 
class SEDTReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider
    public method new() as object
    public method getDisplayName() as character
    public method getAreas() as array
    public method getData() as object
    public method getSchema() as object
endclass

method new() as object class SEDTReportsBusinessObject
_Super:new()
self:setDescription("Naturezas financeiras do Protheus")
self:setIsLookUp(.T.)
return self

method getDisplayName() as character class SEDTReportsBusinessObject
return "Naturezas"

method getAreas() as array class SEDTReportsBusinessObject
return {"Financeiro"}

method getData(nPage as numeric, oFilter as object) as object class SEDTReportsBusinessObject
self:oData:aliasToData("SED", oFilter)
return self:oData

method getSchema() as object class SEDTReportsBusinessObject
local cQuery as character
local aFields as array
Local aDescriptor as array
Local cReturn as character
Local cOrder as character

self:oSchema:aliasToSchema("SED")

cQuery := "SELECT * FROM "+ RetSQLName("SED") +" WHERE D_E_L_E_T_ = ' '"
//cQuery := "SELECT ED_CODIGO, ED_DESCRIC FROM "+ RetSQLName("SED") +" WHERE D_E_L_E_T_ = ' '"
aFields := {"ED_CODIGO", "ED_DESCRIC"}
aDescriptor := {"Codigo", "Descrição"}
cReturn := "ED_CODIGO"
cOrder := "ED_DESCRIC"
//Seta o lookup a partir da query
self:oSchema:setLookUpQuery("ED_CODIGO", aFields, cQuery, .F., aDescriptor, cReturn, cOrder)

return self:oSchema

Exemplo do padrão LookUp na interface:

Image Added

Log para os Filtros do Smart View

Foi criada a chave

Tooltip

appendIcon	No Icon
linkText	fw-smartview-debug

Antiga chave fw-treports-debug

para mandar mensagens para o console e ajudar a identificar erros relacionados aos filtros enviados ao Smart View.

O log de debug somente é ativado pela chave no environment:

Tooltip

linkTextStrong	true
appendIcon	Kein Icon
linkText	fw-smartview-debug

Antiga chave fw-treports-debug

=1

Paginação no Objeto de Negócio

Aviso
Funcionalidade disponível a partir da LIB Label 20220613

Para facilitar a construção do Objeto de Negócio e melhorar a performance foi implementada a paginação na fonte de dados, além de simplificar a forma como ele é construído.

Com isso o desenvolvedor consegue indicar quantos itens serão enviados ao Smart View por requisição.

Método self:setPageSize()

Seta a quantidade de itens por página.

Nota
A partir da lib 20240408 esse método esta depreciado.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
nPageSize	Númerico	X	100	Indica a quantidade de itens por requisição

Exemplo de uso:

Bloco de código
self:setPagesize(nPageSize)

Sintaxe: self:setPagesize(<nPageSize>) → nil

...

Método self:getPageSize()

Retorna a quantidade de itens por requisição.

Exemplo de uso:

Bloco de código
self:getPagesize()

Sintaxe: self:getPagesize() → self:nPageSize

...

Método self:setQuery()

Seta a query do objeto de negócio.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
cQuery	Caracter	X		Indica a query do objeto de negócio

Aviso

title	Observações Importantes

Se não forem enviados todos os campos (Exemplo: SELECT * FROM) deverá ser usado o ID #QueryFields# e os campos setados serão aqueles recuperados do método getSchema().
É possível escrever a query e setar o where dela posteriormente com o método self:setWhere(), para isso deverá ser utilizado o ID #QueryWhere# após o Where da query.

Exemplo de uso:

Bloco de código
cQuery := "SELECT * FROM " + RetSQLName("SB1") + " WHERE B1_FILIAL = '"+ FWxFilial('SB1') +"' AND D_E_L_E_T_ = ' ' self:setQuery(cQuery)

Bloco de código
cQuery := "SELECT #QueryFields# FROM " + RetSQLName("SB1") + " WHERE B1_FILIAL = '"+ FWxFilial('SB1') +"' AND D_E_L_E_T_ = ' ' self:setQuery(cQuery)

Bloco de código

cQuery := "SELECT #QueryFields# FROM " + RetSQLName("SB1") + "WHERE #QueryWhere#" //Usa o ID #QueryWhere# para setar o where posteriormente
self:setQuery(cQuery)
self:setWhere("B1_FILIAL = '"+ FWxFilial('SB1') +"' AND D_E_L_E_T_ = ' '")

Sintaxe: self:setQuery(<cQuery>) → nil

...

Método self:setWhere()

Seta o where da query.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
cWhere	Caracter	X		Indica o where da query

Exemplo de uso:

Bloco de código
self:setWhere("B1_FILIAL = '"+ FWxFilial('SB1') +"' AND D_E_L_E_T_ = ' '")

Sintaxe: self:setWhere(<cWhere>) → nil

...

Método self:setOrder()

Seta o campo de ordenação da query.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
cOrder	Caracter	X	Primeiro campo indicado no método getSchema()	Indica o campo de ordenação

Exemplo de uso:

Bloco de código
self:setOrder("B1_COD")

Sintaxe: self:setOrder(<cOrder>) → nil

...

Método self:setHasNext()

Seta se terá próxima página.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
lHasNext	Lógico	X	.F.	Indica se terá próxima página

Exemplo de uso:

Bloco de código
self:setHasNext(.T.)

Sintaxe: self:setHasNext(<lHasNext>) → nil

Exemplos completos de Objetos de Negócios em TLPP

Bloco de código

title	Exemplo completo - Query - Paginação automática
collapse	true

#include "msobject.ch"
#include "totvs.framework.treports.integratedprovider.th"
 
namespace custom.materiais.produtos.integratedprovider

@totvsFrameworkTReportsIntegratedProvider(active=.T., team="SIGACOM", tables="SB1", name="Materiais", country="ALL", initialRelease="12.1.2210")
class SB1TReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider
    public method new() as object
    public method getData() as object
    public method getSchema() as object
endclass
 
method new() class SB1TReportsBusinessObject
_Super:new()
//Define a Área
self:appendArea("Compras")

//Define o nome do Objeto de Negócio
self:setDisplayName("Produtos")

//Define a descrição do Objeto de Negócio
self:setDescription("Produtos do Protheus")

return self

method getData() as object class SB1TReportsBusinessObject
local cQuery as character

//Define a quantidade máxima por página (Default 100)
self:setPageSize(200)

//Define a query do Objeto de Negócio
cQuery := "SELECT #QueryFields# FROM " + RetSQLName("SB1") +  " WHERE #QueryWhere#"
self:setQuery(cQuery)

//Define o campo de ordenação da query
self:setOrder("B1_COD")

//Define o where da query
self:setWhere("B1_FILIAL = '"+ FWxFilial('SB1') +"' AND D_E_L_E_T_ = ' '") 

return self:oData
 
method getSchema() as object class SB1TReportsBusinessObject

self:addProperty("Filial", "Filial", "string", "Filial", "B1_FILIAL")
self:addProperty("Codigo", "Codigo", "string", "Código", "B1_COD")
self:addProperty("Descricao", "Descricao", "string", "Descricao","B1_DESC")
self:addProperty("Tipo", "Tipo", "string", "Tipo","B1_TIPO")
self:addProperty("Unidade", "Unidade de medida", "string", "Unidade","B1_UM")
self:addProperty("Revisao", "Revisao", "date", "Revisao","B1_UREV")

return self:oSchema

Bloco de código

title	Exemplo completo - AliasToData - Paginação automática
collapse	true

#include "msobject.ch"
#include "totvs.framework.treports.integratedprovider.th"
 
namespace custom.materiais.produtos.integratedprovider

@totvsFrameworkTReportsIntegratedProvider(active=.T., team="SIGACOM", tables="SB1", name="Materiais", country="ALL", initialRelease="12.1.2210") 
class SB1TReportsBusinessObjectData from totvs.framework.treports.integratedprovider.IntegratedProvider
    public method new() as object
    public method getData() as object
    public method getSchema() as object
endclass
 
method new() class SB1TReportsBusinessObjectData
_Super:new()

//Define a Área
self:appendArea("Compras")

//Define o nome do Objeto de Negócio
self:setDisplayName("Produtos")

//Define a descrição do Objeto de Negócio
self:setDescription("Produtos do Protheus")

return self

method getData(nPage as numeric, oFilter as object) as object class SB1TReportsBusinessObjectData
//Define a quantidade máxima por página (Default 100)
self:setPageSize(500) //Setar antes de fazer o aliasToData()

self:aliasToData("SB1", oFilter)

return self:oData
 
method getSchema() as object class SB1TReportsBusinessObjectData
self:aliasToSchema("SB1")

return self:oSchema

Bloco de código

title	Exemplo completo - Paginação manual
collapse	true

#include "msobject.ch"
#include "protheus.ch"
#include "totvs.framework.treports.integratedprovider.th"
  
namespace custom.materiais

@totvsFrameworkTReportsIntegratedProvider(active=.T., team="SIGACOM", tables="SB1", name="Materiais", country="ALL", initialRelease="12.1.2210")
class SB1TReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider
    public method new() as object
    public method getDisplayName() as character
    public method getDescription() as character
    public method getData() as object
    public method getSchema() as object
endclass
  
method new() class SB1TReportsBusinessObject
_Super:new()
self:appendArea("Materiais - KeyLabel")
//Seta o lookup do campo do tipo combobox
self:setIsCBoxLookup(.T., .T.)
return self
  
method getDisplayName() as character class SB1TReportsBusinessObject
return "Produtos"
  
method getDescription() as character class SB1TReportsBusinessObject
return "Produtos do Protheus"
  
method getData(nPage as numeric, oFilter as object) as object class SB1TReportsBusinessObject
local cQuery as character
local cAlias as character
local nSkip as numeric
local nEnd as numeric
local nCount as numeric
local oExec as object

nCount := 0  
cQuery := "SELECT B1_FILIAL, B1_COD, B1_DESC, B1_TIPO, B1_UM, B1_UREV, B1_FILIAL, B1_PRV1 FROM " + RetSQLName("SB1") + " WHERE D_E_L_E_T_ = ' '"
  
//Os filtros serão setados na interface do novo TReports
if oFilter:hasFilter()
    cQuery += " AND " + oFilter:getSQLExpression()
endif

oExec  := FwExecStatement():New(ChangeQuery(cQuery))
cAlias := oExec:OpenAlias()  

//Seta a quantidade de itens por página (Default 100)
self:setPageSize(15)  //Posiciona o conteúdo da query

if nPage > 1
    //Encontra a quantidade de itens que irá pular de acordo com a página atual
    nSkip := ((nPage - 1) * self:getPageSize())       

    (cAlias)->(dbSkip(nSkip))
endif    

while !(cAlias)->(Eof())
    cDate := iif(!empty((cAlias)->B1_UREV), FwTimeStamp(5, StoD((cAlias)->B1_UREV), "00:00:00"), nil)
    self:oData:appendData({"Filial": (cAlias)->B1_FILIAL,;
            "Codigo": (cAlias)->B1_COD,;
            "Descricao": (cAlias)->B1_DESC,;
            "Tipo": (cAlias)->B1_TIPO, ;
            "Unidade": (cAlias)->B1_UM, ;
            "Revisao": cDate ,;
            "Preco": (cAlias)->B1_PRV1})
    (cAlias)->(DBSkip())
	nCount++

 	//Sai do loop quando chegar no tamanho de itens da página
    if nCount == self:getPageSize()
      exit
    endif
enddo  

//Se não for o último registro indica que terá próxima página
self:setHasNext(!(cAlias)->(Eof()))  

(cAlias)->(DBCloseArea())
  
return self:oData
  
method getSchema() as object class SB1TReportsBusinessObject
local cComboFil as character
 
cComboFil := "D MG 01=Filial BH; D MG 02=Filial Uberaba"
 
self:addProperty("Filial", "Filial", "string", "Filial", "B1_FILIAL", cComboFil,.F.)
self:addProperty("Codigo", "Codigo", "string", "Codigo", "B1_COD")
self:addProperty("Descricao", "Descricao", "string", "Descricao","B1_DESC")
self:addProperty("Tipo", "Tipo", "string", "Tipo","B1_TIPO")
self:addProperty("Unidade", "Unidade de medida", "string", "Unidade","B1_UM")
self:addProperty("Revisao", "Revisao", "date", "revisao","B1_UREV")
self:addProperty("Data", "Data", "date", "Data","B1_UREV")
self:addProperty("Preco", "Preço", "number", "Preço","B1_PRV1")

return self:oSchema

Bloco de código

title	Exemplo completo - Paginação e Tratamento de dados LGPD
collapse	true

#include "msobject.ch"
#include "protheus.ch"
#include "totvs.framework.treports.integratedprovider.th"
   
namespace custom.materiais

@totvsFrameworkTReportsIntegratedProvider(active=.T., team="SIGACOM", tables="SA5, SB1", name="Produto X Fornecedor", country="ALL", initialRelease="12.1.2210")
//-------------------------------------------------------------------
/*{Protheus.doc} MATR190TReportsBusinessObject
Classe para criação do Objeto de Negócio de Prod  x Forn para o TReports

@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------   
class MATR190TReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider
    public method new() as object
    public method getDisplayName() as character
    public method getDescription() as character
    public method getData() as object
    public method getSchema() as object

    protected data aFields as array
    protected data aStruct as array

endclass

//-------------------------------------------------------------------
/*{Protheus.doc} new
Método de instância da classe

@return object: self

@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------    
method new() class MATR190TReportsBusinessObject
_Super:new()
self:appendArea("Compras")

self:aFields := {"A5_FILIAL", "A5_FORNECE", "A5_LOJA", "A5_NOMEFOR", "A5_PRODUTO", "A5_NOMPROD", "A5_CODPRF", "B1_TIPO", "B1_PESO"}
self:aStruct := getStruct(self:aFields)

return self

//-------------------------------------------------------------------
/*{Protheus.doc} getDisplayName
Retorna o nome de exibição do objeto de negócio

@return string

@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------    
method getDisplayName() as character class MATR190TReportsBusinessObject
return "Produtos x Fornecedores"

//-------------------------------------------------------------------
/*{Protheus.doc} getDescription
Retorna a descrição do objeto de negócio

@return string

@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------   
method getDescription() as character class MATR190TReportsBusinessObject
return "Produtos x Fornecedores"

//-------------------------------------------------------------------
/*{Protheus.doc} getData
Retorna os dados do objeto de negócio

@param nPage, numérico, indica a página atual do relatório
@param oFilter, objeto, contém o filtro do TReports

@return object: self:oData

@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------    
method getData(nPage as numeric, oFilter as object) as object class MATR190TReportsBusinessObject
local cQuery as character
local cAlias as character
local nSkip as numeric
local nCount as numeric
local nX as numeric
local jItems as json
local aPDFields as array
local oExec as object
 
nCount := 0  
cQuery := "SELECT " + self:getSQLFields(,,,.T.) + " FROM" + RetSQLName("SA5")
cQuery += " SA5 LEFT JOIN " + RetSQLName("SB1") + " SB1 ON SB1.B1_COD = SA5.A5_PRODUTO WHERE SB1.D_E_L_E_T_ = ' ' AND SA5.D_E_L_E_T_ = ' '"  

//Os filtros serão setados na interface do novo TReports
if oFilter:hasFilter()
    cQuery += " AND " + oFilter:getSQLExpression()
endif

oExec  := FwExecStatement():New(ChangeQuery(cQuery))
cAlias := oExec:OpenAlias()  
 
if nPage > 1
    //Encontra a quantidade de itens que irá pular de acordo com a página atual
    nSkip := ((nPage - 1) * self:getPageSize())      
 
    (cAlias)->(dbSkip(nSkip))
endif   

//Verifica se precisa fazer o tratamento para LGPD
aPDFields := FwProtectedDataUtil():UsrAccessPDField(__cUserID, self:aFields)
lObfuscated := len( aPDFields ) != Len(self:aFields) 

while !(cAlias)->(Eof())
    jItems := JsonObject():new()

    for nX := 1 To Len(self:aStruct)
        if lObfuscated .and. aScan(aPDFields, self:aStruct[nX][5]) == 0
            jItems[self:aStruct[nX][1]] := FwProtectedDataUtil():ValueAsteriskToAnonymize((cAlias)->&(self:aStruct[nX][5]))
        else
            jItems[self:aStruct[nX][1]] := (cAlias)->&(self:aStruct[nX][5])
        endif
    next nX

    self:oData:appendData(jItems)

    (cAlias)->(DBSkip())
    nCount++
 
    //Sai do loop quando chegar no tamanho de itens da página
    if nCount == self:getPageSize()
      exit
    endif
enddo  
 
//Se não for o último registro indica que terá próxima página
self:setHasNext(!(cAlias)->(Eof()))  
 
(cAlias)->(DBCloseArea())
   
return self:oData

//-------------------------------------------------------------------
/*{Protheus.doc} getSchema
Retorna a estrutura dos campos

@return object: self:oSchema

@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------    
method getSchema() as object class MATR190TReportsBusinessObject
Local nX as numeric

for nX := 1 To Len(self:aStruct)
    self:addProperty(self:aStruct[nX][1], self:aStruct[nX][2], self:aStruct[nX][3], self:aStruct[nX][4], self:aStruct[nX][5])
Next nX
 
return self:oSchema

//-------------------------------------------------------------------
/*{Protheus.doc} getStruct
Prepara a estrutura dos campos

@param aCpos array: Array com os campos do relatório

@return array: Array com a estrutura dos campos

@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------  
function getStruct(aCpos)
Local aDeParaCpo as array
Local aCpoTmp    as array
Local cCampo     as character
Local cCpoQry    as character
Local cTipR      as character
Local nPos       as numeric
Local nC         as numeric

aDeParaCpo := {{"C", "string"}, {"D", "date"}, {"N", "number"}, {"L", "boolean"}}
aCpoTmp    := {}

for nC := 1 to Len(aCpos)
    cCpoQry := aCpos[nC]
    nPos    := AT(".", aCpos[nC]) + 1
    
    if nPos > 0
        cCampo := Substr(cCpoQry, nPos)
    else
        cCampo := cCpoQry
    endif
    
    cTipo := GetSx3Cache(cCampo, "X3_TIPO")
    
    if (nPos := aScan(aDeParaCpo, {|c| c[01] = cTipo})) > 0
        cTipR := aDeParaCpo[nPos, 02]
    else
        cTipR := "string"
    endif

    AAdd(aCpoTmp, {cCampo, FWSX3Util():GetDescription(cCampo), cTipR, FWSX3Util():GetDescription(cCampo), cCampo})
next nC

return (aCpoTmp)

Informações
Parâmetros nativos nos Objeto de Negócio disponíveis a partir da LIB Label 20230515

Bloco de código

title	Exemplo completo - Objeto de negócio com parâmetros nativos SX1
collapse	true

#include "msobject.ch"
#include "totvs.framework.treports.integratedprovider.th"
#include "tlpp-core.th"
#include "tlpp-rest.th"

namespace totvs.protheus.rh.treportsintegratedprovider   

@totvsFrameworkTReportsIntegratedProvider(active=.T., team="Framework", tables="SRA", name="Funcionários", country="ALL", initialRelease="12.1.2310") 
class SRA2TReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider
    public method new() as object
    public method getAreas() as array
    public method getDescription() as character
    public method getData() as object
    public method getSchema() as object

    data lExistPergunte as logical 
endclass
 
method new() as object class SRA2TReportsBusinessObject
    _Super:new()
    self:setDisplayName("Funcionários")
	self:lExistPergunte := self:setPergunte("GPER140") //Indica o pergunte que será utilizado no relatório GPER140     
    if !self:lExistPergunte 
    	if !self:setErrorStatus(400,"Sem Pergunte","Verifique o grupo de perguntas informado!")
        	FwLogMsg("WARN",, "SmartView",,, , "Codigo de erro invalido, aceito somente codigos de erro 4xx", , ,)
        endif
        FwLogMsg("WARN",, "SmartView",,, , "Grupo de perguntas nao encontrado", , ,)   
    endif

return self
 
method getDescription() as character class SRA2TReportsBusinessObject
return "Funcionários"
 
method getAreas() as array class SRA2TReportsBusinessObject
return {"RH"}
 
method getData(nPage as numeric, oFilter as object) as object class SRA2TReportsBusinessObject
local cQuery as character   
local jParams as json
local cWhere as character

if !self:lExistPergunte //retorno do método SetPergunte()
    return self:oData
else
	jParams := oFilter:getParameters() //metodo para retorno do json dos parâmetros

	cWhere := " D_E_L_E_T_ = ' '"

	//MV_PAR04 é multivalue
	if Len(jParams['MV_PAR04']) > 0
    	cWhere += " AND RA_MAT IN ('" + ArrTokStr(jParams['MV_PAR04'], "','") + "')"
	endif

	cQuery := "SELECT #QueryFields# FROM " + RetSQLName("SRA") +  " WHERE #QueryWhere#"

	//Define a quantidade máxima por página (Default 100)
	self:setPageSize(500)
	//Define a query do Objeto de Negócio
	self:setQuery(cQuery)
	//Define o campo de ordenação da query
	self:setOrder("RA_MAT")

	//Define o where da query
	self:setWhere(cWhere) 
endif

return self:oData
 
method getSchema() as object class SRA2TReportsBusinessObject
    self:aliasToSchema("SRA" , {"RA_NOME", "RA_FILIAL", "RA_MAT", "RA_EMAIL", "RA_ADMISSA"})
return self:oSchema

Bloco de código

title	Exemplo completo - Objeto de negócio com parâmetros nativos manuais
collapse	true

#include "msobject.ch"
#include "totvs.framework.treports.integratedprovider.th"
#include "tlpp-core.th"
#include "tlpp-rest.th"

namespace totvs.protheus.rh.treportsintegratedprovider
 
@totvsFrameworkTReportsIntegratedProvider(active=.T.)
class SRA2TReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider
    public method new() as object
    public method getAreas() as array
    public method getDescription() as character
    public method getData() as object
    public method getSchema() as object
endclass
 
method new() as object class SRA2TReportsBusinessObject
    _Super:new()
    self:setDisplayName("Funcionários")
return self
 
method getDescription() as character class SRA2TReportsBusinessObject
return "Funcionários"
 
method getAreas() as array class SRA2TReportsBusinessObject
return {"RH"}
 
method getData(nPage as numeric, oFilter as object) as object class SRA2TReportsBusinessObject
local cQuery as character   
local jParams as json
local cWhere as character

jParams := oFilter:getParameters() //metodo para retorno do json dos parâmetros

cWhere := " D_E_L_E_T_ = ' '"

cQuery := "SELECT #QueryFields# FROM " + RetSQLName("SRA") +  " WHERE #QueryWhere#"

//Define a quantidade máxima por página (Default 100)
self:setPageSize(500)
//Define a query do Objeto de Negócio
self:setQuery(cQuery)
//Define o campo de ordenação da query
self:setOrder("RA_MAT")

//Define o where da query
self:setWhere(cWhere) 
return self:oData
 
method getSchema() as object class SRA2TReportsBusinessObject
    self:aliasToSchema("SRA" , {"RA_NOME", "RA_FILIAL", "RA_MAT", "RA_EMAIL", "RA_ADMISSA"})
	self:addParameter("logico","logico","boolean", .F.) //Adicionando o parâmetro manual 
return self:oSchema

Bloco de código

title	Exemplo completo - Objeto de negócio com parâmetros nativos manuais do tipo data e campo manual
collapse	true

#include "protheus.ch"
#include "msobject.ch"
#include "totvs.framework.treports.integratedprovider.th"
    
namespace custom.produtos.fornecedores
 
@totvsFrameworkTReportsIntegratedProvider(active=.T., team="SIGACOM", tables="SA5", name="Produto X Fornecedor", country="ALL", initialRelease="12.1.2310")
//-------------------------------------------------------------------
/*{Protheus.doc} ProdFornTReportsBusinessObject
Classe para criação do Objeto de Negócio de Prod  x Forn para o TReports
 
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------  
class ProdFornTReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider
    public method new() as object
    public method getData() as object
    public method getSchema() as object
 
    protected data aFields as array
    protected data aStruct as array
 
endclass
 
//-------------------------------------------------------------------
/*{Protheus.doc} new
Método de instância da classe
 
@return object: self
 
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------   
method new() class ProdFornTReportsBusinessObject
_Super:new()
self:appendArea("Compras")
self:setDisplayName("Fornecedores x Produtos")
self:setDescription("Relatório Fornecedores x Produtos com tratamento LGPD")
 
self:aFields := {"A5_FILIAL", "A5_FORNECE", "A5_LOJA", "A5_NOMEFOR", "A5_PRODUTO", "A5_NOMPROD", "A5_CODPRF", "A5_DTCOM01", "A5_QUANT01"}
self:aStruct := u_getStruct(self:aFields)
 
return self
 
//-------------------------------------------------------------------
/*{Protheus.doc} getData
Retorna os dados do objeto de negócio
 
@param nPage, numérico, indica a página atual do relatório
@param oFilter, objeto, contém o filtro do TReports
 
@return object: self:oData
 
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------   
method getData(nPage as numeric, oFilter as object) as object class ProdFornTReportsBusinessObject
local cQuery as character
local cAlias as character
local nSkip as numeric
local nCount as numeric
local nX as numeric
local jItems as json
local aPDFields as array
local lUseParams as logical
  
nCount := 0
cQuery := "SELECT " + self:getSQLFields(,,,.T.) + "FROM " + RetSQLName("SA5") + " WHERE D_E_L_E_T_ = ' '"
lUseParams := .T.

//Os filtros serão setados na interface do novo TReports
if oFilter:hasFilter()
    cQuery += " AND " + oFilter:getSQLExpression()
endif

jParams := oFilter:getParameters() //metodo para retorno do json dos parâmetros
u_setDefaultParams(@jParams)
//Faz a parametrização na query
cQuery += "AND A5_FORNECE BETWEEN ? AND ? AND A5_DTCOM01 >= ? AND A5_DTCOM01 <= ?"

oExec  := FwExecStatement():New(ChangeQuery(cQuery))
oExec:setString(1, jParams['01'][1])
oExec:setString(2, jParams['02'][1])
//Formato da data recebida pelo smart view: 2020-07-02T00:00:00-03:00, temos que fazer a conversão para a query
oExec:setDate(3, StoD( SubStr(StrTran(jParams['03'][1],"-",""),1,8) ))
oExec:setDate(4, StoD( SubStr(StrTran(jParams['04'][1],"-",""),1,8) ))
cAlias := oExec:OpenAlias()
  
if nPage == 1
    (cAlias)->(dbGoTop())
else
    //Encontra a quantidade de itens que irá pular de acordo com a página atual
    nSkip := ((nPage - 1) * self:getPageSize())     
  
    (cAlias)->(dbSkip(nSkip))
endif  
  
//Verifica se precisa fazer o tratamento para LGPD
aPDFields := FwProtectedDataUtil():UsrAccessPDField(__cUserID, self:aFields)
lObfuscated := len( aPDFields ) != Len(self:aFields)

while !(cAlias)->(Eof())
    jItems := JsonObject():new()
 
    for nX := 1 To Len(self:aStruct)
        if lObfuscated .and. aScan(aPDFields, self:aStruct[nX][5]) == 0
            if self:aStruct[nX][3] == "date"
                jItems[self:aStruct[nX][1]] := nil
            elseif  self:aStruct[nX][3] == "number"
                jItems[self:aStruct[nX][1]] := Val( Replicate( "9", Len((cAlias)->&(self:aStruct[nX][5])) ) )
            else
                jItems[self:aStruct[nX][1]] := FwProtectedDataUtil():ValueAsteriskToAnonymize((cAlias)->&(self:aStruct[nX][5]))
            endif
        elseif self:aStruct[nX][3] == "date"
            jItems[self:aStruct[nX][1]] := totvs.framework.treports.date.stringToTimeStamp((cAlias)->&(self:aStruct[nX][5]))
        else
            jItems[self:aStruct[nX][1]] := (cAlias)->&(self:aStruct[nX][5])

            //Monta os valores do campo Demanda
            if self:aStruct[nX][1] == "A5_QUANT01"
                if jItems[self:aStruct[nX][1]] <= 50
                    jItems["Demanda"] := "Demanda baixa"
                elseif jItems[self:aStruct[nX][1]] <= 1000
                    jItems["Demanda"] := "Demanda média" 
                else //Maior que 1000
                    jItems["Demanda"] := "Demanda alta"
                endif
            endif
        endif
    next nX
 
    self:oData:appendData(jItems)
 
    (cAlias)->(DBSkip())
    nCount++
  
    //Sai do loop quando chegar no tamanho de itens da página
    if nCount == self:getPageSize()
      exit
    endif
enddo 
  
//Se não for o último registro indica que terá próxima página
self:setHasNext(!(cAlias)->(Eof())) 
  
(cAlias)->(DBCloseArea())
    
return self:oData
 
//-------------------------------------------------------------------
/*{Protheus.doc} getSchema
Retorna a estrutura dos campos
 
@return object: self:oSchema
 
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------   
method getSchema() as object class ProdFornTReportsBusinessObject
Local nX as numeric
 
for nX := 1 To Len(self:aStruct)
    self:addProperty(self:aStruct[nX][1], self:aStruct[nX][2], self:aStruct[nX][3], self:aStruct[nX][4], self:aStruct[nX][5])
Next nX

self:addProperty("Demanda", "Demanda", "string", "Demanda do Produto", "Demanda")

self:addParameter("01"  , "Fornecedor de", "string", .F.)
self:addParameter("02"  , "Fornecedor até", "string", .F.)
self:addParameter("03"  , "Data de", "date", .F.)
self:addParameter("04"  , "Data até", "date", .F.)

//Consulta dos parâmetros
self:setCustomURL("01", "api/framework/v1/genericLookupService/smartview/SA2", 2)
self:setCustomURL("02", "api/framework/v1/genericLookupService/smartview/SA2", 2)
  
return self:oSchema
 
//-------------------------------------------------------------------
/*{Protheus.doc} getStruct
Prepara a estrutura dos campos
 
@param aFlds array: Array com os campos do relatório
 
@return array: Array com a estrutura dos campos
 
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//------------------------------------------------------------------- 
user function getStruct(aFlds)
Local aConvFld as array
Local aFldTmp    as array
Local cCampo     as character
Local cFldQry    as character
Local cTipR      as character
Local nPos       as numeric
Local nC         as numeric
 
aConvFld := {{"C", "string"}, {"D", "date"}, {"N", "number"}, {"L", "boolean"}, {"M", "memo"}}
aFldTmp    := {}
 
for nC := 1 to Len(aFlds)
    cFldQry := aFlds[nC]
    nPos    := AT(".", aFlds[nC]) + 1
     
    if nPos > 0
        cCampo := Substr(cFldQry, nPos)
    else
        cCampo := cFldQry
    endif
     
    cTipo := GetSx3Cache(cCampo, "X3_TIPO")
     
    if (nPos := aScan(aConvFld, {|c| c[01] = cTipo})) > 0
        cTipR := aConvFld[nPos, 02]
    else
        cTipR := "string"
    endif
 
    AAdd(aFldTmp, {cCampo, FWSX3Util():GetDescription(cCampo), cTipR, FwX3Titulo(Upper(cCampo)), cCampo})
next nC
 
return (aFldTmp)
 
//-------------------------------------------------------------------
/*{Protheus.doc} setDefaultParams
Seta os valores padrões do parâmetros caso estejam vazios
 
@param jParam json: Parâmetros recebidos

@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//------------------------------------------------------------------- 
user function setDefaultParams(jParams)

if empty(jParams['02'][1])
    jParams['02'][1] := "ZZZZZ"
elseif empty(jParams['03'][1])
    jParams := totvs.framework.treports.date.dateToTimeStamp(Date())
elseif empty(jParams['04'][1])
    jParams := totvs.framework.treports.date.dateToTimeStamp(Date())
endif
return

Objeto de negócio localizado

Temos uma documentação completa sobre como montar o objeto de negócio localizado, acessar o link: Smart View - Objeto de negócio Localizado

Páginas filhas

Histórico da Página

Versões comparadas

Versão antiga 2

Nova versão Atual

Chave

Objetivo

Utilização da Nova Classe

New()

GetSchema()

Exemplo de uso:

Índice

Objetivo e Vantagens do Objeto de Negócio em TLPP

Utilização da classe IntegratedProvider

Métodos

New()

Exemplo de uso:

GetData()

Parâmetros:

Exemplo de uso:

SetDisplayName()

Exemplo de uso:

GetDisplayName()

AppendArea()

Parâmetros:

GetAreas()

SetDescription()

GetDescription()

Exemplos completos:

Exemplos de uso:

GetSchema()

Exemplos de uso:

GetData()

Parâmetros:

Exemplos de uso:

SetDisplayName()

Exemplo de uso:

GetDisplayName()

AppendArea()

Parâmetros:

Exemplo de uso:

GetAreas()

SetDescription()

GetDescription()

SetPergunte()

Parâmetros:

Exemplo de uso:

SetErrorStatus()

Parâmetros:

Exemplo de uso:

SetCanFilter()

Parâmetros:

Exemplo de uso:

SetPropDisplayName()

Parâmetros:

Exemplo de uso:

Implementação do LookUp nos Filtros de campos

Padrão Key-Label

Método self:setIsCBoxLookup()

Parâmetros:

Exemplo de uso:

Método self:oSchema:setComboValues()

Parâmetros:

Utilização com o método addProperty() documentado acima

Exemplo de uso:

Exemplos completos com LookUp Key-Label:

Padrão LookUp

Método self:setIsLookup()

Parâmetros:

Exemplo de uso:

Método self:oSchema:setDescriptor()

Parâmetros:

Exemplo de uso:

Método self:oSchema:setLookUpVal()

Parâmetros:

Exemplo de uso:

Método self:oSchema:setX5Struct()

Parâmetros:

Exemplo de uso:

Método self:oSchema:setLookUpQuery()