TOTVSTEC

Árvore de páginas

  • Criado por Usuário desconhecido (ellen.sousa), última alteração em 24 dez, 2020
Pesquisa o padrão em uma string e retorne o resultado booleano se há alguma substring correspondente.

Sintaxe


lOK := oRegex:Search( < cText > )

Parâmetros

NomeTipoDescriçãoObrigatórioReferênciaObservações
cText
Caractere

Texto no qual o padrão será procurado.

X

Retorno

NomeTipoDescriçãoObservações
lOK
Lógico

Se alguma substring do texto corresponde ao padrão, então o retorno é verdadeiro. 


Observações

Exemplos

user function tRgxSearch()
  local nRet := -1
  local lRet := .F.
  local regex := NIL
  local text1 := "texto com letras"
  local text2 := "1231 123123 8575 5676"
  local pattern1 := "([a-z])\w+"
  local pattern2 := "([1-9])\w+"

  regex := tRegex():new("([Z])\w+")

  if ValType(regex) <> "O"
    Conout('Erro - ValType(regex) <> "O"')
    return
  endif

  nRet := regex:SetPattern(pattern1)
  if (nRet != 0)
    ConOut("SetPattern " + pattern1 + " falhou: " + regex:GetErrorMsg())
    return
  endif

  lret := regex:Search(text1)
  Conout("Encontrou o padrão: " + cvaltochar(lret)) // .T.

  lret := regex:Search(text2)
  Conout("Encontrou o padrão: " + cvaltochar(lret)) // .F.

  nRet := regex:SetPattern(pattern2)
  if (nRet != 0)
    ConOut("SetPattern " + pattern2 + " falhou: " + regex:GetErrorMsg())
    return
  endif

  lret := regex:Search(text1)
  Conout("Encontrou o padrão: " + cvaltochar(lret)) // .F.

  lret := regex:Search(text2)
  Conout("Encontrou o padrão: " + cvaltochar(lret)) // .T.

return



Veja também

  • Sem rótulos