Linha Microsiga Protheus

Árvore de páginas

Descrição

Ponto de Entrada para customização do Relatório de Conferencia da rotina Encerramento de Caixa do Totvs Pdv.

VersõesProtheus 12
Parâmetros

PARAMIXB[1] - Matriz das formas de pagamentos e respectivos valores digitados e apurados (array)
PARAMIXB[2] - Número do Caixa (string)
PARAMIXB[3] - Código da Estação (string)
PARAMIXB[4] - Número do Pdv (string)
PARAMIXB[5] - Data da abertura do movimento (string)
PARAMIXB[6] - Hora da abertura do movimento (string)
PARAMIXB[7] - Data do fechamento (string)
PARAMIXB[8] - Hora do fechamento (string)
PARAMIXB[9] - Número do movimento (string)

Retornotexto a ser impresso (string)
Programa FonteSTICONFCASH.PRW
Exemplo

#Include 'Protheus.ch'


User Function STRECFCX()
Local aPaym     :=  PARAMIXB[1] 
Local sCaixa    :=  PARAMIXB[2]
Local sEstacao  :=  PARAMIXB[3]
Local sPdv      :=  PARAMIXB[4]
Local sDtAbert  :=  PARAMIXB[5]
Local sAbHora   :=  PARAMIXB[6] 
Local sDtFech   :=  PARAMIXB[7] 
Local sFcHora   :=  PARAMIXB[8]
Local sNumMov   :=  PARAMIXB[9]
Local cTexto    :=  ""
Local nTotApu   :=  0
Local nTotDig   :=  0
Local cCRLF     :=  Chr(13) + Chr(10) 
Local nX        :=  0

cTexto := cCRLF + cCRLF 
cTexto += 'caixa.....: ' + sCaixa   + cCRLF  
cTexto += 'estação...: ' + sEstacao + cCRLF  
cTexto += 'pdv.......: ' + sPdv     + cCRLF 
cTexto += 'abertura..: ' + sDtAbert + ' - ' + 'hora: ' + AllTrim(sAbHora) + cCRLF 
cTexto += 'fechamento: ' + sDtFech  + ' - ' + 'hora: ' + AllTrim(sFcHora) + cCRLF 
cTexto += 'movimento.: ' + sNumMov      + cCRLF
cTexto += cCRLF + cCRLF
 
cTexto += 'Forma !Descrição                ! Valor Dig !  Valor Ap.'

cTexto += cCRLF

For nX := 1 To Len(aPaym)
    cTexto += aPaym[nX][1] + '!' + SubStr(aPaym[nX][2],1,22) + Space(3) + '!' + Str(Val(aPaym[nX][7]),10,2) + '!' + Str(aPaym[nX][8],10,2) + cCRLF
    nTotApu := nTotApu + aPaym[nX][8]
    nTotDig := nTotDig + Val(aPaym[nX][7])
Next nX

cTexto += cCRLF + cCRLF
cTexto += cCRLF + "Total Apurado :" + Str(nTotApu,10,2)
cTexto += cCRLF + "Total Digitado:" + Str(nTotDig,10,2)
cTexto += cCRLF + 'ass. caixa    :' + Replic("_",28)
cTexto += cCRLF + 'ass. superior :' + Replic("_",28) + cCRLF 

Return  cTexto