MT220GRL - Alteração na gravação da movimentação de lote no saldo inicial

#Include 'TOTVS.ch'

/*/{Protheus.doc} User Function MT220GRL
    Permite alterar o array da rotina automática do MATA390 - Manutenção de Lotes
    na inclusão de saldo inicial (MATA220)
    Por conta da implementação do ponto de entrada, é recomendado acessar sempre a última posição
    do array, pois o ponto de entrada é chamado uma vez por linha da SD5, onde é incluida uma linha
    nova a cada chamada.
    @type  Function
    @author TOTVS 
    /*/
User Function MT220GRL()
    Local aLotes   := ParamIXB[1]
    Local aHeader  := ParamIXB[2]
    Local nLast    := Len(aLotes)
    Local nPDtVenc := 0
    Local nPQtd    := 0
    Local nPLote   := 0
    Local cUnMed   := ''
    Local nNewLast := 0
    Local cNewLote := ''

    //Alterando somente a última posição do array
    //Exemplo: Caso a data de vencimento informada seja igual a data de hoje, alterar para 31/12/2049
    nPDtVenc := AScan(aLotes[nLast], {|x| AllTrim(x[1]) == 'D5_DTVALID'})
    If nPDtVenc > 0 .And. aLotes[nLast, nPDtVenc, 2] <= dDataBase
        aLotes[nLast, nPDtVenc, 2] := CToD('31/12/2049')
    EndIf

    //Exemplo: Para produtos controlados em KG, quebra em lotes de 100Kg
    cUnMed := Posicione('SB1', 1, FWXFilial('SB1')+SB9->B9_COD, 'B1_UM')
    nPLote := AScan(aLotes[nLast], {|x| AllTrim(x[1]) == 'D5_LOTECTL'})
    nPQtd := AScan(aLotes[nLast], {|x| AllTrim(x[1]) == 'D5_QUANT'})
    If cUnMed == 'KG' .And. nPQtd > 0 .And. nPLote > 0
        cNewLote := Soma1(RTrim(aLotes[nLast, nPLote, 2]))
        While aLotes[nLast, nPQtd, 2] > 100
            If ASCan(aLotes, {|x| RTrim(x[nPLote, 2]) == RTrim(cNewLote)}) > 0
                cNewLote := Soma1(cNewLote)
                Loop
            EndIf
            aLotes[nLast, nPQtd, 2] -= 100
            AAdd(aLotes, aClone(aLotes[nLast]))
            nNewLast := Len(aLotes)
            aLotes[nNewLast, nPQtd, 2]  := 100
            aLotes[nNewLast, nPLote, 2] := cNewLote
        EndDo
    EndIf

Return aLotes