TM190NUM - Geração de Numeração para MDF-e

Programa Fonte
TMSA190.PRW

Sintaxe
TM190NUM - Customiza a geração da numeração do MDF-e

Retorno
(Numero do MDFe Gerado)
Não tem retorno.

Exemplos:

#INCLUDE "PROTHEUS.CH" 

User Function TM190NUM()

Local _cRet       := ''
Local _cSerie 	  := SuperGetMv( "MV_SERMAN", .F., ""   ) //-- Série do Manifesto
Local _aSeries    := {}
Local _cNumNF  	  := ""
Local _cTabSX5    := ""
Local _cTpNrNfs   := SuperGetMV("MV_TPNRNFS")


If _cTpNrNfs == "3" //Utilizando a SD9
	_cRet:= MA461NumNf(.T.,_cSerie)
Else
    If !Empty(_cSerie)	// Utilizando SX5
        _aSeries  := FWGetSX5("PT", _cSerie)
        If Empty(_aSeries)
            _aSeries  := FWGetSX5("ZV", _cSerie)
        EndIf

        If !Empty(_aSeries)
            _cNumNF  := _aSeries[1][4]
            _cTabSX5 := _aSeries[1][2]
        EndIf

        If !Empty(_cNumNF)
            _cNumNF := Soma1(AllTrim(_cNumNF))
            FwPutSX5(, _cTabSX5, _cSerie, _cNumNF, _cNumNF, _cNumNF )
            _cRet := StrZero( Val( _cNumNF ),TamSx3("DTX_MANIFE")[1],0 )
        Else
            Help(' ', 1, 'HELP', ,"Série do manifesto não encontrada na tabela genérica: "+Alltrim(_cSerie) ) //"Série do manifesto não encontrada na tabela genérica ZV"
        EndIf
    Else
        _cRet  := GETSX8NUM("DTX","DTX_MANIFE")  // Utilizando SXE, SXF
    EndIf
EndIf

RETURN _cRet