TOTVSTEC

Árvore de páginas

Recuperação de Array com valores múltiplos / únicos.


Sintaxe


KVHMGet( < cKey >, < @aValIns > )


Parâmetros
NomeTipoDescriçãoObrigatórioReferência
cKeycharacterNome da chave que pretende recuperar seus valores múltiplos.X
aValInsarrayArray multidimensional que recebe por referência os valores múltiplos registrados na chave principal cKey. Também podemos passar quais chaves queremos obter o valor, ou então, passar array vazio para pegar todos os valores.XX
Retorno
NomeTipoDescrição
xRetKVarrayEm caso de sucesso xRetKV será Nil.

Porém, caso ocorra algum erro retorna:
xRetKV[1]= comando executado no servidor KV.
xRetKV[2]= mensagem do erro.
Exemplos


function u_KVHMGet()

  local oKVClient := tTecKVClient():New()
  local cSrv      := '127.0.0.1'
  local nPort     := 6379
  local nIndex    := 0
  local aKV       := {}
  local aValIns

  oKVClient:KVOpenConn(cSrv,nPort)

  if ( oKVClient:KVIsConnected() )

    aKV := oKVClient:KVHMSet('multi', {'01','02'})
    aKV := oKVClient:KVHMSet('multi', {{'key1','11'},{'key2','22'}})

    // Somente chaves desejadas
    // ------------------------
      conout( ' >> Somente chaves desejadas' )
      aValIns := {{'field1',},{'key1',}}
      aKV := oKVClient:KVHMGet( 'multi', @aValIns )

      if ( valtype(aKV) == 'A' )

        conout( 'ERROR' )
        conout( 'command: ' + aKV[1] )
        conout( 'error: ' + aKV[2] )

      elseif ( valtype(aValIns) == 'A' )

        if ( len( aValIns ) == 0 )
          conout( 'Não existe valores para a chave pesquisada!' )
        else
          for nIndex := 1 to len( aValIns )
            conout( " Chave [" + aValIns[nIndex][1] + "] " +;
              "Valor [" + CValToChar(aValIns[nIndex][2][1]) + "]" ;
            )
          next
        endif

      endif

    // Todas as chaves
    // ---------------
      conout( ' >> Todas as chaves' )
      aValIns := {}
      aKV := oKVClient:KVHMGet( 'multi', @aValIns )

      if ( valtype(aKV) == 'A' )

        conout( 'ERROR' )
        conout( 'command: ' + aKV[1] )
        conout( 'error: ' + aKV[2] )

      elseif ( valtype(aValIns) == 'A' )

        if ( len( aValIns ) == 0 )
          conout( 'Não existe valores para a chave pesquisada!' )
        else
          for nIndex := 1 to len( aValIns )
            conout( " Chave [" + aValIns[nIndex][1] + "] " +;
              "Valor [" + CValToChar(aValIns[nIndex][2][1]) + "]" ;
            )
          next
        endif

      endif

  endif

  oKVClient:Finish()  // <- Nao esquecer
return


Abrangência

20.3.0.x ou superior

  • Sem rótulos