F240GAVE - Manipula filtro para montagem de borderô de pagamentos

01. DADOS GERAIS

Produto:	TOTVS Backoffice
Linha de Produto:	Linha Protheus ®
Módulo:	Financeiro
Função:	FINA240 - Borderô de Pagamentos

02. DESCRIÇÃO

O ponto de entrada F240GAVE tem como objetivo permitir a manipulação dos dados de filtro para montagem do borderô.

A 13ª posição do array (nOpc) define se a rotina será executada ou abortada. Para continuar, ela deve ter como conteúdo o número inteiro "1" e para abortar a execução "0" (valor default).

Observação: caso este ponto de entrada esteja sendo utilizado, a tela inicial de montagem de borderôs padrão não será apresentada.

03. PARÂMETROS

Nome

Descrição

aVars

Array contendo os dados iniciais do filtro passiveis de manipulação. Sendo:

Variável	Descrição
cNumBor	Número do borderô
dVenIni240	Vencimento inicial
dVenFim240	Vencimento final
nLimite	Limite do valor
cPort240	Banco
cAgen240	Agência
cConta240	Conta
cContrato	Contrato
cMoeda240	Moeda
aMoedas	Moedas do sistema
cModPgto	Modelo
cTipoPag	Tipo de Pagamento
nOpc	Variável que determina se a rotina deverá continuar ou abortar a execução. 0 - Aborta a execução; 1 - Continua a execução.

04. RETORNO

Nome	Tipo	Descrição
aVars	Array	Array contendo 13 posições. Obs.: o array retornado pelo ponto de entrada deve respeitar as posições conforme o array recebido por parâmetro (paramIXB).

05. EXEMPLO DE UTILIZAÇÃO

F240GAVE

#Include "Protheus.ch"

/*/{Protheus.doc} F240GAVE
Ponto de entrada para manipulação do filtro do borderô de pagamentos.

@type       function
@author     TOTVS
@since      29/01/2021
@return     array, array com 13 posições contendo os filtros que serão aplicados na rotina borderô de pagamentos
/*/
User Function F240GAVE() As Array
    
    Local aVars As Array

    Local nOpc  As Numeric

    aVars   := paramIXB //parâmetro passado via ExecBlock
    nOpc    := aVars[13]

    // Aqui é possível escrever sua lógica de programação para definição do filtro
    If !(IsBlind()) 
        If MsgYesNo("Deseja continuar com a execução da rotina?", "Borderô de Pagamento")
            nOpc := 1
        EndIf
    Else
        nOpc := 1
    EndIf

    If nOpc == 1
        aVars[01] := "000001"
        aVars[02] := CToD("29/01/2021")
        aVars[03] := CToD("29/01/2021")
        aVars[04] := 99999.99
        aVars[05] := "001"
        aVars[06] := "00001"
        aVars[07] := "0000000000"
        aVars[09] := "01"
        aVars[11] := "31"
        aVars[12] := "20"
        aVars[13] := nOpc
    EndIf

Return aVars

Árvore de páginas