Linha Microsiga Protheus - Espanhol

Atalhos

Árvore de páginas

Tempo aproximado para leitura: 4 minutos

01. DATOS GENERALES

Línea de producto:

Microsiga Protheus®

Segmento:

Backoffice

Módulo:

Financiero

Función:

FINA240 - Borderó de pagos

02. DESCRIPCIÓN

El punto de entrada F240GAVE tiene como objetivo permitir el manejo de los datos de filtro para montaje del borderó.

La13ª posición del array (nOpc) define si la rutina se ejecutará o descontinuará. Para continuar, esta debe tener como contenido el número entero "1" y para descontinuar la ejecución "0" (valor estándar).


Observación:

Si este punto de entrada se estuviera utilizando, la pantalla inicial de montaje de borderós estándar no se mostrará.

03. PARÁMETROS

NombreDescripción
PARAMIXB

Array con los datos iniciales del filtro posibles de manejo. Donde:

Variable

Descripción

cNumBor

Número de borderó.

dVenIni240

Vencimiento inicial

dVenFim240

Vencimiento final

nLimite

Límite del valor

cPort240

Banco

cAgen240

Agencia

cConta240

Cuenta

cContrato

Contrato

cMoeda240

Moneda

aMoedas

Monedas del sistema

cModPgto

Modelo

cTipoPag

Tipo de pago

nOpc

Variable que determina si la rutina debe continuar

o descontinuar la ejecución.

  • 0 - Descontinua la ejecución.
  • 1 - Continúa la ejecución.

04. DEVOLUCIÓN

TipoDescripción
ArrayArray con 13 posiciones.

Obs.: el array devuelto por el punto de entrada debe respetar las posiciones de acuerdo con el array recibido por el parámetro (paramIXB).


05. EJEMPLO DE UTILIZACIÓN


F240GAVE
#INCLUDE "TOTVS.CH"
 
/*/{Protheus.doc} F240GAVE
Punto de entrada para manejo del filtro del borderó de pagos.
 
@type       function
@author     TOTVS
@since      29/01/2021
@return     array, array con 13 posiciones con los filtros que se aplicarán en la rutina borderó de pagos
/*/
User Function F240GAVE() As Array
     
    Local aVars As Array
 
    Local nOpc  As Numeric
 
    aVars   := paramIXB //parámetro transferido vía ExecBlock
    nOpc    := aVars[13]
 
    // Aquí es posible escribir su lógica de programación para definición del filtro
    If !(IsBlind())
        If MsgYesNo("¿Desea continuar con la ejecución de la rutina?", "Borderó de pago")
            nOpc := 1
        Else
            nOpc := 0
        EndIf
    Else
        nOpc := 1
    EndIf
 
    If nOpc == 1
        aVars[01] := "000008"           //cNumBor
        aVars[02] := CToD("01/01/2024") //dVenIni240
        aVars[03] := CToD("31/12/2024") //dVenFim240
        aVars[04] := 99999.99           //nLimite
        aVars[05] := "237"              //cPort240
        aVars[06] := "1500"             //cAgen240
        aVars[07] := "111222333"        //cConta240
        aVars[09] := "01"               //Moeda
        aVars[11] := "31"               //cModPgto
        aVars[12] := "20"               //cTipoPag
        aVars[13] := nOpc
    Else
        aVars[13] := nOpc
    EndIf
 
Return aVars