Linha Microsiga Protheus

Árvore de páginas

Carregando...
Tempo aproximado para leitura: 4 minutos

01. DADOS GERAIS

Produto:

TOTVS Manutenção de Ativos

Linha de Produto:

Linha Protheus

Segmento:

Manufatura

Módulo:

TOTVS Manufatura (Linha Protheus) - Manutenção de ativos (SIGAMNT)

Função:MNTA4200()
País:Brasil


02. DESCRIÇÃO

Descrição:

Ponto de entrada acionado na consistência de insumos da O.S. corretiva durante o processo de deleção. Permitindo assim a inclusão de novas validações neste processo.

Localização:

SIGAMNT: Em Atualizações > Controle de Oficina > Ordens de Serviço > Corretiva.

Programa Fonte:

MNTA420.prw

Função:

MNTA4200()

Parâmetros:

Nome
Tipo
Descrição
Obrigatório
ParamIXB[1]ArrayLista com detalhes do insumo posicionado que está em validação.Sim
ParamIXB[2]NúmericoLinha posicionada que encontra-se em validaçãoNão
ParamIXB[3]ArrayLista de campos contidos na listagem de insumo.Sim

Retorno:

Tipo
Descrição
Obrigatório

Lógico

Indica se as validações foram realizadas com êxito.

Sim

03. DEMAIS INFORMAÇÕES

Exemplo MNTA4200()
#Include 'Totvs.ch'
  
User Function MNTA4200()
 
    Local aCols    := ParamIXB[1]
    Local nPos     := ParamIXB[2]
    Local aHeader  := ParamIXB[3]
    Local lRet     := .T.
    Local nPosAlmx := aScan( aHeader, { |x| Trim( Upper( x[2] ) ) == 'TL_LOCAL'   } )
    Local nPosProd := aScan( aHeader, { |x| Trim( Upper( x[2] ) ) == 'TL_CODIGO'  } )
    Local nPosTpRg := aScan( aHeader, { |x| Trim( Upper( x[2] ) ) == 'TL_TIPOREG' } )
    Local nPosRec  := aScan( aHeader, { |x| Trim( Upper( x[2] ) ) == 'TL_REC_WT'  } )
 
    If nPosAlmx > 0 .And. nPosProd > 0 .And. ( nPosRec > 0 .And. aCols[nPos,nPosRec] > 0 ) .And. ( nPosTpRg > 0 .And.;
       aCols[nPos,nPosTpRg] == 'P' ) .And. ( !Empty( aCols[nPos,nPosAlmx] ) .And. !Empty( aCols[nPos,nPosProd] ) )
 
        If aCols[nPos,nPosAlmx] == '01' .And. Trim( aCols[nPos,nPosProd] ) == 'PRD01'
                 
            lRet := .F.
            MsgAlert( 'Deleção não permitida para o local de estoque: ' + Trim( aCols[nPos,nPosAlmx] ) + ' e produto: ' + Trim( aCols[nPos,nPosProd] ), 'Atenção' )
 
        EndIf
 
    EndIf
 
Return lRet


04. ASSUNTOS RELACIONADOS

  • Não se aplica.