VarGetD

Recupera o valor de uma "chave" tanto da "Tabela X" quanto da "Tabela A" de uma determinada sessão, mas não faz bloqueio da "chave" <cChave> (Dirty).

Sintaxe

VarGetD

lRet := VarGetD( <cUID>, <cChave>, <xValor>, <aValor> )

Parâmetros

Nome	Tipo	Descrição	Obrigatório	Referência
cUID	Caractere	Identificador da sessão de Variáveis Globais	X
cChave	Caractere	Identificador da chave	X
xValor	Numérico / Caractere / Data / Lógico	Variável onde será armazenado o valor da chave ("Tabela X")	X	X
aValor	Array	Variável onde será armazenado o valor dachave ("Tabela A")	X	X

Retorno

Nome	Tipo	Descrição	Observações
lRet	Lógico	Indica se conseguiu recuperar o valor da chave <cChave> na sessão <cUID> para qualquer uma das tabelas	Retorna .T. se a função foi executada corretamente e se houver algum erro retorna .F.

Observações

Ver as observações de "VarGetXD" e "VarGetAD" para ver as opções de retorno, e se o valor da chave for encontrado em alguma das tabelas o retorno será verdadeiro (.T.), caso não encontre o valor em ambas o retorno será falso (.F.).

Como esta função não faz o bloqueio da chave esta função sempre irá recuperar o valor, mesmo que uma transação esteja em curso.

Por conta de não fazer bloqueio na chave esta função é mais rápida que a função "VarGet" , ou seja, se os seus "Jobs/Threads" não tiverem a necessidade de fazer uma transação, de preferência para o uso desta função.

Disponível em Build igual ou superior a 7.00.131227A

Exemplos

Exemplo

User Function exemplo()
  Local cMyUID := "teste_UID_RL"
  Local cChave := "chave"
  Local nValor := 32
  Local aValor := {1, 2, 3}
  Local lRet := .F.
     
  lRet := VarSetUID(cMyUID, .T.)
  If(!lRet)
    ConOut("Erro na criação da sessão: " + cMyUID)
  EndIf
    
  lRet := VarSetD(cMyUID, cChave, nValor, aValor)
  If(!lRet)
    ConOut("Erro na atualização da chave: " + cChave)
  EndIf
   
  nValor := 7
  aValor := {4, 5}
   
  lRet := VarGetD(cMyUID, cChave, @nValor, @aValor)
  If(!lRet)
    ConOut("Erro na recuperação da chave: " + cChave)
  Else
    ConOut("Achou a chave: " + cChave + " valor (tab x): " + AllTrim(Str(nValor)))
    ConOut("Achou a chave: " + cChave + " valor (tab a): " + AllTrim(Str(Len(aValor))))
  EndIf
Return .T.

Veja também

VarSetUID, VarSetD, VarGet, VarSetXD, VarSetAD, VarBeginT, VarEndT

Árvore de páginas