Histórico da Página

Durante esse período (calamidade), o empregador poderá acordar no prazo de 90 dias . A a redução proporcional da jornada de trabalho e a redução de salário.

Devendo respeitar os seguintes requisitos:

• A preservação do salário hora de trabalho;
• Pactuação por acordo individual escrito entre as partes, que deverá ser encaminhada ao empregado com no mínimo de antecedência de 2 dias corridos corridos;
• Redução da jornada de trabalho e salário, exclusivamente nos seguintes percentuais : 25% , 50% , ou 70%.

A jornada de trabalho e o salário que era pago eram pagos anteriormente antes desse período (calamidade), serão restabelecidos, sendo:

• No prazo de dois dias corridos, contando da cessão do estado de calamidade pública;
• Na data estabelecida no acordo individual com termo de encerramento que foi realizado no período e redução pactuado pactuado;
• Na data de comunicação do empregador que informe ao empregado sobre a sua decisão de antecipar o fim do período de redução pactuado.

Alterações Procedimentos na Folha de Pagamento

Alteração Salarial

A Alteração salarial pode ser feita de forma individual diretamente no cadastro do funcionário ou através do processo global. Para funcionários de recebimento Mensal, é necessário que além da Jornada alterar o salário. Abaixo exemplificaremos usando a redução de 25%:

Passo 1: Criar um motivo de Alteração Salarial MP 936 em: RH | Folha de Pagamento | Administração de Pessoal | Cadastro Global | Tabelas Dinâmicas - (É opcional e fica a critério de cada Empresa)

Passo 2: Criar duas fórmulas para Alteração Salarial  e Jornada MP 936 conforme abaixo em: RH | Folha de Pagamento | Administração de Pessoal | Fórmulas

SE RC<=3135.00 ENTAO
    SE (RC*0.75)>SM ENTAO
    MAX( RC*0.75, SM) /*EXEMPLO REDUÇÃO SALARIO EM 25% */
    SENAO 0
    fimse
SENAO 0
FIMSE

SE RC<=3135.00 ENTAO
    SE (RC*0.75)>SM ENTAO
    (J*0.75)*60 /* REDUÇÃO JORNADA EM 25% */
    SENAO   0
SENAO 0
FIMSE

Passo 3 - Processar a Alteração Salarial / Jornada, informando o motivo e as fórmulas criadas acima: RH | Folha de Pagamento | Administração de Pessoal | Alterações Cadastrais | Alteração de Salários

Image Removed Image Removed

O processo irá processar a alteração retornando o log abaixo:

Image Removed

O histórico foi preenchido  e o salário/jornada do funcionário alterado:

Image Removed Image Removed

Cálculo de dias trabalhados

Ao calcular os dias/horas trabalhadas, o produto considera a referência passada para os eventos de Código de Cálculo 1 e Código de Cálculo 2. Como não houve alteração de Jornada no cadastro do Funcionário, o módulo Folha de Pagamento irá considerar 30 dias para evento tipo dia e 220:00 horas para evento tipo hora, por exemplo, pagando assim o salário integral sem considerar a Redução de Jornada acordada.

Caso o empregador faça a adesão a redução de jornada/salário deverá seguir os procedimentos abaixo:

01.  Cadastro do Funcionário | Dados "B.E.M."

Preencher os campos na aba B.E.M., eles serão necessários para informação da redução da jornada tanto para o eSocial como para o cálculo na folha.

Cálculo da Folha de Pagamento

Como não houve alteração de Jornada no Cadastro do Funcionário, o módulo Folha de Pagamento não irá calcular os dias trabalhados considerando a Redução de Jornada acordada para o cálculo de salário mensal. Neste contexto, orientamos os clientes a criarem uma verba complementar, para descontar o proporcional da redução da Jornada/Salário do funcionário, utilizando fórmula.

Para os funcionários que tiveram a jornada reduzida e foram feitas as apurações das horas trabalhadas pelo Módulo Automação de Ponto não ha necessidade de lançar a verba de desconto.

As orientações de como fazer a redução de jornada através do Módulo Automação de Ponto encontram-se no Link. Para essas empresas, será necessário a observância do usuário para a utilização do parâmetro "Desconsiderar % de redução no cálculo da jornada - MP 936/20 (Integração com TOTVS Automação de Ponto)":

Image Added

Caso utilizar integração com o Totvs Automação de Ponto e marcá-lo, o sistema não olhará o valor informado no campo "Percentual de Redução da Jornada" no Histórico do cadastro do B.E.M. para calcular a tag <qtdHrsSem> no evento S-2206.

