Recálculo do Custo Médio sem concorrência com movimentações de Estoque

CONTEÚDO

1. Visão Geral
2. Parâmetro
3. Pontos de Entrada - ADVPL
   
4. Pontos de Entrada - Procedure
   

01. VISÃO GERAL

Durante a execução do recálculo do custo médio (MATA330), o saldo final do período é atualizado na tabela de saldos físico/financeiro (SB2) e, caso o ambiente onde a execução ocorre seja operado por vários usuários, pode ocorrer concorrência na gravação da tabela SB2, causando lentidão no recálculo do custo e em outros processos.

Ao habilitar o parâmetro MV_A330SB2, o recálculo do custo médio passa a considerar a tabela TR2XXSP (onde XX é o código do grupo de empresas) como a tabela de saldos físico/financeiro para a execução, minimizando a concorrência com a SB2. Ao término do recálculo, antes da geração dos lançamentos contábeis, os saldos finais* calculados na TR2 são gravados na SB2 conforme disponibilidade dos registros.

Antes de habilitar o parâmetro, o cliente deve avaliar em seu ambiente se possui customizações que possam ser impactadas pela alteração da tabela de saldos físico/financeiro. Os tópicos abaixo listam os pontos de entradas que podem ser impactados.

*O saldo final é aquele gravado nos campos abaixo:

¹ O Custo médio unitário é atualizado somente para produtos do tipo Mão de Obra (MOD), por compatibilidade com o parâmetro desabilitado.

Quando o parâmetro MV_A330GRV estiver com o conteúdo .F. (ou seja, o recálculo do custo médio não processa produtos obsoletos), a tabela TR2 será gravada somente com os produtos/locais que possuem saldo ou movimentação no período, minimizando o volume de gravações no banco de dados. Caso seja necessário, os pontos de entrada da rotina deverão ser avaliados, caso estejam tentando acessar produtos não gravados na TR2.

02. Parâmetro

03. Pontos de Entrada - ADVPL

Abaixo estão listados os pontos de entrada que podem ser impactados ao habilitar o parâmetro MV_A330SB2.

A ativação do parâmetro MV_A330SB2 altera o Alias SB2, passando a apontar para a tabela TR2XXSP e deixa de ler a tabela SB2XX0 durante a execução dos pontos de entrada abaixo, entretanto, como somente os campos de quantidade, valor e custo médio finais são gravados na SB2, é necessário avaliar se outros campos da SB2 estão sendo lidos ou gravados, e realizar ajustes de acordo com a necessidade. Da mesma forma, caso sejam feitas consultas utilizando queries na SB2, com a função RetSqlName, será necessário compatibilizar para ler da tabela TR2XXSP.

Abaixo, é apresentado um exemplo hipotético de regra de negócio em ponto de entrada que pode ser impactado e os ajustes necessários para corrigir.

#INCLUDE 'totvs.ch'

User Function MA330AL()
    Local aArea := GetArea()
    Local cArmazem := "20" // Armazém que NÃO deseja recalcular custo médio
    Local lRet := .T.
 
    If SB2->B2_LOCAL == cArmazem
        lRet := .F.
    Endif
 
    RestArea(aArea)
Return lRet // Retorno Lógico, sendo .T. para recalcular armazém e .F. para não recalcular

No exemplo acima, embora seja feito acesso à SB2, não é necessário alterar o tratamento, pois com o parâmetro MV_A330SB2 habilitado, o Alias SB2 já aponta para a tabela TR2XXSP corretamente.

Caso a regra acima esteja escrita desta forma:

#INCLUDE 'totvs.ch'

User Function MA330AL()
    Local aArea := GetArea()
    Local cArmazem := "20" // Armazém que NÃO deseja recalcular custo médio
	Local cQuery   := ""
	Local cAlTmp   := ""
    Local lRet := .T.

	cQuery := " Select B2_LOCAL From "+RetSqlName("SB2")+" "
	cQuery += "  Where R_E_C_N_O_ = "+cValToChar(SB2->(Recno()))

	cAlTmp := MPSysOpenQuery(cQuery)
 
    If !(cAlTmp)->(EoF()) .And. (cAlTmp)->B2_LOCAL == cArmazem
        lRet := .F.
    Endif
	
	(cAlTmp)->(DbCloseArea())
 
    RestArea(aArea)
Return lRet // Retorno Lógico, sendo .T. para recalcular armazém e .F. para não recalcular

Será necessário corrigir a query, pois o RetSqlName retorna SB2XX0, mas a rotina deve ler os campos da TR2XXSP:

#INCLUDE 'totvs.ch'

