AxCadastro

AxCadastro - Tela padrão da mBrowse

Descrição

Função utilizada para montar a tela padrão da mbrowse (modelo 1).

Sintaxe

AxCadastro:(cAlias, cTitle, cDel, cOk, aRotAdic, bPre, bOK, bTTS, bNoTTS, aAuto, nOpcAuto, aButtons, aACS, cTela, lMenuDef)

Retorno
()

Exemplo

User Function TesteCad()   
 Local aRotAdic :={} 
 Local bPre := {||MsgAlert('Chamada antes da função')}
 Local bOK  := {||MsgAlert('Chamada ao clicar em OK'), .T.}
 Local bTTS  := {||MsgAlert('Chamada durante transacao')}
 Local bNoTTS  := {||MsgAlert('Chamada após transacao')}    
 Local aButtons := {}//adiciona botões na tela de inclusão, alteração, visualização e exclusao
 aadd(aButtons,{ "PRODUTO", {|| MsgAlert("Teste")}, "Teste", "Botão Teste" }  ) //adiciona chamada no aRotina
 aadd(aRotAdic,{ "Adicional","U_Adic", 0 , 6 })
 AxCadastro("SA1", "Clientes", "U_DelOk()", "U_COK()", aRotAdic, bPre, bOK, bTTS, bNoTTS, , , aButtons, , )  
Return(.T.)                        
User Function DelOk() 	
 MsgAlert("Chamada antes do delete") 
Return 
User Function COK() 	
MsgAlert("Clicou botao OK") 
Return .t.      
User Function Adic() 	
MsgAlert("Rotina adicional") 
Return

Parâmetros

Nome	Tipo	Descrição	Default	Obrigatório	Referência
cAlias	Caracter	Alias da Tabela cadastrada no dicionário (SX2) que será baseada a mBrowse.
cTitle	Array of Record	Título da janela.
cDel	Array of Record	Função a ser executada ao deletar o registro.
cOk	Array of Record	Função a ser executada ao clicar no botão OK para gravar o registro(inclusão e alteração).
aRotAdic	Array of Record	Array contendo as rotinas adicionais para ser acrescentado ao array aRotina.
bPre	Array of Record	Codeblock a ser executado antes da abertura do diálogo de inclusão, alteração ou exclusão.
bOK	Array of Record	Codeblock a ser executado ao clicar no botão OK do diálogo de inclusão, alteração ou exclusão.
bTTS	Array of Record	Codeblock a ser executado durante a transação de inclusão, alteração ou exclusão.
bNoTTS	Array of Record	Codeblock a ser executado após a transação de inclusão, alteração ou exclusão.
aAuto	Array of Record	Array com os campos a serem considerados pela rotina automática.
nOpcAuto	Array of Record	Numero da opção selecionada (Inclusão, Alteração, Exclusão, Visualização) para a rotina automática.
aButtons	Array of Record	Array contendo os botões da EnchoiceBar com a seguinte estrutura: aButtons[1][1] – Nome do arquivo da imagem do botão.aButtons[1][2] – Bloco de execução.aButtons[1][3] – Mensagem de exibição no ToolTip.aButtons[1][4] – Nome do botão.
aACS	Array of Record	Array que substituí o controle de acessos das funções básicas do aRotina (Pesquisar, Visualizar, Incluir, Alterar, Excluir). Ex: aACS := { , , , ,3 } No exemplo acima a opção de excluir irá respeitar o 3º acesso da lista de acessos do usuário conforme link abaixo: Relação de Acessos x Rotina
cTela	Array of Record	Nome da variável tipo "private" que a enchoice utilizará no lugar da variável aTela.
lMenuDef	Lógico	Indica se o Menudef padrão da função AxCadastro será criado.	.T.

Páginas filhas

AxCadastro

AxCadastro - Tela padrão da mBrowse