Linha Microsiga Protheus

Árvore de páginas

01. DADOS GERAIS

Linha de Produto:Microsiga Protheus®
Segmento:Serviços
Módulo:Financeiro


02. DESCRIÇÃO

O Ponto de Entrada FA260QBRW permite manipular a condição WHERE padrão de filtragem dos títulos a serem apresentados no browse da conciliação bancária.


Informações

Parâmetros que são passados para o ponto de entrada

PARAMIXB - variável pública do tipo ARRAY, e na posição 1 contém a condição do WHERE padrão gerada na rotina. Modo de uso: PARAMIXB[1]


O retorno esperado pela rotina padrão do PE são as condições a serem tratadas como filtro para a tabela SE2.


03. EXEMPLO DE UTILIZAÇÃO


FA260QBRW
#INCLUDE "PROTHEUS.CH"  

user function FA260QBRW as character
Local   cWhere          :=  PARAMIXB[ 1 ]       as  character
Local   nTamCodBar	    := 0                    as  numeric
Local   nTamIdCnab	    := 0                    as  numeric
Local   dDtIni          := CToD( '  /  /  ' )   as  date
Local   dDtFin          := CToD( '  /  /  ' )   as  date

If cFilAnt == 'D MG 01 '
    nTamCodBar	:= TAMSX3("FIG_CODBAR")[1]
    nTamIdCnab	:= TAMSX3("E2_IDCNAB")[1]

    //Verifico se o parametro Vencto de/Ate nao esta vazio
    dDtIni	    := Max(dDtIni,Iif(Empty(mv_par09),dDtIni,mv_par09))
    dDtFin	    := Max(dDtFin,Iif(Empty(mv_par10),dDtFin,mv_par10))

    // Acrescento/diminuo das variaveis para abrir periodo
    dDtIni	    := dDtIni - mv_par14
    dDtFin	    := dDtFin + mv_par13

	cWhere      := "E2_FILIAL IN('D MG 01 ','D MG 02 ','D MG 03 ') AND "
	cWhere      += "E2_FORNECE  >= '"+ mv_par04 + "' AND "
	cWhere      += "E2_FORNECE  <= '"+ mv_par05 + "' AND "
	cWhere      += "E2_LOJA >= '"	+ mv_par06 + "' AND "
	cWhere      += "E2_LOJA <= '"	+ mv_par07 + "' AND "
	
	//Considera Vencto do titulo
	If mv_par08 == 1
		cWhere +=	"E2_VENCTO >= '"	+ DTOS(dDtIni) + "' AND "
		cWhere +=	"E2_VENCTO <= '"	+ DTOS(dDtFin) + "' AND "

	Else//Considera Vencto real do titulo
		cWhere +=	"E2_VENCREA >= '"	+ DTOS(dDtIni) + "' AND "
		cWhere +=	"E2_VENCREA <= '"	+ DTOS(dDtFin) + "' AND "

	Endif
	
	cWhere += "E2_SALDO > 0 AND "
	cWhere += "E2_TIPO NOT IN " + FORMATIN(MV_CPNEG+MVPAGANT,,3) + " AND "
	cWhere += "E2_TIPO NOT IN " + FORMATIN(MVABATIM,'|') + " AND "
	cWhere += "E2_TIPO NOT IN " + FORMATIN(MVTXA+"INA",,3) + " AND "
	cWhere += "E2_TIPO NOT IN " + FORMATIN(MVTAXA,,3) + " AND "
	cWhere += "E2_TIPO NOT IN " + FORMATIN(MVPROVIS,,3) + " AND "
	cWhere += "E2_CODBAR = '"	+ Space(nTamCodbar) + "' AND "
	cWhere += "E2_IDCNAB = '"	+ Space(nTamIdCnab) + "' AND "
	cWhere += "D_E_L_E_T_ = ' ' "

EndIf

return cWhere



04. DEMAIS INFORMAÇÕES

Não há


05. ASSUNTOS RELACIONADOS

  • Não há