Histórico da Página

Índice

maxLevel	2
minLevel	2
style	circle

Informações

title	Nota

Esta rutina se ajustó para cumplir con la Ley general de protección de datos (Ley n° 13,70), teniendo en cuenta que algunos campos que presentan información considerada como datos sensibles y/o personales se ocultarán, y dejarán de ser legibles.

Informações

title	Nota

El proceso de selección de sucursales, así como el de baja en múltiples sucursales por medio de la rutina de bajas automáticas unificada estará a disposición solamente a partir de abril/2022

01. VISIÓN GENERAL

Esta rutina permite ejecutar la baja automática de títulos pendientes de una sola vez.
Lo títulos son seleccionados por el usuario, por medio de un filtro de portador, intervalo de vencimientos, motivo de baja y borderó (si los títulos estuvieran vinculados a un borderó), permitiendo la baja de varios borderós dentro de un intervalo especificado por el usuario (de/a). El sistema también permite que se efectúe la baja de uno o más títulos con cheque, automáticamente.

02. MAPA MENTAL

03. EJECUCIÓN

Manual

Procedimiento efectuado de forma manual vía rutina Bajas Pagar Automática (FINA090), con exhibición de las pantallas involucradas en el proceso, necesitando de acciones/comandos del usuario.

Automática

Procedimiento realizado de forma automática en la rutina Bajas Pagar Automática (FINA090), sin exhibición de pantallas o necesidad de interacción del usuario.

Se utiliza en personalizaciones donde el proceso no necesita de interacciones del usuario (MSEXECAUTO)

Informações

title	Importante - Contabilidad Online

Si la contabilidad fuera online, la baja vía rutina automática solamente se procesará si la contabilidad no estuviera configurada para mostrar la pantalla en casos de error en el registro (falta de cuenta, débito/crédito no coinciden, etc.).

Solamente se procesará con la contabilidad online si:
MV_PRELAN = S
MV_CT105MS = N
MV_ALTLCTO = N

Si utiliza la configuración para que se muestre la pantalla de contabilidad en caso de error en el registro, la rutina de baja automática vía execauto solamente se procesará si la contabilidad fuera Off-Line.

Bloco de código

language	java
theme	Midnight
title	Ejemplo de rutina automática
collapse	true

#INCLUDE "PROTHEUS.CH"

/*
Baja automática

	Baja automática
	----------------------   
Estructura de aRetAuto - baja automática
		---------------------------------------------------------
		aRetAuto [1] := aRecnos		(array conteniendo los Recnos de los registros por darse de baja)
		aRetAuto [2] := cBanco 		(Banco de la baja)
		aRetAuto [3] := cAgencia	(Agencia de la baja)
		aRetAuto [4] := cConta		(Cuenta de la baja)
		aRetAuto [5] := cCheque		(Cheque de la baja - solamente Cuentas por pagar)
		aRetAuto [6] := cLoteFin	(Lote financiero de la baja)
		aRetAuto [7] := cNatureza	(Modalidad del movimiento bancario - solamente Cuentas por pagar)
		aRetAuto [8] := dBaixa		(Fecha de la baja)
		aRetAuto [9] := nTipoBx		(1 = Baja solamente títulos que no están en el borderó o nTipoBx -> 2 = Baja solamente títulos en borderó)
		aRetAuto [10]:= cBcoDe 		(De Portador)
		aRetAuto [11]:= cBcoAte		(A Portador)
		aRetAuto [12]:= dVencIni	(Vencimiento inicial)
		aRetAuto [13]:= dVencFim	(Vencimiento final)
		aRetAuto [14]:= cBord090I	(Borderó inicial)
		aRetAuto [15]:= cBord090F	(Borderó final)
		aRetAuto [16]:= cBenef090	(Beneficiario del cheque)
		aRetAuto [17]:= cHistor		(Historial del cheque)
		aRetAuto [18]:= lMultNat	(Prorrateo múltiples modalidades)
		aRetAuto [19]:= aVendor		(Array para la baja de vendor)		

		Ejemplo: 	MSExecAuto({|x, y| FINA090(x, y)}, 3, aRetAuto)

		Para definir el Motivo de baja (si no se hubiera informado, el default es NORMAL):
			Private _cAutoMotBx := "DEBITO CC"	

	Anulación de baja:
	----------------------

		Estructura de aRetAuto - Anulación automática de bajas
		---------------------------------------------------------
		nRadio		:= aRetAuto[1] //1 = Anula baja de títulos títulos 	2 = anula baja solamente de títulos en borderó
		cBord1		:= aRetAuto[2] // De Borderó
		cBord2 		:= aRetAuto[3] // A Borderó
		cDatB1		:= aRetAuto[4] // Fch. Baja inicial
		cDatB2		:= aRetAuto[5] // Fch. Baja final
		cFor1		:= aRetAuto[6] // De Proveedor
		cFor2		:= aRetAuto[7] // A Proveedor
		aSelFil		:= aRetAuto[8] // Array con las sucursales que se considerarán en la selección de los títulos

*/

/*
------------------------------------------------------------------------------------
	FAut090
	
	Ejemplos de procesos del FINA090 Automático
------------------------------------------------------------------------------------
*/