Exemplo: Somando a jornada cadastrada no horário do funcionário, corresponde a um total de 20 horas semanais após a alteração do horário do funcionário para o período do B.E.M.. No campo de Percentual de Redução da Jornada foi informado o valor de 50%. Nesse caso será levado para a tag <qtdHrsSem> o valor de 20 horas semanais pois não irá considerar esse percentual no cálculo.

Caso utilizar integração com o Totvs Automação de Ponto e não marcá-lo, o sistema olhará o valor informado no campo "Percentual de Redução da Jornada" no Histórico do cadastro do B.E.M. para calcular a tag <qtdHrsSem> no evento S-2206.

Exemplo: Somando a jornada cadastrada no horário do funcionário, corresponde a um total de 20 horas semanais após a alteração do horário do funcionário para o período do B.E.M.. No campo de Percentual de Redução da Jornada foi informado o valor de 50%. Nesse caso será levado para a tag <qtdHrsSem> o valor de 10 horas semanais pois será aplicado novamente a redução de 50% sobre as horas semanais da jornada do funcionário.

Obs.: Caso a empresa não utilizar integração com o Totvs Automação de Ponto, sempre será considerado o campo "Percentual de Redução da Jornada" no Histórico do cadastro do B.E.M. para calcular a tag <qtdHrsSem> no evento S-2206.Para o cálculo de dias/horas trabalhados mensais, considerando  a jornada reduzida, iremos usar duas abordagens de cálculo, utilizando fórmulas. 

Como exemplo iremos considerar o Funcionário com que o funcionário tem o salário mensal de R$ 2000R$2.000,00, sendo o salário hora 9R$9,09 e Jornada de 220:00.

Antes de executar os passos abaixo, os campos criados na aba B.E.M. foram preenchidos considerando a redução de 25% da Jornada de trabalho, com data do acordo dia 13/04/2020:

Caso 1 - Referência do evento reduzidoLançar evento de desconto complemento

Neste caso poderá informar a referência do evento considerando a Jornada Reduzida e lançar um evento de desconto considerando o valor da redução. O evento de pagamento de Salário Mensal irá pagar de forma integral o salário. Assim, o módulo da Folha de Pagamento irá calcular os dias/horas trabalhados considerando a referência informada retornando o valor devido do salário Mensal. abater dos proventos o valor que foi reduzido.

A informação do valor no evento poderá ser feita através de Códigos Fixos, Entrada de dados, etc. ou poderá utilizar uma fórmula para calcular o valor considerando as informações do acordo preenchidos no cadastro do Funcionário.A informação da referência pode ser feito através da Entrada de dados, por exemplo, digitado manualmente a referência considerando a Jornada Reduzida ou então incluir fórmula de referência no evento do tipo Dia/Valor ou fórmula de hora no evento do tipo hora/referência para que seja calculada a referência considerando as informações do acordo da Redução de Jornada. 

Abaixo exemplificaremos uma sugestão de Fórmula quer retorna a referência em dias e horas: Referência em Dias

Fórmula criada e Criada a inserida no evento de Pagamento desconto de dias trabalhados. A mesma retorna a referência em dias: 

Mensalista ou Horista

DECL QUANTDIAS;
DECL QUANTDIASRETORNO;
DECL QUANTMES;
DECL DATARETORNO;
DECL JORMENSAL;
DECL PERC;
SETVAR (QUANTDIAS, SUBTRAIDATAS(TABFUNC('DTACORDOBEM','D'),MTDATA(01,MES,ANO)));
SETVAR (QUANTMES , TABFUNC('MESESDURACAOBEM','I'));
SETVAR (DATARETORNO, (TABFUNC('DTACORDOBEM','D')+ (QUANTMES*30)));
SETVAR (QUANTDIASRETORNO, SUBTRAIDATAS(MTDATA(30,MES,ANO), DATARETORNO));
SETVAR (JORMENSAL, TABFUNC('JORNADAMENSAL','I'));
SETVAR (PERC, TABFUNC('PERCENTUALREDUCAOBEM', 'I'));

SE QUANTDIAS > 0 E (TABFUNC('DTACORDOBEM','D') > MTDATA(01,MES,ANO) E TABFUNC('DTACORDOBEM','D') < MTDATA(30,MES,ANO));
(((JORMENSAL - (JORMENSAL * (PERC/100))) + (((JORMENSAL * (PERC/100))/ ND) * QUANTDIAS)) /(JORMENSAL/ND))
SENAO
SE QUANTDIASRETORNO > 0 E (DATARETORNO > MTDATA(01,MES,ANO) E DATARETORNO < MTDATA(30,MES,ANO));
(((JORMENSAL - (JORMENSAL * (PERC/100))) + (((JORMENSAL * (PERC/100))/ ND) * QUANTDIASRETORNO)) /(JORMENSAL/ND))
SENAO
SE QUANTDIAS < 0 E QUANTDIASRETORNO < 0;
(JORMENSAL - (JORMENSAL * (PERC/100))) /(JORMENSAL/ND)
SENAO
JORMENSAL/(JORMENSAL/ND)

