TOTVSTEC

Árvore de páginas

Você está vendo a versão antiga da página. Ver a versão atual.

Comparar com o atual Ver Histórico da Página

« Anterior Versão 52 Próxima »

Classe: TMediaPlayer


Cria um objeto para reprodução de vídeos e áudios. Este componente utiliza tecnologia ActiveX, através do Windows Media Player®, desta forma estando homologado apenas para os sistema operacionas da Microsoft®, dentre eles:

Windows XP
Windows Vista
Windows 7
Windows 8

O Windows Media Player® pode depender de Codecs específicos para reprodução dos arquivos MP4, como teste basta executar este arquivo diretamente na ferramenta da Microsoft®, caso funcione nesta, a reprodução ocorrera sem problemas no TMediaPlayer.

Importante: Este componente está disponível em versões superiores à 120420A.

SmartClient HTML

Os formatos de arquivos homologados para SmartClient HTML são: MP4, MOV, WMV e MP3


Hierarquia

TSrvObject -> TControl -> TMediaPlayer


Construtores
New

 

New

Método construtor da classe.


Sintaxe

TMediaPlayer(): New ( [ nRow], [ nCol], [ nWidth], [ nHeight], [ oWnd], [ cFile], [ nVolume], [ lShowBar] ) --> oObjeto


Parâmetros

 

NomeTipoDescriçãoObrigatórioReferência
nRowNuméricoIndica a coordenada vertical em pixels ou caracteres.  
nColNuméricoIndica a coordenada horizontal em pixels ou caracteres.  
nWidthNuméricoIndica a largura em pixels do objeto.  
nHeightNuméricoIndica a altura em pixels do objeto.  
oWndObjetoIndica a janela ou controle visual onde o objeto será criado.X 
cFileCaractereIndica o nome do arquivo de mídia(MP4 ou MP3), que caso preenchido iniciara automaticamente a reprodução .  
nVolumeNuméricoIndica o volume de audio, de 0 a 100  
lShowBarBoleanoSe .T. indica que será exibida a barra de comandos do próprio Windows Media Palyer®  

 

Retorno
oObjeto
  • Retorna o objeto criado.


Exemplos

oMedia := TMediaPlayer():New(1, 1, 200, 200, oDlg, "c:/dir/file.mp4", 70, .T.)

 

Métodos

OpenFile

 

OpenFile

Abre e inicia a reprodução de um arquivo de mídia.

Sintaxe

TMediaPlayer(): Openfile([cFile]) -->

Exemplos

oMedia:OpenFile("c:/fir/file.mp3")

Parâmetros
 

 

NomeTipoDescriçãoObrigatórioReferência
cFileCaracterIndica o nome do arquivo de mídia(MP4 ou MP3), que caso preenchido iniciara automaticamente a reprodução .X 

 


SetShowBar

SetShowBar

Habilita a exibição da barra de ferramentas do Windows Media Player®.


Sintaxe

TMediaPlayer(): SetShowBar( <lShow> ) -->


Parâmetros

 

NomeTipoDescriçãoObrigatórioReferência
lShowBoleanoSe .T. indica que será exibida a barra de comandos do próprio Windows Media Palyer®X 

 


Observações
 

Exemplos
oMedia:SetShowBar(.T.)

SetVolume

 

SetVolume

Ajusta a altura do volume de áudio.

Sintaxe

TMediaPlayer(): SetVolume([nVolume] ) -->

Exemplos
oMedia:SetVolume(70)

Nome

Tipo

Descrição

Obrigatório

Referência

nVolume

Numérico

Indica o volume de audio, de 0 a 100

X

 

 

Play

 

Play

Inicia reprodução.

 

Sintaxe

TMediaPlayer():Play() -->


Exemplos
oMedia:Play()

 

Stop

 

Stop

Para a reprodução.

 

Sintaxe

TMediaPlayer():Stop() -->


Exemplos
oMedia:Stop()

 

Pause

Pause