User Function FAut090()

	Local nOpca  := 0
	Local nRadio := 1

	While .T.
		DEFINE MSDIALOG oDlg FROM  094,1 TO 230,293 TITLE "Baja automática" PIXEL
			@ 05,07 TO 40, 140 OF oDlg  PIXEL
			@ 10,10 RADIO oRadio VAR nRadio;
			ITEMS "Baja automática","Baja automática - Vendor","Anulación automática de bajas";
			3D SIZE 100,10 OF oDlg PIXEL

			DEFINE SBUTTON FROM 45,085 TYPE 1 ENABLE OF oDlg ACTION (nOpca := 1, oDlg:End())
			DEFINE SBUTTON FROM 45,115 TYPE 2 ENABLE OF oDlg ACTION (nOpca := 0, oDlg:End())

		ACTIVATE MSDIALOG oDlg CENTERED
		If nOpca == 1
			If nRadio == 1 		//Baja automática
				FBx090Aut()
				Loop
			ElseIf nRadio == 2	//Baja automática - Vendor
				FBx090VEN()
				Loop
			Else				//Anulación automática de baja
				FBx090Can()
				Loop
			Endif
		Else
			Exit
		Endif
	EndDo		

Return

/*
------------------------------------------------------------------------------------
	FBx090Aut
	
	Función para realizar baja automática - Multisucursales
	
	Ajustar pregunta Selecciona sucursales		- SÍ
------------------------------------------------------------------------------------
*/
Static Function FBx090Aut()

	Local aRecnos	:= {}
	Local cPref		:= "091"
	Local cFil1		:= "D MG 01 "
	Local cTitulo1	:= "FIN000001"
	Local cFil2		:= "D MG 02 "
	Local cTitulo2	:= "FIN000002"
	Local cParcel	:= " "
	Local cTipo		:= "NF "
	Local cForne	:= "FIN102"
	Local cLoja		:= "01"
	Local cBanco    := "001"
	Local cAgencia	:= "00001"
	Local cConta	:= "0000000001"
	Local cCheque	:= ""
	Local dBaixa	:= dDataBase
	Local nTipoBx	:= 1
	Local cBcoDe 	:= "   "
	Local cBcoAte 	:= "ZZZ"
	Local dVencIni	:= dDataBase
	Local dVencFim	:= dDataBase
	Local cBordIni	:= "      "
	Local cBordFim	:= "ZZZZZZ"	
	Local cBenef090	:= ""
	Local cHistor	:= ""
	Local lMultNat	:= .F.
	Local cLoteFin	:= ""
	Local cNatureza := PadR("PEQ000",Len( SE2->E2_NATUREZ))
	Local aFilBx	:= {cFil1,cFil2}

	Private _cAutoMotBx := "DEBITO CC"	//Si no se informa esta variable, el motivo de baja será NORMAL

//-- variables utilizadas para el control de error de la rutina automática
	Private lMsErroAuto		:= .F.
	Private lAutoErrNoFile	:= .T.

//-- Data base
	dDataBase := CTOD("14/07/2016")
	dBaixa	  := dDataBase
	dVencIni  := dDataBase
	dVencFim  := dDataBase

//-- Array con la información para seleccionar los títulos
	aAdd(aRecnos,PesqSE2(cFil1,cPref, cTitulo1, cParcel, cTipo, cForne, cLoja))
	aAdd(aRecnos,PesqSE2(cFil2,cPref, cTitulo2, cParcel, cTipo, cForne, cLoja))	

	aRetAuto := {}

	aAdd(aRetAuto,aRecnos	)		//(array conteniendo los Recnos de los registros por darse de baja)
	aAdd(aRetAuto,cBanco	)		//(Banco de la baja)
	aAdd(aRetAuto,cAgencia	)		//(Agencia de la baja)
	aAdd(aRetAuto,cConta	)		//(Cuenta de la baja)
	aAdd(aRetAuto,cCheque	)		//(Cheque de la baja - solamente Cuentas por pagar)
	aAdd(aRetAuto,cLoteFin	)		//(Lote financiero de la baja)
	aAdd(aRetAuto,cNatureza	)		//(Modalidad del movimiento bancario - solamente Cuentas por pagar)
	aAdd(aRetAuto,dBaixa	)		//(Fecha de la baja)
	aAdd(aRetAuto,nTipoBx	)		//(1 = Baja solamente títulos que no están en el borderó o nTipoBx -> 2 = Baja solamente títulos en el borderó)
	aAdd(aRetAuto,cBcoDe	)		//(De Portador)
	aAdd(aRetAuto,cBcoAte	)		//(A Portador)
	aAdd(aRetAuto,dVencIni	)		//(Vencimiento inicial)
	aAdd(aRetAuto,dVencFim	)		//(Vencimiento final)
	aAdd(aRetAuto,cBordIni	)		//(Borderó inicial)
	aAdd(aRetAuto,cBordFim	)		//(Borderó final)
	aAdd(aRetAuto,cBenef090	)		//(Beneficiario del cheque)
	aAdd(aRetAuto,cHistor	)		//(Historial del cheque)
	aAdd(aRetAuto,lMultNat	)		//(Prorrateo Múltiples modalidades)
	aAdd(aRetAuto,aFilBx	)		//(Sucursales para selección de los títulos para la baja - Solamente se selecciona sucursales = Sí)

//-- Realiza baja
	//3 = inclusión
	MSExecAuto({|x, y| FINA090(x, y)}, 3, aRetAuto)

	If lMsErroAuto
		MOSTRAERRO() 
	Endif
Return