A fórmula foi inserida no evento de CC 2, campo fórmula de referência: 

Image Removed

No cálculo do evento a fórmula foi executada, retornando a referência:

Image Removed

Fórmula associada ao evento que será lançado no envelope do Funcionário. No envelope lançou com a referência de 25,5 dias:

Image Removed

Referência em Horas

Fórmula criada e inserida no evento de horas trabalhadas

DECL QUANTDIAS;
DECL QUANTDIASRETORNO;
DECL QUANTMES;
DECL DATARETORNO;
DECL JORMENSAL;
DECL PERC;
SETVAR (QUANTDIAS, SUBTRAIDATAS(TABFUNC('DTACORDOBEM','D'),MTDATA(01,MES,ANO)));
SETVAR (QUANTMES , TABFUNC('MESESDURACAOBEM','I'));
SETVAR (DATARETORNO, (TABFUNC('DTACORDOBEM','D')+ (QUANTMES*30)));
SETVAR (QUANTDIASRETORNO, SUBTRAIDATAS(MTDATA(30,MES,ANO), DATARETORNO));
SETVAR (JORMENSAL, TABFUNC('JORNADAMENSAL','I'));
SETVAR (PERC, TABFUNC('PERCENTUALREDUCAOBEM', 'I'));

SE QUANTDIAS > 0 E (TABFUNC('DTACORDOBEM','D') > MTDATA(01,MES,ANO) E TABFUNC('DTACORDOBEM','D') < MTDATA(30,MES,ANO));
((JORMENSAL - (JORMENSAL * (PERC/100))) + (((JORMENSAL * (PERC/100))/ ND) * QUANTDIAS))
SENAO
SE QUANTDIASRETORNO > 0 E (DATARETORNO > MTDATA(01,MES,ANO) E DATARETORNO < MTDATA(30,MES,ANO));
((JORMENSAL - (JORMENSAL * (PERC/100))) + (((JORMENSAL * (PERC/100))/ ND) * QUANTDIASRETORNO)) 
SENAO
SE QUANTDIAS < 0 E QUANTDIASRETORNO < 0;
JORMENSAL - (JORMENSAL * (PERC/100))
SENAO
JORMENSAL

A fórmula foi inserida no evento de CC 1, campo fórmula de hora:

Image Removed

No cálculo de evento a fórmula é executada, retornando a referência:

Image Removed

Fórmula associada ao evento que será lançado no envelope do Funcionário. No envelope lançou com a referência de 187 horas:

Image Removed

Caso 2 - Lançar evento de desconto

Neste caso poderá lançar um evento de desconto considerando o valor da redução. O evento de pagamento de Salário Mensal irá pagar de forma integral o salário não utilizando a abordagem do caso 1. Assim, o módulo da Folha de Pagamento irá abater dos proventos o valor que foi reduzido e não irá reduzir a Jornada na referência do provento. 

A informação do valor no evento poderá ser feita através de Códigos Fixos, Entrada de dados, etc. ou poderá utilizar uma fórmula para calcular o valor considerando as informações do acordo preenchidos no cadastro do Funcionário.

Abaixo exemplificaremos uma sugestão de Fórmula:

Fórmula Criada a inserida no evento de desconto de dias trabalhados. 

DECL QUANTDIAS;
DECL QUANTDIASRETORNO;
DECL QUANTMES;
DECL DATARETORNO;
DECL PERC;
DECL SALRED;
SETVAR (QUANTDIAS, SUBTRAIDATAS(TABFUNC('DTACORDOBEM','D'),MTDATA(01,MES,ANO)));
SETVAR (QUANTMES , TABFUNC('MESESDURACAOBEM','I'));
SETVAR (DATARETORNO, (TABFUNC('DTACORDOBEM','D')+ (QUANTMES*30)));
SETVAR (QUANTDIASRETORNO, SUBTRAIDATAS(MTDATA(30,MES,ANO), DATARETORNO));
SETVAR (PERC, TABFUNC('PERCENTUALREDUCAOBEM', 'I'));
SETVAR (SALRED, TABFUNC ('VALORREDUZIDOBEM', 'I'));
SE QUANTDIAS> 0 E (TABFUNC('DTACORDOBEM','D') > MTDATA(01,MES,ANO) E TABFUNC('DTACORDOBEM','D') < MTDATA(30,MES,ANO));
SALRED - ((SALRED / ND) * QUANTDIAS)
SENAO
SE QUANTDIASRETORNO > 0 E (DATARETORNO > MTDATA(01,MES,ANO) E DATARETORNO < MTDATA(30,MES,ANO));
SALRED - ((SALRED / ND) * QUANTDIASRETORNO)
SENAO
SE QUANTDIAS < 0 E QUANTDIASRETORNO < 0;
SALRED
SENAO
0

