XmlParser

XmlParser ( < cXml>, < cReplace>, < @cError>, < @cWarning> ) --> oXML

(objeto)
• Retorna um objeto com a estrutura de acordo com o XML.

A estrutura retornada:

<ObjXML>
           <NodeXML>
                   -<ArrayNodes>
                   -REALNAME
                   -TEXT
                   -TYPE

Onde REALNAME, TEXT e TYPE são propriedades que todos nodos possuem.

A propriedade <ArrayNodes> existirá quando um node possuir mais de um filho, do mesmo tipo. (demonstrado no exemplo).

Tratamento de "encoding" e caracteres especiais

A string contendo o XML pode conter uma especificação/atributo de codificação (encoding) usado das tags de conteúdo do XML. As identificações mais comuns são UTF-8 e iso-8859-1. Caso o XML recebido não possua a tag inicial com as propriedades de codificação, é assumido o encoding UTF-8. Caso o XML recebido, como parâmetro, possua nodes onde o conteúdo não esteja corretamente codificado em UTF-8, a geração do Objeto XML vai falhar, indicando na variável de erro a informação "Input is not proper UTF-8, indicate encoding ! ". Isto indica uma inconsistência no documento XML, que deve ser resolvida pelo programa/aplicação que montou/forneceu a string XML.

Existem também restrições à interpretação de caracteres especiais ou caracteres de controle dentro do documento XML. Um node de dados XML pode conter os caracteres especiais & (e-Comercial), < (menor), > (maior), entre outros, desde que estes estejam representados em formato de tags não-interpretáveis ("&amp;" ,  "&gt;" , "&lt;" respectivamente). Ao ser tratado pela função XMLParser, o conteúdo do node será convertido para a representação literal automaticamente. Caso um XML seja montado sem o tratamento para tags não-interpretáveis, e enviar como conteúdo o texto "A & B LTDA", a geração do objeto XML vai falhar, indicando na variável de erro a informação  "xmlParseEntityRef: no name".

/*Neste exemplo criamos uma função geraXml que retorna uma string contento um XML. Quando passamos essa string para
a XmlParser, a função irá montar um objeto Advpl correspondente à estrutura de dados  / nodes do XML. caso isso nao
ocorra a função irá retonar NIL, e uma informação de advertência ou erro será retornada nos parametros informados
por referência.
A estrutura:
oXml:
        pedido:
               -realName
               -type
               -text
                   nome_cliente:
                             -realName
                             -type
                             -text
                   endereço:
                             -realName
                             -type
                             -text
                   numero:
                             -realName
                             -type
                             -text
                   data:
                             -realName
                             -type
                             -text
                   itens:
                             -item <- (array)
                                       -item[1]:
                                             -realName
                                             -type
                                             -text
                                                     produto:
                                                     quantidade:
                                                     preco:
                                       -item[2]
                                             -realName
                                             -type
                                             -text
                                                     produto:
                                                     quantidade:
                                                     preco:
                             -realName
                             -type
                             -text  */
#INCLUDE "TOTVS.CH"
#INCLUDE "XMLXFUN.CH"

User Function getObjXML()
Local cError   := ""
Local cWarning := ""
Local oXml := NIL

//Gera o Objeto XML
oXml := XmlParser( GeraXML(), "_", @cError, @cWarning )
If (oXml == NIL )
	MsgStop("Falha ao gerar Objeto XML : "+cError+" / "+cWarning)
	Return
Endif

// Mostrando a informação do Node
MsgInfo(oXml:_PEDIDO:_NOMECLIENTE:Text,"Cliente")

Return oXml

// função para gerar uma string contendo um xml
Static Function GeraXML()
Local cScript
cScript := '<?xml version="1.0" encoding="ISO-8859-1"?>'
cScript += "<pedido>"
cScript += "    <Nome_Cliente>Microsiga Software</Nome_Cliente>"
cScript += "    <Endereco>Av. Braz Leme</Endereco>"
cScript += "    <Numero>1361</Numero>"
cScript += "    <Data>22-03-2005</Data>"
cScript += "    <Itens>"
cScript += "        <Item>"
cScript += "            <Produto>Protheus</Produto>"
cScript += "            <Quantidade>1</Quantidade>"
cScript += "            <Preco>100.00</Preco>"
cScript += "        </Item>"
cScript += "    </Itens>"
cScript += "</pedido>"
Return cScript

/*No exemplo abaixo, usamos um conteudo com caracteres acentuados e caracteres especiais para ser colocado dentro
de um node XML. Utilizamos as funcoes EncodeUTF8() para gerar um conteudo adequado à codificação do XML, e uma
função de framework _NoTags() para transformar eventuais tags interpretaveis que possam existir dentro do conteúdo
para serem representadas como conteudo do node XML*/

User Function XMLEnc()
Local cNome    := 'A&B-ZÃO LTDA'
Local cXml     := ""
Local cErro    := ""
Local cAviso   := ""
cXml += '<?xml version="1.0" encoding="UTF-8"?>'
cXml += "<Teste>"
cXml += EncodeUTF8( _NoTags( cNome ) )
cXml += "</Teste>"
conout("XML Original....:")
conout(cXml)
oXml := XmlParser(cXml,"_",@cErro,@cAviso)
MsgInfo(oXml:_TESTE:TEXT , "Conteudo" )
Return