/*
------------------------------------------------------------------------------------
	FBx090VEN
	
	Función para realizar la baja automática por el motivo Vendor
------------------------------------------------------------------------------------
*/

Static Function FBx090VEN()

	Local aRetAuto  := {}
	Local aRecnos   := {}
	Local cPref		:= "PEQ"
	Local cTitulo	:= "CT090A090"
	Local cTituloV	:= "CT090V090"
	Local cParcel	:= PadR(" ",Len( SE2->E2_PARCELA ))
	Local cTipo		:= "DP "
	Local cNatureza := "PEQ000    "
	Local cForne	:= "PEQ000"
	Local cLoja		:= "00"
	Local cCheque   := ""
	Local cLoteFin	:= ""
	Local cBanco    := "001"
	Local cAgencia	:= "00001"
	Local cConta	:= "0000000001"
	Local dBaixa	:= dDatabase
	Local cFil		:= "D MG 01 "
	Local nTipoBx	:= 1
	Local cBcoDe 	:= "   "
	Local cBcoAte 	:= "ZZZ"
	Local dVencIni	:= dDatabase
	Local dVencFim	:= dDatabase
	Local cBordIni	:= "      "
	Local cBordFim	:= "ZZZZZZ"	
	Local cBenef090	:= ""
	Local cHistor	:= "BAJA POR VENDOR"
	Local lMultNat	:= .F.
	Local cContrato := "FINA090_CT090"
	Local dDtVencV  := CTOD("20/12/2021")
	Local nTxAcresV := 5
	Local nValorV	:= 1000
	Local cNatV		:= "VENDOR    " 
	Local aFilBx	:= {}
	Local aVendor	:= {cContrato, cBanco, cAgencia, cPref, cTituloV, cParcel, cTipo, dDtVencV, nTxAcresV, cNatV, nValorV}

	Private _cAutoMotBx := "VENDOR"

//-- variables utilizadas para el control de error de la rutina automática
	Private lMsErroAuto		:= .F.
	Private lAutoErrNoFile	:= .T.

	//-- Data base
	dDataBase 	:= CTOD("14/12/2021")
	dBaixa 		:= dDataBase
	dVencIni	:= dDataBase
	dVencFim	:= dDataBase

	aAdd(aRecnos,PesqSE2(cFil,cPref, cTitulo,cParcel, cTipo, cForne, cLoja))

	aAdd(aRetAuto,aRecnos	)		//(array conteniendo los Recnos de los registros por darse de baja)
	aAdd(aRetAuto,cBanco	)		//(Banco de la baja)
	aAdd(aRetAuto,cAgencia	)		//(Agencia de la baja)
	aAdd(aRetAuto,cConta	)		//(Cuenta de la baja)
	aAdd(aRetAuto,cCheque	)		//(Cheque de la baja - solamente Cuentas por pagar)
	aAdd(aRetAuto,cLoteFin	)		//(Lote financiero de la baja)
	aAdd(aRetAuto,cNatureza	)		//(Modalidad del movimiento bancario - solamente Cuentas por pagar)
	aAdd(aRetAuto,dBaixa	)		//(Fecha de la baja)
	aAdd(aRetAuto,nTipoBx	)		//(1 = Baja solamente títulos que no están en el borderó o nTipoBx -> 2 = Baja solamente títulos en el borderó)
	aAdd(aRetAuto,cBcoDe	)		//(De Portador)
	aAdd(aRetAuto,cBcoAte	)		//(A Portador)
	aAdd(aRetAuto,dVencIni	)		//(Vencimiento inicial)
	aAdd(aRetAuto,dVencFim	)		//(Vencimiento final)
	aAdd(aRetAuto,cBordIni	)		//(Borderó inicial)
	aAdd(aRetAuto,cBordFim	)		//(Borderó final)
	aAdd(aRetAuto,cBenef090	)		//(Beneficiario del cheque)
	aAdd(aRetAuto,cHistor	)		//(Historial del cheque)
	aAdd(aRetAuto,lMultNat	)		//(Prorrateo Múltiples modalidades)
	aAdd(aRetAuto,aFilBx	)		//(Sucursales para selección de los títulos para la baja - Solamente se selecciona sucursales = Sí)
	aAdd(aRetAuto,aVendor	)		//(Array con datos del Vendor)

//-- Realiza baja
	//3 = inclusión
	MSExecAuto({|x, y| FINA090(x, y)}, 3, aRetAuto)

	If lMsErroAuto
		MOSTRAERRO() 
	Endif
Return


/*
------------------------------------------------------------------------------------
	FBx090Can
	
	Función para realizar anulación automática de bajas
------------------------------------------------------------------------------------
*/
Static Function FBx090Can()

	Local cFil1		:= "M PR 01 "
	Local cFil2		:= "M PR 02 "
	Local cForne	:= "FICN13"
	Local cForne2	:= "FICN14"
	Local aFiliais	:= {cFil1,cFil2}

//-- variables utilizadas para el control de error de la rutina automática
	Private lMsErroAuto		:= .F.
	Private lAutoErrNoFile	:= .T.

	//Data base
	dDataBase := CTOD("09/08/2019")
	dBaixa 	  := dDataBase

	aRetAuto := {}
		
	aAdd(aRetAuto,1			) //1 = Baja solamente títulos que no están en el borderó o nTipoBx -> 2 = Baja solamente títulos en el borderó
	aAdd(aRetAuto,"   "		) // De Borderó
	aAdd(aRetAuto,"ZZZZZ"	) // A Borderó
	aAdd(aRetAuto,dDataBase	) // Fch. Baja inicial
	aAdd(aRetAuto,dDataBase	) // Fch. Baja final
	aAdd(aRetAuto,cForne	) // De Proveedor
	aAdd(aRetAuto,cForne2	) // A Proveedor
	aAdd(aRetAuto,aFiliais	) //Títulos dados de baja	 