Fórmula associada ao evento que será lançado no movimento do Funcionário.

Image Removed

Envelope lançou o valor referente ao período reduzido:

Image Removed

...

...

/* Cálculo utilizado para o layout do BEM versão 3 */ 
/* Data Atualização: 29/06/2020 */ 
/* Data Atualização: 10/08/2020 */ 
/* Data Atualização: 28/09/2020 */
/* Data Atualização: 30/09/2020 */
/* Data Atualização: 20/10/2020 */
/* Data Atualização: 23/10/2020 - Será considerado mais de uma prorrogação. Necessário informar a data fim da prorrogação, quando houver. Necessário atualizar a consulta SQL 'BEM'  */
/* Data Atualização: 10/11/2020 - Será considerado mais de uma prorrogação. Necessário informar a data INICIO da prorrogação, quando houver. 


/* Essa fórmula irá calcular o valor a reduzir de jornada e deverá ser associado a um evento de desconto no pagamento do funcionário.

1 - Será considerado mais de um período de adesão do histórico do BEM dentro da competência
exemplo,  uma adesão com percentual de 25% finalizando no mês e uma nova adesão de 50% iniciando no mês 
2 - Será considerado os novos campos do Layout do BEM 3 - Adesões com a mesma data de acordo, considerando Dias prorrogação, Data antecipação e Data Cancelamento */
3 - Será considerado mais de uma prorrogação. Necessário informar a data do início da prorrogação.


1 - Antes de criar a fórmula, deverá atualizar a consulta SQL BEM incluído os novos campos


select DTACORDOBEM,DURACAOBEM,VALORREDUZIDOBEM,DTCANCELAMENTOBEM,DTANTECIPACAOBEM,DIASPRORROGACAOBEM,PERCENTUALREDUCAOBEM,DTPRORROGACAOBEM
FROM PFHSTBEM
where codcoligada =:FRM_COLIGADA and chapa =:FRM_CHAPA
and TIPOADESAOBEM = '1'
ORDER BY DTMUDANCA DESC



2 - Colar o conteúdo da fórmula abaixo: 

DECL DiasDuracao;
DECL DataFimAcordo;
DECL DataInicioReducao;
DECL DataFimReducao;
DECL DataInicioProrroga;
DECL ValorReduzido;
DECL DiasReducaoMes;
DECL Valor;
DECL DiasProrrog;
DECL DataCancelamento;
DECL DataAntecipacao;
DECL DataInicioAcordoAnt;
DECL DataInicioAcordo;
DECL ConsideraAcordo;
 
SETVAR (DataInicioAcordoAnt,DATANULA);
 
SE (EXECSQL ('BEM') = Verdade)
ENTAO
  REPITA
     SETVAR (ValorReduzido,resultsql('BEM','VALORREDUZIDOBEM'));
     SETVAR (DataInicioAcordo,resultsql('BEM','DTACORDOBEM'));
     SETVAR (DiasDuracao,resultsql('BEM','DURACAOBEM'));
     SETVAR (DiasProrrog,resultsql('BEM','DIASPRORROGACAOBEM'));
     SETVAR (DataCancelamento,resultsql('BEM','DTCANCELAMENTOBEM'));
     SETVAR (DataAntecipacao,resultsql('BEM','DTANTECIPACAOBEM'));
     SETVAR (DataInicioProrroga,resultsql('BEM','DTPRORROGACAOBEM'));
     SETVAR (DataFimAcordo,(DataInicioAcordo + DiasDuracao)-1) ;
     SETVAR (ConsideraAcordo,1);
  
  
