DT PE OM200AD2 - Inclusão de campos na tela de montagem da carga

01. DADOS GERAIS

Produto:	TOTVS OMS
Linha de Produto:	Linha Protheus
Segmento:	Logística
Módulo:	SIGAOMS - Gestão de Distribuição
Função:	OMSA200 - Montagem de Carga
País:	Todos Países
Ticket:	-
Requisito/Story/Issue (informe o requisito relacionado) :	-

02. DESCRIÇÃO

Este Ponto de Entrada permite incluir os campos adicionais relacionados com a Carga, na tela de seleção de Pedidos da Montagem de Carga (OMSA200).

03. LOCALIZAÇÃO

Localizado antes da abertura da tela de Montagem de Carga (OMSA200).

04. PARÂMETROS

Nome	Tipo	Descrição
oCargas	Objeto	Objeto do tipo ListBox, que contém a estrutura do browse de Cargas
aArrayCarga	Array	Contém as informações da Carga que está sendo montada
aHeaders	Array	Contém o cabeçalho dos campos a serem apresentados no browse de Cargas
bLine	Bloco de Código	Armazena a regra de preenchimento dos campos do browse de Cargas
oEnable	Objeto	Contém a imagem/ícone a ser apresentada quando o registro da Carga estiver Habilitado
oDisable	Objeto	Contém a imagem/ícone a ser apresentada quando o registro da Carga estiver Desabilitado

05. RETORNO

Nome

Tipo

Descrição

aRetCarga

Array

Array de três posições, contendo:

aRetCarga[1] - aArrayCarga
aRetCarga[2] - aHeaders
aRetCarga[3] - bLine

Estes três elementos devem estar no mesmo formato em que foram recebidos por parâmetro, contendo inclusive os campos adicionados pelo Ponto de Entrada e que serão apresentados na tela de Montagem de Carga.

06. VERSÕES

Protheus 12.1.17 ou superiores.

07. OBSERVAÇÃO

Não se aplica.

08. EXEMPLO

------

#INCLUDE "PROTHEUS.CH"

#DEFINE CARGA_ENABLE 1
#DEFINE CARGA_COD 2
#DEFINE CARGA_DESC 3
#DEFINE CARGA_PESO 4
#DEFINE CARGA_VALOR 5
#DEFINE CARGA_VOLUM 6
#DEFINE CARGA_QTDLIB 7
#DEFINE CARGA_PTOENT 8
#DEFINE CARGA_TRANSP 9
#DEFINE CARGA_VEIC 10
#DEFINE CARGA_VEI2 11
#DEFINE CARGA_VEI3 12
#DEFINE CARGA_MOTOR 13
#DEFINE CARGA_AJUD1 14
#DEFINE CARGA_AJUD2 15
#DEFINE CARGA_AJUD3 16
#DEFINE CARGA_USER 27

User Function OM200AD2()
Local aRetCarga := {}
Local oCargas := PARAMIXB[1]
Local aArrayCarga := PARAMIXB[2]
Local aHeaders := PARAMIXB[3]
Local bLine := PARAMIXB[4]
Local oEnable := PARAMIXB[5]
Local oDisable := PARAMIXB[6]

// Adiciona o título do campo a ser apresentado no array de Cabeçalhos
aAdd(aHeaders,"Usuário")

// Adiciona a informação que deve ser apresentada no campo
aAdd(aArrayCarga[Len(aArrayCarga)],cUserName)

// Inclui o campo no bloco de código para preenchimento das linhas da grade
bLine:={ ||{Iif(aArrayCarga[oCargas:nAT,CARGA_ENABLE],oEnable,oDisable),;
aArrayCarga[oCargas:nAT,CARGA_COD],;
aArrayCarga[oCargas:nAT,CARGA_DESC],;
aArrayCarga[oCargas:nAT,CARGA_PESO],;
aArrayCarga[oCargas:nAT,CARGA_VALOR],;
aArrayCarga[oCargas:nAT,CARGA_VOLUM],;
aArrayCarga[oCargas:nAT,CARGA_QTDLIB],;
aArrayCarga[oCargas:nAT,CARGA_PTOENT],;
aArrayCarga[oCargas:nAT,CARGA_TRANSP],;
aArrayCarga[oCargas:nAT,CARGA_VEIC],;
aArrayCarga[oCargas:nAT,CARGA_VEI2],;
aArrayCarga[oCargas:nAT,CARGA_VEI3],;
aArrayCarga[oCargas:nAT,CARGA_MOTOR],;
aArrayCarga[oCargas:nAT,CARGA_AJUD1],;
aArrayCarga[oCargas:nAT,CARGA_AJUD2],;
aArrayCarga[oCargas:nAT,CARGA_AJUD3],;
aArrayCarga[oCargas:nAT,CARGA_USER]}}

AAdd(aRetCarga, aArrayCarga)
AAdd(aRetCarga, aHeaders)
AAdd(aRetCarga, bLine)

Return aRetCarga