//-- Realiza anulación de la baja
	//4 = Anulación
	MSExecAuto({|x, y| FINA090(x, y)}, 4, aRetAuto)

	If lMsErroAuto
		MOSTRAERRO() 
	Endif

Return



/*
------------------------------------------------------------------------------------
	PesqSE2
	
	Función para devolver el Recno del título por darse de baja
	
	@param cFilOri	 , Character, Sucursal de origen del título (E2_FILORIG)
	@param cPrefOri	 , Character, Prefijo del título (E2_PREFIXO)
	@param cNumOri 	 , Character, Número del título (E2_NUM)
	@param cParcOri  , Character, Cuota del título (E2_PARCELA)
	@param cTipoOri  , Character, Tipo del título (E2_TIPO)
	@param cCfOri    , Character, Proveedor del título (E2_FORNECE)
	@param cLojaOri  , Character, Tienda del título (E2_LOJA)

	@retorno nRec, Numeric, Recno del registro por darse de baja

------------------------------------------------------------------------------------
*/
Static Function PesqSE2(cFilOri, cPref, cTitulo, cParcel, cTipo, cForne, cLoja )

	Local aAreaSE2  := SE2->(GetArea())
	Local nRec 		:= 0

	DEFAULT cFilOri := cFilAnt

	SE2->(DbSetOrder(1))
	If DbSeek (xFilial("SE2", cFilOri) + cPref + cTitulo + cParcel + cTipo + cForne + cLoja)
		nRec := SE2-> (RECNO())
	Endif

	RestArea(aAreaSE2)

Return nRec

04. OPERACIONES

Deck of Cards

effectDuration	0.5
history	false
id	samples
effectType	fade

Card

default	true
id	1
label	Automática

Procedimiento para baja de títulos por pagar de cualquier modalidad del módulo Financiero.

Al activar esta opción, verifique la cumplimentación de los principales campos y confirme el procedimiento.

Ejemplo:

Baixar: seleccione la opción deseada entre Títulos o borderós.

Títulos: Muestra solamente títulos que no están en el borderó

Borderós: Carrega solamente títulos en el borderó

Portador: define un intervalo de portadores para que se realice el filtro de los títulos que se darán de baja.
Vencimiento: define un intervalo de vencimientos de los títulos que se descargarán. De esta forma, el sistema considera solamente los títulos referentes al portador informado.
Borderó: define el intervalo de borderós que se considerarán en el proceso. Este campo solamente estará habilitado si la selección de Bajar fuera Borderó.
Mot. Baja : define el motivo de baja que se aplicará al proceso.
Banco: define el código del banco para la generación de los movimientos bancarios referentes a la baja. Este campo solamente estará habilitado si Mot. Baja permita la generación del movimiento bancario.
Agencia: define el código de la agencia del banco para la generación de los movimientos bancarios referentes a la baja. Este campo solamente estará habilitado si Mot. Baja permite la generación del movimiento bancario.
Cuenta: define el código de la cuenta corriente del banco para la generación de los movimientos bancarios referentes a la baja. Este campo solamente estará habilitado si Mot. Baja permite la generación del movimiento bancario.
Cheque: define el código del cheque que se generará en el proceso de bajas. Este campo solamente estará habilitado si Mot. Baja permite la generación de cheque y la pregunta Genera cheque Autom. = Sí
Beneficiario: define el beneficiario del cheque generado para el proceso de bajas.
Modalidad Movto.: define la modalidad financiera que clasificará el movimiento bancario. No afecta de ninguna manera eventuales retenciones de impuestos.
Lote: define el lote que agrupa el proceso de bajas. Este campo solamente estará habilitado si se opta por que el movimiento totalizador (ver parámetro MV_BXCNAB) o punto de entrada F090NATLOT tenga devolución .T.
Historial del cheque: define el historial del cheque. Este campo solamente estará habilitado si Mot. Baja permite la generación de cheque y la pregunta Genera cheque Autom. = Sí
Fch. Baja: define la fecha que se registrará como fecha de baja del proceso.
Prorrateo Multimodalidades: define si la baja copiará el prorrateo múltiples modalidades informado en la emisión del título. Este campo solamente estará habilitado si el parámetro MV_MULNATP estuviera habilitado.

Haga clic en OK.

Si la pregunta Selecciona sucursales = Sí, se mostrará la pantalla para la selección de sucursales que se considerarán para la selección de los títulos que se darán de baja.

Seleccione las sucursales deseadas

Si la pregunta Selecciona sucursales = No, la sucursal conectada se considerará como única sucursal para la selección de los títulos por darse de baja.

A continuación se mostrará la pantalla de la selección de los títulos que se darán de baja en el proceso.

Seleccione los títulos deseados y haga clic en Grabar.

El proceso se realizará y los títulos se darán de baja de acuerdo con la parametrización efectuada.

Nota

title	Importante

Sobre la baja de títulos del tipo PA - (Pago anticipado).
Cuando realizamos una baja de un PA que ja tuvo movimiento bancario, esta baja es considerada la devolución de aquel valor, es decir, se genera un movimiento bancario por cobrar.

