Linha Microsiga Protheus - Espanhol

Atalhos

Árvore de páginas

01. DATOS GENERALES

Línea de producto:Microsiga Protheus®
Segmento:

Servicios

Módulo:

Financiero

Rutina:

FINA080 - Baja por pagar manual 


02. DESCRIPCIÓN

El punto de entrada F80L9816 se puso a disposición para atender la Ley 9.816 de 1999, donde es posible que se informe la tasa de cambio que se utilizará en la formación de la base de cálculo del IRRF, que no es necesariamente la tasa utilizada en la baja del título por pagar. Este se ejecutará en las bajas manuales del cuentas por pagar y en su respectiva rutina automática (Execauto - FINA080). 

Observación:

El punto de entrada F80L9816 está disponible para la ejecución durante la baja manual (FINA080) de cualquier título, cabe a quién fuera implementar, crear los criterios y reglas para el uso de la nueva tasa.

Para las otras rutinas, como por ejemplo la baja automática (FINA090), debe utilizarse el punto de entrada FBXL9816 (disponible en el programa FINXIMP con fecha igual o superior al 29/12/2023).


Importante

Parámetros:

ParamIXB[1] - Clave del título - SE2→(E2_FILIAL+E2_PREFIXO+E2_NUM+E2_PARCELA+E2_TIPO+E2_FORNECE+E2_LOJA)
ParamIXB[2] - Fecha del pago
ParamIXB[3] - Fecha del débito
ParamIXB[4] - Código de la operación = 4 - Baja manual

Además de los parámetros informados en el punto de entrada, se puede utilizar cualquier información disponible del Título por pagar (campos de la tabla SE2) y Proveedor (campos de la tabla SA2) que se está procesando, pues los registros estarán marcados.


Devolución:

NombreTipoDescripciónObligatorio
nTaxaNuméricoTasa que se utilizará para componer la base de cálculo del IRRF. En caso de no haber cambios en la tasa estándar del sistema, devolver 0 (cero)Sim


03. EJEMPLO DE UTILIZACIÓN


F80L9816
#INCLUDE "PROTHEUS.CH"

User Function F80L9816()

Local cChave    := ParamIXB[1]
Local dDtBaixa  := ParamIXB[2]
Local dDtDebito := ParamIXB[3]
Local nOpc      := ParamIXB[4]
Local dDtTaxa   := dDataBase
Local aArea     := GetArea()
Local aAreaSED  := NIL
Local nTaxa     := 0

dDtTaxa:=dDtBaixa-2

If SA2->A2_TIPO=='X' .And. SE2->E2_MOEDA > 1 
    dbSelectArea('SED')
	aAreaSED := SED->(GetArea())
    SED->(dbSetOrder(1))
    SED->(dbSeek(xFilial('SED')+SE2->E2_NATUREZ))
    If SED->ED_CALCIRF=='S'
        //-- Devuelve tasa en la fecha solicitada
        nTaxa:=RecMoeda(dDtTaxa,SE2->E2_MOEDA)
    EndIF
	RestArea(aAreaSED)
EndIF

RestArea(aArea)
Return(nTaxa)


04. OTRAS INFORMACIONES

IRRF - Tasa cambiaria en el cálculo del impuesto para proveedor extranjero

F080TXIR - Punto de entrada para informar tasa en bajas manuales (rutina automática)

05. ASUNTOS RELACIONADOS

RecMoeda() (SIGAFAT)