9368673 DSERSGS-9016 DT Relacionamento entre contrato e orçamento na geração do contrato

User Function RetEscal()
Local cRet := ""
Local cQry := GetNextAlias()
Local oModel := FwModelActive()
Local cContrt := ""
Local cRev := ""
Local cPlan := ""
Local cItemCNB := ""

If oModel:GetId() == 'CNTA300' .AND. oModel:GetModel("CNBDETAIL"):Length() > 0
    cPlan := FwFldGet("CNA_NUMERO")
    cRev := FwFldGet("CN9_REVISA")
    cContrt := FwFldGet("CN9_NUMERO")
    cItemCNB := FwFldGet("CNB_ITEM")

    BeginSQL Alias cQry
        SELECT TDW.TDW_DESC
        FROM %Table:TDW% TDW
        INNER JOIN %Table:TFF% TFF ON
            TDW.TDW_COD = TFF.TFF_ESCALA AND
            TFF.TFF_FILIAL = %xFilial:TFF% AND
            TFF.TFF_ITCNB = %Exp:cItemCNB% AND
            TFF.TFF_CONTRT = %Exp:cContrt% AND
            TFF.TFF_CONREV = %Exp:cRev% AND
            TFF.%NotDel%
        INNER JOIN %Table:TFL% TFL ON
            TFL.TFL_CODIGO = TFF.TFF_CODPAI AND
            TFF.TFF_FILIAL = TFL.TFL_FILIAL AND
            TFL.%NotDel% AND
            TFL.TFL_PLAN = %Exp:cPlan% AND
            TFL.TFL_CONTRT = %Exp:cContrt% AND
            TFL.TFL_CONREV = %Exp:cRev%
        WHERE TDW.TDW_FILIAL = %xFilial:TDW%
            AND TDW.%NotDel%
    EndSQL

    If !EMPTY((cQry)->TDW_DESC)
        cRet := Alltrim((cQry)->TDW_DESC)
    Else
        cRet := "Escala não configurada"
    EndIf

    (cQry)->(DbCloseArea())
EndIf
Return cRet

//--------------------------
// P.E. SetActivate CNTA300
//--------------------------

User Function CN300ACT()
Local aParam := PARAMIXB
Local oModel
Local oMdlCNB
Local oMdlCNA
Local aSaveLines
Local nX
local nY

If aParam <> NIL
    aSaveLines := FWSaveRows()
    oModel := aParam[1]
    oMdlCNB := oModel:GetModel("CNBDETAIL")
    oMdlCNA := oModel:GetModel("CNADETAIL")
    If oMdlCNB:CanUpdateLine() .AND. !oMdlCNA:isEmpty()
        For nX := 1 To oMdlCNA:Length()
            oMdlCNA:SetLine(nX)
            If !oMdlCNB:isEmpty()
                For nY := 1 To oMdlCNB:Length()
                    oMdlCNB:SetLine(nY)
                    oMdlCNB:LoadValue("CNB_NOMESC", U_RetEscal())
                Next nY
            EndIf
        Next nX
    EndIf
    FWRestRows(aSaveLines)
EndIf
Return .T.