Actualmente la rutina Baja automática por pagar (FINA090) no tiene tratamientos para cheques cobrados,

En el proceso estándar se generarán cheques, referentes a los pagos de títulos, solamente aquellos que generarán movimientos bancarios por pagarr.

Informações

title	Títulos en moneda extranjera

Baja de títulos de múltiples monedas utilizando banco en moneda actual (01), todos los títulos se darán de baja en el proceso. Para bancos en moneda extranjera, solamente permite la baja de los títulos que están en la misma moneda del banco.

Card

id	2
label	Buscar

Permite la búsqueda de información para el título seleccionado con la utilización de filtros que las ordenan de acuerdo con la característica deseada.

El índice seleccionado en la búsqueda se utilizará para ordenar la pantalla de selección de títulos, permitiendo que el usuario seleccione cuál es el orden de la pantalla de selección.

Ejemplo:

sucursal+orden pago.

Card

id	4
label	Anulación automática de bajas

Procedimiento para permitir que un proceso de baja se anule de forma automática, dentro de determinadas condiciones.

Acceda a Otras acciones → Anulación automática de bajas.

Ejemplo:

Anular bajas: seleccione la opción deseada entre Títulos o borderós.

Títulos: Muestra solamente títulos que no están en el borderó.

Borderós: Carga solamente títulos en el borderó.

De Borderó/ A Borderó: define un intervalo de borderós que se considerarán en el proceso. Este campo solamente estará habilitado si la selección de Bajar fuera Borderó.
De Fch. Baja/ A Fch. Baja: define un intervalo de fechas que se considerarán en el proceso.
De Proveedor/ A Proveedor: define el intervalo de códigos de proveedores que se considerarán en el proceso.
Selecciona sucursales: define si se permitirá la anulación de bajas de múltiples sucursales.
Al marcarse, permite la presentación de la pantalla para selección de las sucursales que se considerarán en el proceso.
En caso contrario, solamente títulos de la sucursal actual se considerarán en el proceso.

Haga clic en OK para proseguir.

Se mostrará la pantalla para la selección de los títulos que tendrán sus bajas anuladas.

Seleccione los títulos y haga clic en la opción Confirmar, para que se realice el proceso de anulación.

Card

id	5
label	Tracker contable

En esta opción es posible encontrar y mostrar los asientos contables a partir del documento que los originó.

Card

id	6
label	Consulta prorrateo multimodalidades

Muestra la consulta con el prorrateo de múltiples modalidades del título marcado en el browse.
Esta presentación depende de la activación del proceso de prorrateos de múltiples modalidades para cuentas por pagar (parámetro MV_MULNATP)

Card

id	7
label	Consulta de retenciones

Muestra la consulta de las retenciones de impuestos ocurridas con configuraciones del Configurador de tributos - Reglas financieras.

Card

id	6
label	Leyenda

Muestra el cuadro de las leyendas y sus significados referidos de la situación del título del cuentas por pagar.

La leyenda puede visualizarse en la primera columna del browse.

05. PARÁMETROS APLICADOS

Lista de parámetros aplicados al FINA090 y su procesamiento

Deck of Cards

id	1

Card

id	1
label	Preguntas (F12)
effectType	fade

Pregunta

Descripción

¿Muestra Asien. Contable?

Informe la opción "SÍ" para que los asientos contables generados por medio de la compensación se muestren en pantalla, o "NO", en caso contrario.

¿Agrupa asientos?

Informe la opción "SÍ" para que los asientos contables generados por medio de la compensación se agrupen en un único asiento.

¿Contabiliza On Line?

Informe "SÍ" para que la contabilidad de los asientos referentes a la baja de cuentas por pagar se realice online, o "NO", en caso contrario.

¿Genera cheque Autom.?

Informe la opción “Sí” para que las bajas por pagar automáticas generen los cheques para el pago de los respectivos títulos, o “No”, en caso contrario.

Informações

title	Nota

Por medio de la rutina de Liberación de cheques el sistema permite que los cheques generados puedan liberarse on-line, de acuerdo con la cumplimentación del parámetro MV_LIBCHEQ. Si el contenido fuera S, los cheques son liberados automáticamente y si fuera N, obligatoriamente deben pasar por esta opción.

El movimiento bancario referente a los cheques ocurre si hubiera aprobación on-line o después del procedimiento de aprobación de cheques.

¿Contabiliza borderó?

Indica si la contabilidad del AE 532, basada en la variable VALOR, se realizará desmembrando borderó por borderó o la contabilidad de todos los borderós solamente en un total.

¿Tipo de descuento?

Informe el tipo de descuento concedido a lo(s) título(s), si hubiera. Esta información se utilizará en el Fiscal, bloque F100 del SPED.

ATENCIÓN - Esta pregunta solamente se aplica a la localización BRA (Brasil)

¿Selecciona sucursales?

Selecione SIM para que seja possível selecionar as filiais a serem consideradas para o processo.
Caso selecione NÃO, apenas a filial atual será considerada para o processo.

Informações

title	Nota

El proceso de selección de sucursales, así como el de baja en múltiples sucursales solamente estará a disposición en abril/2022

¿Contabiliza en la sucursal conectada?

Seleccione 1-SÍ para contabilizar en la sucursal conectada o 2-NO para contabilizar en la sucursal de origen del título.