/* Verifica se tem antecipação, prorrogação ou cancelamento */
     SE (DiasProrrog > 0)
     ENTAO
       SETVAR (DataFimAcordo,(DataInicioProrroga + DiasProrrog));
     SENAO
       SE (DataCancelamento <> DATANULA) 
       ENTAO
         SETVAR (DataFimAcordo,DataCancelamento);
       SENAO
          SE (DataAntecipacao <> DATANULA) 
          ENTAO
            SETVAR (DataFimAcordo,(DataAntecipacao + 1));
          FIMSE;
       FIMSE;
     FIMSE;
      
      
     /*Verifica se é o mesmo acordo e teve antecipação, prorrogação ou cancelamento no seguinte */
     SE ((DataInicioAcordo = DataInicioAcordoAnt) E ((DataAntecipacao = DATANULA) OU (DiasProrrog = 0) OU (DataCancelamento = DATANULA)))
     ENTAO
       SETVAR(ConsideraAcordo,0)
     FIMSE;
 
/*Considera acordo no cálculo */
SE (ConsideraAcordo = 1)
ENTAO
   SE (DataInicioAcordo <= ULTDIAMES(MTDATA(1,MES,ANO)) E DataFimAcordo >= MTDATA(1,MES,ANO) )
   ENTAO
      SETVAR(DatainicioReducao,DataInicioAcordo);
      SETVAR(DataFimReducao,DataFimAcordo);
 
      /*Atribui início redução */
      SE (DataInicioAcordo <= MTDATA(1,MES,ANO))
      ENTAO
        SETVAR(DatainicioReducao,MTDATA(01,MES,ANO))
      FIMSE;
      
      /*Atribui fim redução */     
      SE (DataFimAcordo > ULTDIAMES(MTDATA(1,MES,ANO)))
      ENTAO
        SETVAR(DataFimReducao,ULTDIAMES(MTDATA(1,MES,ANO)))
      FIMSE;
  
     
/* calcula dias redução no mes*/
     SE (DIADT(ULTDIAMES(MTDATA(1,MES,ANO))) = 30) OU (DIADT(ULTDIAMES(MTDATA(1,MESDT(DataInicioAcordo),ANODT(DataInicioAcordo)))) = 30) 
     ENTAO 
       SETVAR(DiasReducaoMes, SUBTRAIDATAS(DataFimReducao,DatainicioReducao)+1)
     SENAO 
       SETVAR(DiasReducaoMes, SUBTRAIDATAS(DataFimReducao,DatainicioReducao))
     FIMSE;
    
     
     SETVAR(ValorReduzido,(ValorReduzido / 30) * MIN(DiasReducaoMes,30));
  
 /* calcula dias redução no mês desconsiderando férias*/
     SETVAR(DiasReducaoMes,(DiasReducaoMes  -  DIAFERPER(DatainicioReducao,DataFimReducao)));
    
 /* calcula dias redução no mês desconsiderando afastamento*/
     SETVAR(DiasReducaoMes,(DiasReducaoMes  -  DIASAFT(DatainicioReducao,DataFimReducao,'PTO')));
 
  
  /* Soma dois períodos de redução no mês */
      SETVAR(Valor,Valor + ValorReduzido);
   SENAO 0
   FIMSE;
FIMSE;
SETVAR (DataInicioAcordoAnt,DataInicioAcordo);
ATE ProxRegSQL('BEM' ) = Falso
FIMSE;
Valor;





Fórmula associada ao evento que será lançado no movimento do Funcionário.

Image Added

Envelope lançou o valor referente ao período que considera a Jornada reduzida:

Image Added

Diferença Salarial por Dissídio x  Redução de Jornada/Salário

A MP 936 convertida em Lei n° 14.020 , foi criada com o objetivo de preservar o emprego e renda dos trabalhadores, garantir as atividades empresariais e laborais, e reduzir os impactos sociais da calamidade pública decorrentes ao COVID-19.

A MP com a conversão da Lei não traz a questão do dissídio retroativo, dessa forma o entendimento é que ela veio flexibilizar algumas regras trabalhistas, e devemos nos atentar o que diz o artigo 471 da CLT.

Art. 471 - Ao empregado afastado do emprego, são asseguradas, por ocasião de sua volta, todas as vantagens que, em sua ausência, tenham sido atribuídas à categoria a que pertencia na empresa.

Link Consultoria MP 936/2020 - Lei n° 14.020 - Redução de salário e jornada com dissidio retroativo

No produto,  a diferença salarial por dissídio será calculada considerando o salário integral.

A fórmula que calcula o valor redutor não reduzirá a jornada/salário considerando o reajuste salarial,  conforme entendimento acima.

Caso a empresa tenha interpretação jurídica diferente do exposto, poderá usar recursos de fórmulas do produto e customizar o cálculo considerando o aumento salarial no desconto redutor de jornada/salário.

Abaixo roteiro para utilização deste recurso.

MP 936 - Fórmula de redução da jornada/salário considerando aumento salarial por dissídio

...