Linha Microsiga Protheus

Árvore de páginas

Ponto-de-Entrada: GP120END - Ponto de Entrada para Gravação de Dados de Usuário após Fechamento


Versões:Microsiga Protheus 12
Compatível Países:Todos
Sistemas Operacionais:Todos
Compatível às Bases de Dados:Todos
Issue:DRHPAG-27605
Ticket:6392474
Fonte:GPEM120.PRX
Pacote:



Descrição:
Permite a gravação de informações de campos do usuário após o processamento completo do Fechamento de um roteiro, ou seja, após todos os registro de Funcionários terem sido processados.

Programa Fonte: GPEM120.PRX

Exemplo de utilização:
#include 'protheus.ch'

User Function GP120END()

Local aRotPE    := PARAMIXB
Local cFilPE    := ""
Local cProcPE   := ""
Local cRotPE    := ""
Local cPerPE    := ""
Local cNpgPE    := ""
Local nOrder    := RetOrdem( "Z03" , "Z03_FILIAL+Z03_PROC+Z03_ROTEIR+Z03_PERIOD+Z03_NUMPAG" )
Local nX        := 0


If Len(aRotPE) > 0
    For nX := 1 to Len(aRotPE)
        cRotPE  := aRotPE[nX,1]
        cPerPE  := aRotPE[nX,2]
        cNpgPE	:= aRotPE[nX,3]
        cFilPE 	:= aRotPE[nX,5]
        cProcPE	:= aRotPE[nX,6]

        DbSelectArea( "Z03" )
        Z03->(DbSetOrder( nOrder ))
        If Z03->(!DbSeek(cFilPE+cProcPE+cRotPE+cPerPE+cNpgPE)) // Filial + Processo + Roteiro + Periodo + Número de Pagamento

                RecLock("Z03",.T.)
                Z03->Z03_FILIAL     := cFilPE
                Z03->Z03_PROC       := cProcPE
                Z03->Z03_ROTEIR     := cRotPE 
                Z03->Z03_PERIOD     := cPerPE
                Z03->Z03_NUMPAG     := cNpgPE
                Z03->Z03_STATUS     := "ATUA-TAB"
                Z03->( MsUnLock() )

        EndIf

    Next nX
EndIf

Return

Importante

  • Na ocasião do uso do Ponto de Entrada como o exemplo acima deve ser efetuado o travamento e o destravamento do registro utilizado.