Informações

title	Nota

Este parámetro solamente es válido para situaciones en la cuales la contabilidad se realiza título por título.

Disponible después de la aplicación de la expedición continua de diccionario de Octubre/2022.

¿Considera BCO/AG/CTA Borderó?

SÍ - Los movimientos de baja debe considerar el banco que se utilizó cuando se creó el borderó.

NO - Informe en la pantalla de baja en qué banco deben realizarse los movimientos de baja (DEFAULT).

Nota

title	IMPORTANTE

Independientemente de la selección de la pregunta SÍ o NO, si el parámetro MV_BXCNAB = S y al realizar la baja con más de 1 borderó, solamente se generará 1 único totalizador con el banco seleccionado en pantalla.
Si la selección de la pregunta fuera SÍ y MV_BXCNAB = S, debe realizarse la baja individual de cada borderó para que el movimiento de la baja reciba el banco, agencia e cuenta grabado en el borderó.

Informações

title	Nota

Disponible después de la aplicación de la expedición continua de diccionario de Diciembre/2022.

Card

id	2
label	Parámetros (SX6)
effectType	fade

Parámetro	Descripción	Estándar
MV_AG10925	Indica si los impuestos de PCC se agruparán en un título solamente si ocurrieran los tres impuestos en el mismo título.	2
MV_ALTLCTO	¿Permite modificar asiento contable de integración?(S)Sí o (N)No.	S
MV_ATUFORN	Indica si la actualización de saldos del proveedor deba ejecutarse on-line, en las bajas automáticas por pagar.	.T.
MV_ATUSLBC	Indica si la actualización de saldos bancarios deba ejecutarse on-line, en las bajas automáticas por pagar.	.T.
MV_BX10925	Define el momento del tratamiento de la retención de los impuestos Pis Cofins y Csll, 1 = En la baja o 2 = En la emisión.	1
MV_BXAUTVE	Activa la Baja automática de títulos con motivo VENDOR	.F.
MV_BXCNAB	Define si deben agruparse las bajas de los títulos en la devolución del CNAB. (S)í o (N)o.	N
MV_BXDTFIN	No permite fecha de baja menor que la fecha contenida en el parámetro MV_DATAFIM (1=Permite, 2=No permite)	2
MV_BXTXA	Tratamiento para control de la baja de títulos TXA en la baja automática. 1 = Permite bajar 2 = No pone el saldo en cero.	1
MV_CALCCM	Indica si se efectuará o no se efectuará el cálculo de corrección monetaria. Válidos: "S" - calcula o "N" - no calcula.	S
MV_CARTEIR	Códigos de los bancos que operan en cartera.
MV_CHQBOR	Indica si se permitirá informar el número del cheque si el título estuviera en borderó.	S
MV_COFINS	Modalidad para títulos referentes al COFINS.	COFINS
MV_CSLL	Modalidad para títulos referentes al CSLL	CSLL
MV_CTBAIXA	Define si la tasa informada en la compensación se utilizará en todo el proceso. T = Ts en el Proceso, F = Ts Individual	.F.
MV_CTBFLAG	Indica si la marcación de los flags de contabilidad de las rutinas Off Line se realizará en la transacción del asiento contable - SIGACTB.	.F.
MV_CTLIPAG	Controla las bajas por pagar por medio de la fecha de liberación completada, si fuera .T. el sistema verifica si se completó el campo E2_DATALIB, en caso contrario no controla	.F.
MV_CTMOVPA	Indica si la Contabilidad Off del AE513 ocurrirá por el Título(SE2) o Mov. Bancario(SE5) del Pago anticipado. 1="SE2" / 2="SE5"	1
MV_CXFIN	Caja general Financiero	CX1/00001/0000000001
MV_DTCNBXP	Fecha para contabilidad Online bajas pagar: 1- Fecha digitación; 2- Fecha disponibilidad; 3- Fecha pago	3
MV_EASYFIN	Define si el Easy Import Control está integrado con el Financiero	N
MV_ESTADO	Sigla del estado/prov/reg de la empresa usuaria del Sistema.	SP
MV_FATOUT	Time out para selección del registro por el usuario (en segundos). Si el usuario demora más tiempo, la pantalla se cierra.	900
MV_FINVDOC	¿Activa el control de documentos obligatorios en las rutinas de liberación para baja / movimiento de los títulos por pagar? ("1" = Sí / "2" = No)	2
MV_IRF	Modalidad para títulos referentes al IRF	IRF
MV_ISS	Modalidad para títulos referentes al ISS	ISS
MV_JFILBCO	Indica si debe filtrar las cuentas corrientes vinculadas a la oficina conectada. (.T.=Sí o .F.=No)	.F.
MV_JURXFIN	Habilita la integración entre los módulos SIGAFIN - Financiero y SIGAPFS - Jurídico estándar deshabilitado.
MV_LIBCHEQ	Esta opción se utiliza para liberar el saldo bancario en la generación de cheques antes de la baja.	S
MV_MCUSTO	Moneda utilizada para verificar el límite de crédito informado en el Archivo de clientes.	2
MV_MRETISS	Modo de retención del ISS en las adquisiciones de servicios 1 = en la emisión del título principal; 2 = en la baja del título principal	1
MV_MSGTIME	Informe (en segundos) el tiempo en el cual el sistema mostrará el mensaje al usuario, avisando que se está acabando el tiempo de utilización de la pantalla.	120
MV_MULNATP	Se utiliza para identificar si el título utiliza múltiples modalidades en el cuentas por pagar
MV_MUNIC	Se utiliza para identificar el código dado al Departamento de finanzas del municipio para pagar el ISS.	MUNIC
MV_NGMNTFI	Integración Mantenimiento (MNT) con Financiero (FIN), Informe S = Sí, P = Pedido o N = No.	N
MV_PCOINTE	Indica si la integración de los procesos de Planificación y Control presupuestario con los procesos de Registros / Bloqueos está activa (1=Sí/ 2=No).	2
MV_PISNAT	Modalidad para títulos referentes al PIS.	PIS
MV_PRELAN	Indica si el Asiento contable se registrará automáticamente o pasará por Asiento previo: S=Siempre, N=Nunca, D=Doc. Inconsistente	N
MV_RT10925	Modo estándar de operación del sistema con respecto a la retención de PIS/COFINS/CSLL. (1=Calculado p/sistema, 2=Efectúa retención siempre, 3=No efectúa retención)	1
MV_SOLNCP	Define si debe utilizarse la rutina de solicitud de Nota de crédito	.F.
MV_UNIAO	Se utiliza para identificar el código dado al Fisco para pago del Impuesto a la renta.	FEDERACIÓN
MV_VL10925	Valor máximo de pagos en el período para dispensa de la retención de PIS/COFINS/CSLL (solamente aplicable a empresa pública o cálculos anteriores al 22/06/2015.)	5000
MV_VLMINPG	Valor mínimo para ejecutar la baja del título, aunque el campo E2_DATALIB no se hubiera completado y el parámetro MV_CTLIPAG fuera .T.	0
MV_VLMPUB	Valor mínimo que se considerará en la suma del PCC e IRRF para dispensa de retención para empresas públicas.	10
MV_VLTITAD	Verificar en el momento de la baja por pagar, si el proveedor tiene títulos de anticipo para compensación. T = Activa verificación o F = No activa.	F

