01. VISÃO GERAL

Essa rotina possibilita a geração dos cheques antes que seja realizada a baixa dos títulos, podendo ser gerado um único cheque para vários títulos do mesmo fornecedor. Quando ocorrer a baixa, fica vinculado o banco/agencia/conta/cheque.   

02. EXECUÇÃO

• Manual

Procedimento efetuado de forma manual via rotina Cheques sobre Títulos (FINA390), com exibição das telas envolvidas no processo e necessitando de ações/comandos do usuário

• Automática

Procedimento realizado de forma automática na rotina de Cheques sobre Títulos (FINA390), sem exibição de telas ou necessidade de interação do usuário.

Utilizado em customizações onde o processo não necessita de interações do usuário (MSEXECAUTO)

#Include 'Protheus.ch'
//---------------------------------
// CHEQUE SOBRE TITULOS            |
//---------------------------------
User Function MyFA390()
	Local aArray := {}
	Local cCheque:= "2906001"
	Local nOpc   := 2       // 2 - Chq s/ titulo, 3 - Avulso

	Private lMsErroAuto := .F.

	aArray := { { "AUTBANCO"    , "237"             , NIL },;
            	{ "AUTAGENCIA"  , "33901"           , NIL },;
           		{ "AUTCONTA"    , "125008    "      , NIL },;
            	{ "AUTCHEQUE"   , cCheque           , NIL },;
            	{ "AUTVENCINI"  , CtoD("21/06/2016"), NIL },; // Remover caso utilizar opc 3
            	{ "AUTVENCFIM"  , CtoD("29/06/2016"), NIL },; // Remover caso utilizar opc 3
            	{ "AUTVALOR"    , 5000              , NIL },;
            	{ "AUTFORN"     , "001"             , NIL },;
            	{ "AUTBENEF"    , "F PADRAO            ", NIL },;
            	{ "AUTNATUREZA" , "10101     "      , NIL }}

	MsExecAuto( { |x,y,z| FINA390(x,y,z)} ,0, aArray, nOpc) 

	If lMsErroAuto
    	MostraErro()
	Else
    	Alert("O cheque "+cCheque+" foi gerado com sucesso!")
	Endif
	 
Return

#Include 'Protheus.ch'
//---------------------------------
// CHEQUE SOBRE TITULOS            |
//---------------------------------
User Function MyCanFA390()
	Local aArray := {}
	Local cCheque:= "2906001"

	Private lMsErroAuto := .F.

	aArray := { { "AUTBANCO"    , "237"             , NIL },;
            	{ "AUTAGENCIA"  , "33901"           , NIL },;
           		{ "AUTCONTA"    , "125008    "      , NIL },;
            	{ "AUTCHEQUE"   , cCheque           , NIL },;
            	{ "AUTCHQIMPR"  , .T.               , NIL }}// Identifica se deve ou não reutilizar o cheque caso impresso.

	MsExecAuto( { |x,y,z| FINA390(x,y,z)} ,0, aArray, 5) 

	If lMsErroAuto
    	MostraErro()
	Else
    	Alert("O cheque "+cCheque+" foi cancelado com sucesso!")
	Endif
	 
Return

03. OPERAÇÕES

• Avulsos 

Procedimento para inserção de cheques que não possuam nenhum titulo vinculado a eles.

• Cheque sobre títulos

Procedimento que permite ao usuário, inserir e vincular um cheque a titulo que ainda não sofreu baixas.

• Pesquisa

Pesquisa o titulo dentro do arquivo de contas a pagar, tendo como resultado o titulo posicionado e destacado na browse.

• Cancelar 

Procedimento para exclusão do cheque e cancelamento do movimento bancário. 

• Tracker contábil 

Apresenta consulta com o lançamento contábil do cheque, caso o mesmo já tenha sido contabilizado.  

• Legenda 

Apresenta quadro das legendas e seus significados referenciados a situação do cheque

• Redeposito

Procedimento que realiza o estorno do movimento gerado pela operação cheque avulso

04. PARÂMETROS APLICADOS

Lista de parâmetros aplicados ao FINA390 e seu processamento 

05. REGRA FINANCEIRA 

Um cheque é uma ordem de pagamento à vista. Ao gerar um cheque utilizando a operação Cheque sobre títulos , o emissor ordena que um banco faça o pagamento de uma quantia determinada a um beneficiário.

Além de uma ordem de pagamento, o cheque também é considerado um "título de crédito". Ou seja, ele é o reconhecimento de uma dívida por parte de seu emissor e, dessa forma, caso o pagamento não ocorra, o cheque poderá ser protestado ou executado em juízo por meio de uma ação de cobrança.

O cheque é pago quando há saldo na conta bancária que sera verificada na tabela SE8-Saldos bancários da empresa/unidade de negocio/filial onde o usuário estiver logado .Se não houver saldo, o cheque é considerado sem fundos e é devolvido, tendo que utilizar a operação Cancelar.

06. CALCULO DE IMPOSTOS

07. CONTABILIDADE

A contabilização dos processos aplicados a um cheque incluído via módulo Financeiro é feita pelos lançamentos padrões abaixo:

08. TABELAS RELACIONADAS

• SE2 - Cadastro do contas a pagar 
• SEF - Cadastro de cheques 
• SED - Cadastro de Naturezas.
• SA6 - Cadastro de Bancos.
• SA2 - Cadastro de Fornecedores.
• FK2 -  Baixas a Pagar.
• FK3 - Impostos Calculados.
• FK4 - Impostos Retidos.
• FK5 - Movimentos Bancários.
• FK6 - Valores acessórios.
• FKA - Rastreio de movimento.

09. PONTOS DE ENTRADA