User Function MA330AL()
    Local aArea := GetArea()
    Local cArmazem := "20" // Armazém que NÃO deseja recalcular custo médio
	Local cQuery   := ""
	Local cAlTmp   := ""
	Local cAlSB2   := RetSqlName("SB2")
    Local lRet := .T.
	Local lA330SB2 := SuperGetMV("MV_A330SB2")

	If  lA330SB2
		cAlSB2 := "TR2"+cEmpAnt+"SP"
	EndIf

	cQuery := " Select B2_LOCAL From "+ cAlSB2 +" "
	cQuery += "  Where R_E_C_N_O_ = "+cValToChar(SB2->(Recno()))

	cAlTmp := MPSysOpenQuery(cQuery)
 
    If !(cAlTmp)->(EoF()) .And. (cAlTmp)->B2_LOCAL == cArmazem
        lRet := .F.
    Endif
	
	(cAlTmp)->(DbCloseArea())
 
    RestArea(aArea)
Return lRet // Retorno Lógico, sendo .T. para recalcular armazém e .F. para não recalcular

Abaixo é apresentado outro exemplo, onde ocorre a gravação de campos na SB2

#INCLUDE 'totvs.ch'  User Function MA330D1()
    Local cFornece := '000001' //Dados do fornecedor - pode ser lido de parâmetro
    Local cLoja    := '01'     //ou outra tabela para a customização

    //Fornecedor da nota se enquadra na regra X
    If SD1->D1_FORNECE == cFornece .And. SD1->D1_LOJA == cLoja
        If RecLock('SB2', .F.)
            //Faz com que o valor de custo considerado seja o total da nota e não o custo
            SB2->B2_VFIM1  := B2_VFIM1 - SD1->D1_CUSTO + SD1->D1_TOTAL
            //Acumula o custo total deste fornecedor
            SB2->B2_XCTTOT += SD1->D1_CUSTO
            SB2->B2_CMFIM1 := B2_VFIM1 / B2_QFIM
            SB2->(MsUnlock())
        EndIf
    EndIf

Return

No exemplo acima, a gravação dos campos B2_VFIM1 e B2_CMFIM1 está correta e, ao término do recálculo, será gravada na SB2 conforme esperado, entretanto, o campo B2_XCTTOT, por não fazer parte dos campos de saldo final padrão, não será gravado na SB2, sendo necessário reavaliar o cenário customizado para adequar o ponto de entrada.

04. Pontos de Entrada - Procedure

Durante a execução do recálculo, as procedures são utilizadas para preparar o arquivo TRB e iniciar os dados na SB2, e, por conta disso, é preciso avaliar se as procedures abaixo estão instaladas no banco de dados fazendo algum acesso à tabela SB2XX0. Caso estejam, deve ser alterado para que acesse a tabela TR2XXSP

Abaixo é apresentado um exemplo hipotético de regra de negócio em um ponto de entrada escrito em procedure para MSSQL que precisaria ser ajustado:

USE [P12127MNTDBEXP]
GO
 
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
-- Procedure creation
ALTER PROCEDURE [dbo].[MA330AL_T1] (
    @IN_FILIALCOR Char( 8) ,
    @IN_COD Char( 30) ,
    @IN_LOCAL Char( 2) ,
    @IN_RECNOSB2 Integer ,
    @OUT_RESULTADO Char( 01 )  output ) AS
 
-- Declaration of variables
DECLARE @cB2_LOCAL Char(02)

BEGIN
   SET @OUT_RESULTADO  = '0'

   Select @cB2_LOCAL = ISNULL(B2_LOCAL, '  ')
   From SB2990
   Where R_E_C_N_O_ = @IN_RECNOSB2

   IF @cB2_LOCAL = '20' -- Armazém que NÃO deseja recalcular custo médio
   BEGIN
      SET @OUT_RESULTADO  = '1' -- Retorno em caractere, sendo '0' para recalcular armazém e '1' para não recalcular   
   END
END

Onde é feito o select na SB2990, é necessário trocar para TR299SP:

USE [P12127MNTDBEXP]
GO
 
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
-- Procedure creation
ALTER PROCEDURE [dbo].[MA330AL_T1] (
    @IN_FILIALCOR Char( 8) ,
    @IN_COD Char( 30) ,
    @IN_LOCAL Char( 2) ,
    @IN_RECNOSB2 Integer ,
    @OUT_RESULTADO Char( 01 )  output ) AS
 
-- Declaration of variables
DECLARE @cB2_LOCAL Char(02)

BEGIN
   SET @OUT_RESULTADO  = '0'

   Select @cB2_LOCAL = ISNULL(B2_LOCAL, '  ')
   From TR299SP
   Where R_E_C_N_O_ = @IN_RECNOSB2

   IF @cB2_LOCAL = '20' -- Armazém que NÃO deseja recalcular custo médio
   BEGIN
      SET @OUT_RESULTADO  = '1' -- Retorno em caractere, sendo '0' para recalcular armazém e '1' para não recalcular   
   END
END