06. CONTABILIDAD

La contabilidad de los procesos aplicados a la compensación cuentas por pagar vía módulo Financiero se realiza por los asientos estándar siguientes:

AE	Hecho generador	ON	OFF
530	En la baja de títulos por pagar	X	X
532	En la baja de títulos por pagar en Borderó	X	X
513	En la inclusión de movimiento bancario de anticipo Ver parámetro MV_CTMOVPA	X	X

Informações

title	Borderó

Borderós: Para títulos normales el asiento estándar será el 532, para títulos de anticipo, el asiento estándar es el 513

Los impuestos con hecho generador "Caja" (en la baja) generados por el borderó, deben ser contabilizados por el AE 530.
Observación: Si el parámetro "¿Contabiliza por?" estuviera configurado como "Borderó/borderó" el asiento estándar 513 no se contabilizará.

Historial.

Si fuera necesario rescatar el número del borderó e informar en el historial en el momento de la contabilidad, debe utilizarse el campo SEA→EA_NUMBOR.
Observación: Esta opción devolverá el valor del Borderó correcto solamente si el parámetro "¿Contabiliza por?" estuviera configurado como "Borderó/borderó".

Informações

title	Nota

Contabilidad por tipo de baja:

Títulos: Para títulos normales el asiento estándar será el 530, para títulos de anticipo el asiento estándar es el 513.

07. TABLAS

SE2 - Archivo del cuentas por pagar.
SEF - Archivo de cheques.
SED - Archivo de modalidades.
SA2 - Archivo de proveedores.
FK2 - Bajas por pagar.
FK3 - Impuestos calculados.
FK4 - Impuestos retenidos.
FK5 - Movimientos bancarios.
FK6 - Valores adicionales
FK7 - Tabla auxiliar.
FKA - Rastreo de movimiento.

08. PUNTOS DE ENTRADA

Expandir

title	Puntos de entrada - FINA090

Punto de entrada	Observación	Enlace
F090ADBTN	Permite incluir opciones en la pantalla (enchoicebar), donde se seleccionan los títulos que se darán de baja de forma automática	F090AdBtn - Incluye opciones en la pantalla
F090ADDB	Punto de entrada para agregar rutinas y opciones en aRotina.	F090ADDB - Permite la inclusión de rutinas y opciones en el menú de la rutina FINA090
F090ADFR	Punto de entrada para manejo del filtro que selecciona los registros pendientes de anticipos (PA) y/o notas de débito (NDF/DIC) del proveedor del título que se bajará.	F090ADFR - Manejo del filtro que selecciona los registros de anticipos y/o notas de débito del proveedor.
F090BROW	Ejecutado antes de la activación de mBrowse.	F090BROW - Baja automática
F090CHOK	Permite validar la utilización o no de las bajas automáticas.	F090CHOK - Valida bajas automáticas
F090CPOS	Trata los campos que se presentarán en la pantalla de selección de los títulos que se darán de baja por la rutina de baja automática	F090CPOS - Tratamiento de campos
F090DESC	Permite informar los descuentos para cada título liberado para baja que se pagó anticipadamente.	F090DESC - Concede descuento para cada título liberado para baja que se pagó anticipadamente.
F090FIL	Permite la modificación del filtro estándar del proceso de baja automático	F090FIL - Filtro de datos
F090FILB	Agrega filtros específicos (de usuario) en el browse inicial (específico para Brasil).	F090FILB - Definir filtro en SQL
F090FILEMI	Tiene como finalidad permitir al cliente personalizar qué campo de fecha de emisión se considerará en el filtro de los títulos traídos para la baja automática.	F090FILEMI - Personalización del cliente
F090FLBR	Agrega filtros específicos (de usuario) en el browse inicial (específico para mercado internacional).	F090FLBR - Punto de entrada para filtrar los registros de la browse en la Baja Pagar Automática, excepto localización Brasil.
F090GAVE	Maneja los datos de filtro para montaje de la pantalla inicial de baja automática.	F090GAVE - Maneja filtro para montaje de baja automática
	Se utiliza para grabación de log.	F090LOG - Grabación de log
