Linha Microsiga Protheus

Árvore de páginas

STIPAYCST - Inclusão de Forma de Pagamento customizada - TOTVS PDV

Descrição:

Ponto de entrada para permitir campos customizados quando selecionada a forma de pagamento, substituindo o painel de campos padrão por painel de campos especificos

Eventos:

O ponto de entrada é executado assim que selecionada uma forma de pagamento no TOTVS PDV

Programa Fonte:STIPayment.PRW

Parâmetros:

Nome
Tipo
Descrição
ParamIxb[1]Objeto
Objeto do painel adicional (oPnlAdconal)
ParamIxb[2]Caracter
Forma de Pagamento Selecionada
Retorno:
Nome
Tipo
Descrição
lRetLógico

.T. mantém o painel de campos padrão e .F. não apresenta o painel de campos padrão

Exemplo:

/*/{Protheus.doc} STIPAYCST
Ponto de Entrada para Incluir a forma de pagamento Especifica
/*/
User Function STIPAYCST()
    Local oLblValor     := Nil //Objeto do label 'Valor do Pagamento'
    Local oGetValor     := Nil //Objeto do get 'Valor do Pagamento' 
    Local cGetVal      := SPACE(TamSx3("L4_XVOUCHE")[1])

    Local oPnlAdconal := ParamIxb[1]
    Local cTpForm := ParamIxb[2]
    Local lRet := .F. // Nao abre o painel de pagamento padrao

    Local oMdl      := FwLoadModel("STIPayFinancial")               //Recupera o model ativo

    oMdl := oMdl:GetModel("FINANCIALMASTER")    

    oMdl:Activate()

    oMdl:LoadValue("L4_XVOUCHE",'')

    If cTpForm == 'TD' 
        /* Label: 'Voucher' */
        oLblValor := TSay():New(POSVERT_PAYLABEL1, POSHOR_PAYCOL1,;
        {||"Voucher"}, oPnlAdconal,,,;
        ,,,.T.,;
        ,,,8)

        /* Get: Voucher */
        oGetValor := TGet():New(POSVERT_PAYGET1 ,POSHOR_PAYCOL1,{|u| If(PCount()>0,cGetVal:=u,cGetVal)},oPnlAdconal,;
        LARG_GET_VALOR,ALTURAGET,"@E 9999999999",,,;
        ,,,,;
        .T.,,,,,,,lReadOnly,,,,,,,,.T.)     

        oGetValor:SetFocus()

        oLblValor:SetCSS( POSCSS (GetClassName(oLblValor), CSS_LABEL_FOCAL ))
        oGetValor:SetCSS( POSCSS (GetClassName(oGetValor), CSS_GET_FOCAL ))

        /* Button: OK */
        oBtnOk := TButton():New(POSVERT_BTNPAY,POSHOR_BTNCONFPAY,"Confirma Trade In",oPnlAdconal,;
        {||oMdl:LoadValue("L4_XVOUCHE",cGetVal),STIAddPay(cTpForm, oMdl, oMdl:GetValue("L4_PARCELA"),.F.), oPnlAdconal:Hide(), STIEnblPaymentOptions()},LARGBTN,ALTURABTN,,;
        ,,.T.) //'Efetuar Pagamento'


        //STICSConfPay(oGetValor3, oPnlAdconal)
        /* Button: Cancelar */
        oBtnCa  := TButton():New(POSVERT_BTNPAY,00,"Cancelar",oPnlAdconal,;
        {|| STIPayCancel() },LARGBTN,ALTURABTN,,;
        ,,.T.) //'Cancelar'

        oBtnOk:SetCSS( POSCSS(GetClassName(oBtnOk), CSS_BTN_FOCAL) )
        oBtnCa:SetCSS( POSCSS(GetClassName(oBtnCa), CSS_BTN_ATIVO) )
    Else
        lRet := .T.
    Endif

Return lRet