Linha Microsiga Protheus

Árvore de páginas

MNTA765 - Cadastro de Multas - SIGAMNT


Linha de Produto:Protheus
Segmento:Manufatura
Módulo:Manutenção de Ativos e Gestão de Frotas (SIGAMNT).
Descrição:

Rotina automática de cadastro de Multas, permite instanciar o objeto da rotina MNTA765 possibilitando realizar o cadastro de Multas

via Execução Automática.

Observações:

Para realizar o processo, é essencial instanciar o modelo da rotina MNTA765 usando o comando 'FwLoadModel('MNTA765')'.


O objeto retornado deve possuir o método 'SetValue', o qual é empregado para atribuir valores aos campos da tabela TRX. O primeiro parâmetro do método 'SetValue' deve ser 'MULTAS', enquanto o segundo parâmetro deve representar o nome do campo e o terceiro deve conter o valor a ser inserido no referido campo.


Para que o ExecAuto seja executado corretamente é necessário declarar a seguinte variável private

  • PRIVATE nOpcao := 3

Também é preciso que as funções a seguir sejam executadas;

  • MNTA765VAR();
  • SetInclui().

(Funções responsáveis pela declaração de variáveis private usadas pela rotina)


Os campos que requerem preenchimento obrigatório são os seguintes: TRX_FILIAL, TRX_MULTA, TRX_DTINFR, TRX_RHINFR, TRX_NUMAIT, TRX_CODINF, TRX_LOCAL, TRX_UFINF, TRX_CODOR, TRX_PLACA, TRX_ORIGEM, TRX_RECNOT, TRX_VALOR, TRX_DTEMIS, TRX_TIPO, TRX_PREFIX, TRX_NATURE e TRX_CONPAG.

Para setar valores string em campos de tipo data a função de conversão utilizada deve ser STOD()


Exemplo MNTA765 ExecAuto
#INCLUDE "TOTVS.ch"

User Function MNTA765EXE()

    Local oModel
    Private nOpcao   := 3

    MNTA765VAR() //Declaração de variáveis Private necessárias
    SetInclui()  //Declaração da variável lInclui

    oModel := FwLoadModel("MNTA765") // Carrega o modelo da rotina MNTA765
    oModel:SetOperation( 3 ) // Seta a Operação como Inclusão
    oModel:Activate()

	// Setando os valores nos campos
    oModel:SetValue('MULTAS', 'TRX_FILIAL' , 'D MG 01 ')
    oModel:SetValue('MULTAS', 'TRX_MULTA' , "123456719")
    oModel:SetValue('MULTAS', 'TRX_DTINFR' , STOD("20240313"))
    oModel:SetValue('MULTAS', 'TRX_RHINFR' , "05:30")
    oModel:SetValue('MULTAS', 'TRX_NUMAIT' , "T123456789")
    oModel:SetValue('MULTAS', 'TRX_CODINF' , "0001")
    oModel:SetValue('MULTAS', 'TRX_LOCAL' , "TESTE")
    oModel:SetValue('MULTAS', 'TRX_UFINF' , "PR")
    oModel:SetValue('MULTAS', 'TRX_CODOR' , "000001")
    oModel:SetValue('MULTAS', 'TRX_PLACA' , "VEI-24  ")
    oModel:SetValue('MULTAS', 'TRX_ORIGEM' , "2")
    oModel:SetValue('MULTAS', 'TRX_RECNOT' , "2")
    oModel:SetValue('MULTAS', 'TRX_VALOR' , 200)
    oModel:SetValue('MULTAS', 'TRX_DTEMIS' , STOD('20240313'))
    oModel:SetValue('MULTAS', 'TRX_PREFIX' , "MUL")
    oModel:SetValue('MULTAS', 'TRX_TIPO' , "01")
    oModel:SetValue('MULTAS', 'TRX_NATURE' , '"COFINS"')
    oModel:SetValue('MULTAS', 'TRX_CONPAG' , "001")
	
	// Execução das validações necessárias
    If oModel:VldData() 
        oModel:CommitData() // Gravação do registro
    Else
        VarInfo("Erro ao incluir",oModel:GetErrorMessage()[6])
    EndIf

	// Tratamentos para fechar novamente o Modelo após a execução do ExecAuto
    oModel:DeActivate()
    oModel:Destroy()
    oModel := NIL

Return .T.


  • Sem rótulos