Linha Microsiga Protheus

Árvore de páginas

GFEA032D - Realizar processamento no botão "Incluir"

Características do Requisito

Linha de Produto:

Microsiga Protheus

Segmento:

Supply Chain - Logística

Módulo:

SIGAGFE

Ponto de Entrada:GFEA032D

Descrição:

Realizar processamento após encerramento da tela de Inclusão. Esse ponto tem por objetivo algum processamento específico, após encerramento da tela de inclusão de Ocorrência. Acionado na finalização da inclusão da Ocorrência (botão Incluir).

Localização:

No botão Incluir do programa Registrar Ocorrência (GFEA032).

Programa Fonte:

GFEA032 - Registrar Ocorrência

Parâmetros:

Não se aplica.

Retorno:

Não se aplica.

Exemplo: GFEA032D
#INCLUDE "PROTHEUS.CH"
User Function GFEA032D()
Local aOldArea := GetArea()
Local cAliasGW1 := GetNextAlias()
Local lPrimeiro := .t.

	BeginSql Alias cAliasGW1
		SELECT GW1.R_E_C_N_O_ RECNOGW1, GW1.GW1_NRROM
		  FROM %Table:GW1% GW1
		 INNER JOIN %Table:GWL% GWL
	 	    ON GWL.GWL_FILDC = GW1.GW1_FILIAL
		   AND GWL.GWL_EMITDC = GW1.GW1_EMISDC
		   AND GWL.GWL_SERDC = GW1.GW1_SERDC
		   AND GWL.GWL_NRDC = GW1.GW1_NRDC
		   AND GWL.GWL_TPDC = GW1.GW1_CDTPDC
		   AND GWL.GWL_FILIAL = %Exp:GWD->GWD_FILIAL%
		   AND GWL.GWL_NROCO  = %Exp:GWD->GWD_NROCO%
		   AND GWL.%NotDel%
         WHERE GW1.GW1_FILIAL = %xFilial:GW1%
		   AND GW1.%NotDel%
	EndSql
	Do While (cAliasGW1)->(!Eof())
        dbSelectArea("GW1")
        dbGoTo((cAliasGW1)->RECNOGW1)

		If lPrimeiro
			dbSelectArea("GWN")
			dbSetOrder(1)
			If dbSeek(xFilial("GWN")+(cAliasGW1)->GW1_NRROM)
				U_PROTPORT('1001') //"ENCERRADO" (Romaneio)
			EndIf
			lPrimeiro := .f.
		EndIf

       	U_PROTPORT('1201') //Atualiza Status dos DCs para "ENTREGUE" (Quando Aprovar Entregue) ou "CANCELADO" (Quando Cancelar Entrega)
		U_XYZABC() //Atualiza Data/Hora de Entrega e Transportadora (Quando Aprovar Entregue) ou limpa a Data/Hora de Entrega (Quando Cancelar Entrega)

		(cAliasGW1)->(dbSkip())
	EndDo
	(cAliasGW1)->(dbCloseArea())

RestArea(aOldArea)

Return