F090MNAT	Habilita o deshabilita la opción de múltiples modalidades.	F090MNAT - Opción de múltiples modalidades
F090MTBX	Permite crear como estándar, otro motivo de baja, al acceder a la pantalla de la rutina Baja automática, para facilitar la operación.	F090MTBX - Modifica motivo de baja Autom.
F090NATLOT	Permite la liberación de los campos Modalidad financiera y Lote de la baja para digitación aunque el parámetro MV_BXCNAB esté como no.	F090NATLOT - Liberación de campos en la baja automática
F090NLOTE	Permite manejar la variable cLoteFin.	F090NLOTE - Maneja variable cLoteFin
F090PABX	Se utiliza para verificar la existencia de títulos del tipo PA (Pago anticipado) de un determinado proveedor, en el momento de la baja de un título.	F090PABX - Verificación de PA de proveedor en la baja de un título
F090POSTIT	Marca el título deseado en el momento de la selección de títulos en la baja automática por Pagar.	F090POSTIT - Baixa automática marcación de títulos CP
F090QFIL	La finalidad del punto de entrada F090QFIL es permitir complementar el filtro de los registros de la Baja Pagar Automática (FINA090).	F090QFIL - Punto de entrada para filtrar los registros de la Baja Pagar Automática
F090REST	Se ejecuta después de destrabar los registros de todas las tablas involucradas en la grabación de la Baja automática, se utiliza para realizar alguna operación después de la grabación de la Baja automática.	F090REST - Grabación y restauración de los índices
F090SE5	Maneja movimientos bancarios procesados teniendo como parámetro el Recno de los registros SE5 que se utilizaron en la baja automática.	F090SE5 - Maneja movimientos bancarios procesados en la baja automática
F090TIPO	Este punto de entrada permitirá seleccionar qué tipos de títulos no se considerarán en la baja por pagar automática.	F090TIPO - Selecciona tipos de título
F090TIT	Se utiliza en la marcación de los títulos que se dará de baja.	F090TIT - Marca título en la baja
F090TOK	Se utiliza para validar información adicional en la función Valida datos para baja automática	F090TOK - Validaciones adicionales de los datos
F090VLEX	Tratamientos específicos para información de la tabla temporal.	F090VLEX – Tratamientos específicos para información de la tabla temporal
F091FBX	Control de las sucursales de la baja de títulos para las multisucursales	F091FBX - Control de las sucursales de la baja de títulos para las multisucursales
	Tratamiento de la modalidad de un título dado de baja que no tiene campo modalidad completado	F091Natur - Tratamiento de la modalidad de un título dado de baja que no tiene campo modalidad completado
F90SE5GRV	Grabaciones complementarias en SE5 después de la baja.	F90SE5GRV - Grabaciones complementarias en SE5 después de la baja
F90TOTGRV	Grabaciones complementarias en el registro totalizador de la baja.	F90TOTGRV - Grabaciones complementarias en el registro totalizador de la baja
FA080SEF	Después de la grabación del cheque cuando se informa el cheque en la baja.	FA080SEF - Graba cheque
FA090BCO	Se ejecutará después de digitar el código del banco en la baja por pagar automática.	FA090BCO - Valida código del banco
	Se ejecutará después de confirmar la baja automática y se utilizará para calcular el valor de la corrección monetaria para cada uno de los títulos.	FA090COR- Calcula valor de la corrección monetaria
FA090DES	Se ejecutará después de la confirmación de la baja automática y se utilizará para calcular el valor del descuento para cada uno de los títulos.	FA090DES - Calcula valor de descuento
FA090JUR	Se ejecutará después de confirmar la baja automática y se utilizará para calcular el valor de los intereses para cada uno de los títulos.	FA090JUR - Calcula valor de los intereses
FA090MUL	Se ejecutará después de confirmar la baja automática y se utilizará para calcular el valor de la multa para cada uno de los títulos	FA090MUL - Calcula valor de la multa
FA090POS	Permite el tratamiento de las variables (CBCO090, CAGE090, CTA090, CCHEQ090).	FA090POS - Punto de entrada para tratamiento de variables de la rutina FINA090
FA090TIT	Se utiliza en la confirmación de la baja de los títulos.	FA090TIT - Confirma baja de título
FA090TX	Se ejecutará después de la baja del título en el SE2.	FA090TX - Baja título

Atalhos

Árvore de páginas

Versões comparadas

Versão antiga 14

Nova versão 15

Chave

01. VISIÓN GENERAL

02. MAPA MENTAL

03. EJECUCIÓN

04. OPERACIONES

05. PARÁMETROS APLICADOS

06. CONTABILIDAD

07. TABLAS

08. PUNTOS DE ENTRADA

09. CONTENIDOS RELACIONADOS