Função: ValType
Retorna um caractere que identifica o tipo de dado da variável informada através do parâmetro.
ValType ( < xVariavel> ) --> cRet
Nome | Tipo | Descrição | Obrigatório | Referência |
xVariavel | Qualquer | Indica o dado ou a variável que se deseja identificar. | X |
cRet
- (caracter)
- Retorna um caractere que identifica o tipo de dado informado.
Tipos de dados válidos:
Tipo de dado | ValType() |
Array | A |
Bloco de código | B |
Caractere | C |
Data | D |
Lógico | L |
Numérico | N |
Decimal de ponto fixo | F |
Objeto | O |
Não definido (NIL) | U |
#DEFINE CRLF Chr(13)+Chr(10)
User Function Exemplo()
Local aArray := {}
Local bBloco := {|| .T.}
Local cCaractere := "Caractere", cMensagem := ""
Local dData := Date()
Local lLogico := .T.
Local nNumerico := 1024.2048
Local oObjeto := MSDialog():Create()
Local uUndefined := Nil
//+----------------------------------------------------------------------------+
//|Exemplifica o uso da função ValType |
//+----------------------------------------------------------------------------+
cMensagem += "[" + ValType(aArray) + "] Array" + CRLF
cMensagem += "[" + ValType(bBloco) + "] Bloco de código" + CRLF
cMensagem += "[" + ValType(cCaractere) + "] Caractere" + CRLF
cMensagem += "[" + ValType(dData) + "] Data" + CRLF
cMensagem += "[" + ValType(lLogico) + "] Lógico" + CRLF
cMensagem += "[" + ValType(nNumerico) + "] Numérico" + CRLF
cMensagem += "[" + ValType(oObjeto) + "] Objeto" + CRLF
cMensagem += "[" + ValType(uUndefined) + "] Undefined"
//+----------------------------------------------------------------------------+
//|Apresenta uma mensagem com os resultados obtidos |
//+----------------------------------------------------------------------------+
Return MsgInfo(cMensagem, "Exemplo do ValType")
Preview
Exemplo da função ValType
Microsiga Protheus 8.11 , Protheus 10
Visão Geral
Import HTML Content
Conteúdo das Ferramentas
Tarefas