Pausa a reprodução.

 

Sintaxe

TMediaPlayer(): Pause() -->


Exemplos
oMedia:Pause()

SetMute

SetMute

Liga e desliga a opção silencio (mute).


Sintaxe

TMediaPlayer(): SetMute( <lMute> ) -->


Parâmetros

 

NomeTipoDescriçãoObrigatórioReferência
lMuteBoleanoSe .T. habilita a opção silencio (mute)X 

 

Exemplos
oMedia:SetMute( .T. )

 

Propriedades

Nome

Tipo

Descrição

Obrigatório

Referência

nPlayCount

Numérico

Define e retorna a quantidade de repetições para reprodução da mídia

 

 


 

Exemplo
#INCLUDE "TOTVS.CH"
USER FUNCTION TMediaPlayer()
	local nLeft := 1 
	local nTopBtn := 202 
	local showBar := .F. 
	local isMute := .F. 
	local nVolume := 70
	
	SetStyle(5)
	 
	DEFINE MSDIALOG oDlg TITLE "TMediaPlayer" FROM 0,0 TO 424,510 PIXEL 
	
		oMedia := TMediaPlayer():New(1,nLeft,255,200,oDlg,"c:/garbage/file.mp4",nVolume,showBar) 
	
		TButton():New( nTopBtn, nLeft, "Open", oDlg,; 
			{|| oMedia:openFile( FWInputBox("Escolha o arquivo", "c:/garbage/") ) },;
			28,010,,,.F.,.T.,.F.,,.F.,,,.F. )
	
		TButton():New( nTopBtn, nLeft+=28, "Play", oDlg,; 
			{|| oMedia:play() },;
			28,010,,,.F.,.T.,.F.,,.F.,,,.F. ) 
	
		TButton():New( nTopBtn, nLeft+=28, "Pause", oDlg,; 
			{|| oMedia:pause() },;
			28,010,,,.F.,.T.,.F.,,.F.,,,.F. ) 
	
		TButton():New( nTopBtn, nLeft+=28, "Stop", oDlg,; 
			{|| oMedia:stop() },;
			28,010,,,.F.,.T.,.F.,,.F.,,,.F. )
			 
		TButton():New( nTopBtn, nLeft+=28, "SetVolume", oDlg,; 
			{|| oMedia:setVolume( Val( FWInputBox("Escolha a altura do volume [0-100]", cValToChar(oMedia:nVolume)) ) ) },;
			28,010,,,.F.,.T.,.F.,,.F.,,,.F. )
			 
		TButton():New( nTopBtn, nLeft+=28, "GetVolume", oDlg,; 
			{|| MsgAlert( oMedia:nVolume ) },;
			28,010,,,.F.,.T.,.F.,,.F.,,,.F. )
			 
		TButton():New( nTopBtn, nLeft+=28, "ShowBar", oDlg,; 
			{|| showBar:=!showBar, oMedia:setShowBar( showBar ) },;
			28,010,,,.F.,.T.,.F.,,.F.,,,.F. )
			 
		TButton():New( nTopBtn, nLeft+=28, "nPlayCount", oDlg,; 
			{|| oMedia:nPlayCount := ( Val( FWInputBox("Escolha o numero de repetições", cValToChar(oMedia:nPlayCount)) ) ) },;
			28,010,,,.F.,.T.,.F.,,.F.,,,.F. )
			 
		TButton():New( nTopBtn, nLeft+=28, "SetMute", oDlg,; 
			{|| isMute:=!isMute, oMedia:setMute( isMute ) },;
			28,010,,,.F.,.T.,.F.,,.F.,,,.F. )
			 
	ACTIVATE MSDIALOG oDlg CENTERED
	 
RETURN

 

 
Preview
Exemplo da classe TMediaPlayer

Abrangência
Microsiga Protheus 8.11 , Microsiga Protheus 11 , Protheus 10 , TOTVS Application Server 10 , ByYou Application Server

 

  • Sem rótulos